안녕하세요
예스스탁입니다.

점선은 굵기를 굵게하면 서로 붙어서 선그래프로 보이게 됩니다.
아래 굵기 2로 지정해 드립니다.
기본굵기는 0입니다.

input : 분(60),굵기(2);
input : bull_col(Green);
input : bear_col(red);
input : mid_col(Gray);
var : line_1(nan),line_2(Nan);
var : count(0),hh(0),ll(0),mid(0),color_trend(0),trend(False);
var : S1(0),D1(0),TM(0),TF(0),Tfchange(False);

if Bdate != Bdate[1] Then
{
     S1 = TimeToMinutes(stime);
     D1 = sdate;
}

if D1 > 0 and 분 > 0 then
{
      if sdate == D1 Then
            TM = TimeToMinutes(stime)-S1;
      Else
            TM = TimeToMinutes(stime)+1440-S1;

      TF = TM%분;

      Tfchange = False;
      if Bdate != Bdate[1] or 
            (Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
            (Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
            (Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
      {
            TFchange = true;
      }
}

if 분 == 0 Then
{
      if Bdate == Bdate[1] Then
            TFchange = False;
      if Bdate != Bdate[1] Then
            TFchange = true;
}

if TFchange == False Then
{
    count = count+1;
    hh = highest(H,count);
    ll = lowest(L,count);
}

if TFchange == true Then
{
    count = 0;

      var1 = hh[1];
      line_1 = TL_New(sDate,sTime,var1,NextBarSdate,NextBarStime,var1);
      TL_SetColor(line_1,bear_col);
      TL_SetStyle(line_1,3);
        TL_SetSize(line_1,굵기);#굵기
      
      var2 = ll[1];
      line_2 = TL_New(sDate,sTime,var2,NextBarSdate,NextBarStime,var2);
      TL_SetColor(line_2,bull_col);
      TL_SetStyle(line_2,3);
        TL_SetSize(line_2,굵기);#굵기
}

TL_SetEnd(line_1,sDate,sTime,var1);
TL_SetEnd(line_2,sDate,sTime,var2);

mid = avg(var1,var2);


if CrossUp(close,var1) Then
{
    color_trend = bull_col;
    trend = true;
}

if CrossDown(close, var2) Then
{
    color_trend = bear_col;
    trend = false;
}

plot1(mid, "Trend",color_trend,Def,2);


즐거운 하루되세요



> 레전드 님이 쓴 글입니다.

> 제목 : 문의

> 92343에서 고저선을 조금 굵게 표현 부탁드립니다,실선이 너무 가늘어서 잘아보여서 그렇습니다,부탁드립니다