커뮤니티
문의드립니다.
2017-08-29 16:11:53
139
글번호 112327
환절기에 건강관리 잘하세요.
1.질문
보통 틱차트에 분봉차트를 나타내는 것은 정확하지 않은데요, 같은 틱차트 끼리는 정확한가요?
150틱 차트에서 300틱 차트의 지표를 정확히 나타낼수 있는지 궁금합니다.
현재 상위차트 지표를 참고하려고 150틱차트 위에 300틱차트를 또 띄워서 함께 보고 있는데요, 300틱 차트의 필요한 지표만 150틱차트에 불러서 사용하려고 합니다.
2.지표
150틱 차트에서 300틱차트의 MACD 와 DMI 지표를 불러와서 보고 싶습니다.
그리고 300틱 차트의 캔들중에서 도지의 종가를 150틱 차트에 plot 하는 수식도 부탁합니다.
수고하세요.
답변 1
예스스탁 예스스탁 답변
2017-08-30 14:46:16
안녕하세요
예스스탁입니다.
1
틱에서 다른 틱은 단순히 N개봉씩 묶는 내용이므로 정확합니다.
150틱에서 300틱은 150틱에서 봉 2(N)개씩 묶어 계산하면 됩니다.
2-1 MACD
input : N(20);
Input : Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), idx(0),idx2(0),PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0);
var : MACDVal(0),MACDSig(0),S1(0),D1(0),TM(0),TF1(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
if Bdate != Bdate[1] Then
idx = 0;
Else
idx = idx+1;
TF1 = idx%N;
if bdate != bdate[1] or (TF1 < TF1[1] and bdate == bdate[1]) Then{
idx2 = idx2 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDSIG = MACDSIG[1];
}
if idx2 <= 1 then {
JISU1 = C;
JISU2 = C;
MACDVal = JiSu1-Jisu2;
MACDSIG = Jisu1-jisu2;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
MACDVal = JiSu1-Jisu2;
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
plot1(MACDVal);
plot2(MACDsig);
2-2 DMI
input : N(2),Length(14);
var : TT(0),BarCnt(0),cnt(0),MyRange(0);
var : DP(0),PlusDM(0),MinusDM(0),TH(0),TL(0);
var : DM(0),DMIv(0),idx(0);
Array : HH[61](0),LL[61](0),CC[61](0),TR[61](0),TRange[61](0);
Array : PlusDM14[61](0),MinusDM14[61](0);
if Bdate != Bdate[1] Then
idx = 0;
Else
idx = idx+1;
TT = idx%N;
if bdate != bdate[1] or (Bdate == Bdate[1] and TT < TT[1]) Then{
BarCnt = BarCnt+1;
HH[0] = H;
LL[0] = L;
for cnt = 1 to 60{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
TR[cnt] = TR[cnt-1][1];
TRange[cnt] = TRange[cnt-1][1];
PlusDM14[cnt] = PlusDM14[cnt-1][1];
MinusDM14[cnt] = MinusDM14[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if CC[1] > 0 Then{
If CC[1] > HH[0] then
TH = CC[1];
else
TH = HH[0];
If CC[1] < LL[0] then
TL = CC[1];
else
TL = LL[0];
TR[0] = TH-TL;
}
If BarCnt == Length+2 Then {
MyRange = Length;
DP = 0;
DM = 0;
PlusDM14[0] = 0;
MinusDM14[0] = 0;
TRange[0] = 0;
For cnt = 0 To MyRange - 1 {
If HH[cnt] - HH[cnt+1] < 0 Then
PlusDM = 0;
Else
PlusDM = HH[cnt] - HH[cnt+1];
If LL[cnt+1] - LL[cnt] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[cnt+1] - LL[cnt];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0;
TRange[0] = TRange[0] + TR[cnt];
PlusDM14[0] = PlusDM14[0] + PlusDM;
MinusDM14[0] = MinusDM14[0] + MinusDM;
}
If TRange[0] <> 0 Then {
DP = 100 * PlusDM14[0] / TRange[0];
DM = 100 * MinusDM14[0] / TRange[0];
}
Else {
DP = 0 ;
DM = 0;
}
}
Else If BarCnt > Length+2 Then {
If HH[0] - HH[1] < 0 Then
PlusDM = 0;
Else
PlusDM = HH[0] - HH[1];
If LL [1] - LL [0] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[1] - LL[0];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0 ;
If MyRange > 0 Then {
TRange[0] = TRange[1] - (TRange[1] / MyRange) + TR[0];
PlusDM14[0] = PlusDM14[1] - (PlusDM14[1] / MyRange) + PlusDM;
MinusDM14[0] = MinusDM14[1] - (MinusDM14[1] / MyRange) + MinusDM;
}
If TRange[0] <> 0 Then{
DP = 100 * PlusDM14[0] / TRange[0];
DM = 100 * MinusDM14[0] / TRange[0];
}
Else{
DP = 0;
DM = 0;
}
}
If DP + DM == 0 Then
DMIv = 0;
Else
DMIv = 100 * AbsValue(DP - DM) / (DP + DM);
plot1(DMIv);
plot2(DP);
plot3(DM);
3
input : N(20);
Input : Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), idx(0),idx2(0),PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0);
var : MACDVal(0),MACDSig(0),S1(0),D1(0),TM(0),TF1(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
if Bdate != Bdate[1] Then
idx = 0;
Else
idx = idx+1;
TF1 = idx%N;
if bdate != bdate[1] or (TF1 < TF1[1] and bdate == bdate[1]) Then{
var1 = O;
var2 = var1[1];
if C[1] == var2 Then
value1 = C[1];
}
plot1(value1);
즐거운 하루되세요
> 웹피 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 환절기에 건강관리 잘하세요.
1.질문
보통 틱차트에 분봉차트를 나타내는 것은 정확하지 않은데요, 같은 틱차트 끼리는 정확한가요?
150틱 차트에서 300틱 차트의 지표를 정확히 나타낼수 있는지 궁금합니다.
현재 상위차트 지표를 참고하려고 150틱차트 위에 300틱차트를 또 띄워서 함께 보고 있는데요, 300틱 차트의 필요한 지표만 150틱차트에 불러서 사용하려고 합니다.
2.지표
150틱 차트에서 300틱차트의 MACD 와 DMI 지표를 불러와서 보고 싶습니다.
그리고 300틱 차트의 캔들중에서 도지의 종가를 150틱 차트에 plot 하는 수식도 부탁합니다.
수고하세요.