커뮤니티
문의드립니다.
2017-09-01 04:15:27
117
글번호 112415
항상 천절하고 빠른 답변 감사드립니다.
1. 고점 갱신후 하락시 var1 에서 매수. 청산 이후 1시간 이내에 고점 추가 갱신 없이 재하락시 var1 에서 매수금지
저점 갱신후 상승시 var2 에서 매도. 청산 이후 1시간 이내에 저점 추가 갱신 없이 재상승시 var2 에서 매도금지
2. 최근 1시간 이내 고점대비 100틱 이상 하락시 var3 에서 매수. 1시간 이내 재매수 금지
3. 최근 1시간 이내 var4를 터치후 100틱 이상 하락시 var5 에서 매수. 1시간 이내 재매수 금지
4. 연속수익 3회 발생시 1시간 동안 매매 금지 조건
5. 청산식에서 진입명 "고점매수" 는 30틱 익절, 30틱 손절
6. 청산식에서 진입명 "추세매수" 는 20틱 이상 수익 발생시 트레일링스탑을 진입가로 정하며
이후 수익이 20틱 이상일 경우 올라갔던 틱수만큼 트레일링스탑을 올려잡습니다.
ex. 20틱 수익발생시 TS= 진입가로 설정. 25틱 수익발생중이면 TS= 진입가+5틱으로 설정
7. 종목검색식. 다음달 첫 거래일에 월말 직전 3일 간의 고점을 돌파한 종목들 검색.
이상입니다. 개별적으로 적용해보고 응용해보면서 재미를 붙이고 있습니다.
모아서 질문하다보니 항목이 많습니다. 건강하시고 좋은 하루 되세요.
답변 1
예스스탁 예스스탁 답변
2017-09-01 14:04:37
안녕하세요
예스스탁입니다.
1
var : BuyEntry(false),SellEntry(false);
var : BT(0),ST(0),TM(0);
var : S1(0),D1(0);
if Bdate != Bdate[1] then{
S1 = TimeToMinutes(stime);
D1 = sdate;
BuyEntry = true;
SellEntry = true;
}
Else{
if dayhigh > DayHigh(0)[1] Then
BuyEntry = true;
if daylow < DayLow(0)[1] Then
SellEntry = true;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
if MarketPosition == 1 and MarketPosition != MarketPosition[1] Then{
BuyEntry = false;
BT = TM;
}
if MarketPosition == -1 and MarketPosition != MarketPosition[1] Then{
SellEntry = false;
ST = TM;
}
if (BT == 0 or TM >= BT+60) and BuyEntry == true and L > var1 Then
buy("B",atlimit,var1);
if (ST == 0 or TM >= ST+60) and SellEntry == true and H < var2 Then
sell("S",atlimit,var2);
}
2
var : idx(0),TM(0),cnt(0),HH(0),S1(0),D1(0),BT(0);
if Bdate != Bdate[1] then{
S1 = TimeToMinutes(stime);
D1 = sdate;
idx = 0;
}
if MarketPosition == 1 and MarketPosition != MarketPosition[1] Then
BT = TM;
if D1 > 0 then{
idx = idx+1;
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
HH = H;
for cnt = 0 to idx{
if Sdate[cnt] == sdate and
TM[cnt] > TM-60 and
H[cnt] > HH Then{
HH = H[cnt];
}
if Sdate[cnt] < sdate or TM[cnt] <= TM-60 Then
cnt = idx+1;
}
if (BT == 0 or (TM >= BT+60)) and C <= HH-PriceScale*100 Then{
if NextBarOpen < var3 Then
buy("b1",AtStop,var3);
Else
buy("b2",Atlimit,var3);
}
}
3
var : S1(0),D1(0),TM(0);
var : TT(0),VV(0),BT(0);
if Bdate != Bdate[1] then{
S1 = TimeToMinutes(stime);
D1 = sdate;
TT = 0;
BT = 0;
}
if MarketPosition == 1 and MarketPosition != MarketPosition[1] Then
BT = TM;
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
if crossup(H,var4) or CrossDown(L,var4) Then{
TT = TM;
VV = var4;
}
if (BT == 0 or (TM < BT+60)) and
TT != 0 and TM < TT+60 and C <= VV-PriceScale*100 Then{
if NextBarOpen < var5 Then
buy("b1",AtStop,var5);
Else
buy("b2",Atlimit,var5);
}
}
4
var : S1(0),D1(0),TM(0);
var : Pcnt(0),Xcond(false),XD(0),XT(0);
if Bdate != Bdate[1] then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
if TotalTrades > TotalTrades[1] Then
{
if PositionProfit(1) > 0 Then
{
Pcnt = Pcnt+1;
if Pcnt == 3 Then
{
Xcond = true;
XD = Bdate[BarsSinceExit(1)];
XT = TM[BarsSinceExit(1)];
}
}
Else
Pcnt = 0;
}
if Xcond == true and (Bdate > XD or (Bdate == XD and TM > XT+60)) Then
Xcond = false;
if Xcond == false Then
{
진입식
}
}
5
if MarketPosition == 1 Then
{
exitlong("bp",atlimit,EntryPrice+PriceScale*30,"고점매수");
exitlong("bl",AtStop,EntryPrice-PriceScale*30,"고점매수");
}
6
if MarketPosition == 1 Then
{
if highest(h,BarsSinceEntry) >= EntryPrice+PriceScale*20 Then
exitlong("btr",AtStop,highest(H,BarsSinceEntry)-PriceScale*20);
}
7
if sdate > sdate[1]+30 and C > highest(H,3)[1] Then
find(1);
즐거운 하루되세요
> 생생파생 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 항상 천절하고 빠른 답변 감사드립니다.
1. 고점 갱신후 하락시 var1 에서 매수. 청산 이후 1시간 이내에 고점 추가 갱신 없이 재하락시 var1 에서 매수금지
저점 갱신후 상승시 var2 에서 매도. 청산 이후 1시간 이내에 저점 추가 갱신 없이 재상승시 var2 에서 매도금지
2. 최근 1시간 이내 고점대비 100틱 이상 하락시 var3 에서 매수. 1시간 이내 재매수 금지
3. 최근 1시간 이내 var4를 터치후 100틱 이상 하락시 var5 에서 매수. 1시간 이내 재매수 금지
4. 연속수익 3회 발생시 1시간 동안 매매 금지 조건
5. 청산식에서 진입명 "고점매수" 는 30틱 익절, 30틱 손절
6. 청산식에서 진입명 "추세매수" 는 20틱 이상 수익 발생시 트레일링스탑을 진입가로 정하며
이후 수익이 20틱 이상일 경우 올라갔던 틱수만큼 트레일링스탑을 올려잡습니다.
ex. 20틱 수익발생시 TS= 진입가로 설정. 25틱 수익발생중이면 TS= 진입가+5틱으로 설정
7. 종목검색식. 다음달 첫 거래일에 월말 직전 3일 간의 고점을 돌파한 종목들 검색.
이상입니다. 개별적으로 적용해보고 응용해보면서 재미를 붙이고 있습니다.
모아서 질문하다보니 항목이 많습니다. 건강하시고 좋은 하루 되세요.