커뮤니티
지표 문의 드립니다.
2017-09-07 15:48:57
108
글번호 112598
주봉에서 일목균형표에 선행스팬1,2를 일봉에서 나타나게 하고 싶습니다.
일봉에서 일봉 일목균형표 선행스팬1,2랑 주봉에서 나타나는 일목균형표 선행스팬1,2를
일봉 주봉 따로 따로 보는게아니라 일봉에서 주봉 일목균형표 선행스팬1,2를 같이 나오게 하고 싶습니다.
답변 1
예스스탁 예스스탁 답변
2017-09-07 16:41:36
안녕하세요
예스스탁입니다.
지표속성 차트표시탭에서 기본차트선행1과 기본차트선행2는
수평이동을 25로 지정하시면 됩니다.
input : 전환선기간(9),기준선기간(26),선행스팬2기간(52);
var : cnt(0);
var : wH1(0),wL1(0),wH11(0),wL11(0),wH2(0),wL2(0),wH22(0),wL22(0),wH3(0),wL3(0);
var : w전환선(0),w기준선(0),w선행스팬1(0),w선행스팬2(0);
Array : WH[100](0),WL[100](0);
if DayOfWeek(bdate) < DayOfWeek(bdate[1]) Then{
WH[0] = H;
WL[0] = L;
for cnt = 1 to 99{
WH[cnt] = WH[cnt-1][1];
WL[cnt] = WL[cnt-1][1];
}
}
if H > WH[0] Then
WH[0] = H;
if L < WL[0] Then
WL[0] = L;
if WH[선행스팬2기간+25] > 0 and WL[선행스팬2기간+25] > 0 then{
wH1 = WH[0];
wL1 = WL[0];
wH11 = WH[25];
wL11 = WL[25];
wH2 = WH[0];
wL2 = WL[0];
wH22 = WH[25];
wL22 = WL[25];
wH3 = WH[25];
wL3 = WL[25];
for cnt = 0 to 선행스팬2기간-1{
if cnt < 전환선기간 Then{
if WH[cnt] > wH1 Then
wH1 = WH[cnt];
if WL[cnt] < wL1 Then
wL1 = WL[cnt];
if WH[cnt+25] > wH11 Then
wH11 = WH[cnt+25];
if WL[cnt+25] < wL11 Then
wL11 = WL[cnt+25];
}
if cnt < 기준선기간 Then{
if WH[cnt] > wH2 Then
wH2 = WH[cnt];
if WL[cnt] < wL2 Then
wL2 = WL[cnt];
if WH[cnt+25] > wH22 Then
wH22 = WH[cnt+25];
if WL[cnt+25] < wL22 Then
wL22 = WL[cnt+25];
}
if WH[cnt+25] > wH3 Then
wH3 = WH[cnt+25];
if WL[cnt+25] < wL3 Then
wL3 = WL[cnt+25];
}
w전환선 = (wH1 + wL1)/2;
w기준선 = (wH2 + wL2)/2;
w선행스팬1 = ((wH11+wL11)/2 + (wH22+wL22)/2) / 2 ;
w선행스팬2 = (wH3+wL3) / 2;
plot1(w선행스팬1,"주봉선행1");
plot2(w선행스팬2,"주봉선행2");
}
Var : 전환선(0),기준선(0), 선행스팬1(0), 선행스팬2(0);
전환선 = (Highest(H, 전환선기간) + Lowest(L, 전환선기간)) / 2;
기준선 = (Highest(H, 기준선기간) + Lowest(L, 기준선기간)) / 2;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(H, 선행스팬2기간)[25] + Lowest(L, 선행스팬2기간)[25]) / 2;
Plot3(선행스팬1,"기본차트선행1");
Plot4(선행스팬2, "기본차트선행2");
즐거운 하루되세요
> 디얼디어 님이 쓴 글입니다.
> 제목 : 지표 문의 드립니다.
> 주봉에서 일목균형표에 선행스팬1,2를 일봉에서 나타나게 하고 싶습니다.
일봉에서 일봉 일목균형표 선행스팬1,2랑 주봉에서 나타나는 일목균형표 선행스팬1,2를
일봉 주봉 따로 따로 보는게아니라 일봉에서 주봉 일목균형표 선행스팬1,2를 같이 나오게 하고 싶습니다.
다음글
이전글