커뮤니티
수식부탁드립니다
2018-06-17 21:42:53
156
글번호 119795
#,아래수식에서 질문드립니다
1,음운과양운이 교차하는지점에서 연장선을 Y축까지 오른쪽그리기와 교차값을 텍스트 출력
하고 싶습니다, [이때,현재가로부터 이전5개(변수처리)의 교차점연장선과 값만 표시되게]
2,1식을 data2 적용할수있게 도움 부탁드립니다.
Inputs: shortperiod(9), midperiod(26), longperiod(52);
Variables: 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
전환선 = (Highest(High, shortperiod) + Lowest(Low, shortperiod)) / 2;
기준선 = (Highest(High, midperiod) + Lowest(Low, midperiod)) / 2;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, longperiod) + Lowest(Low, longperiod)) / 2;
Plot1(선행스팬1," 선행스팬1");
Plot2(선행스팬2, "선행스팬2");
##,언제나 늘 고맙습니다^^
답변 1
예스스탁 예스스탁 답변
2018-06-18 15:07:08
안녕하세요
예스스탁입니다.
1.
Inputs: shortperiod(9), midperiod(26), longperiod(52);
Variables: 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0),cnt(0);
Array : UpTL[10](0),UpTX[10](0),UpVV[10](0);
Array : DnTL[10](0),DnTX[10](0),DnVV[10](0);
전환선 = (Highest(High, shortperiod) + Lowest(Low, shortperiod)) / 2;
기준선 = (Highest(High, midperiod) + Lowest(Low, midperiod)) / 2;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, longperiod) + Lowest(Low, longperiod)) / 2;
Plot1(선행스팬1,"선행스팬1");
Plot2(선행스팬2,"선행스팬2");
if crossup(선행스팬1[25],선행스팬2[25]) Then
{
var1 = (선행스팬1[25]+선행스팬2[25])/2;
UpVV[0] = var1;
UpTL[0] = TL_New(sdate[1],stime[1],UpVV[0],sdate,stime,UpVV[0]);
TL_SetColor(UpTL[0],RED);
TL_SetExtRight(UpTL[0],true);
UpTX[0] = Text_New(sdate,stime,UpVV[0],NumToStr(UpVV[0],2));
Text_SetColor(UpTX[0],RED);
for cnt = 1 to 9
{
UpVV[cnt] = UpVV[cnt-1][1];
UpTL[cnt] = UpTL[cnt-1][1];
UpTX[cnt] = UpTX[cnt-1][1];
}
TL_Delete(UpTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(UpTX[cnt]);
if UpVV[cnt] > 0 Then
{
UpTX[cnt] = Text_New(sdate,stime,UpVV[cnt],NumToStr(UpVV[cnt],2));
Text_SetColor(UpTX[cnt],RED);
}
}
if CrossDown(선행스팬1[25],선행스팬2[25]) Then
{
var2 = (선행스팬1[25]+선행스팬2[25])/2;
DnVV[0] = var2;
DnTL[0] = TL_New(sdate[1],stime[1],DnVV[0],sdate,stime,DnVV[0]);
TL_SetColor(DnTL[0],BLUE);
TL_SetExtRight(DnTL[0],true);
DnTX[0] = Text_New(sdate,stime,DnVV[0],NumToStr(DnVV[0],2));
Text_SetColor(DnTX[0],blue);
for cnt = 1 to 9
{
DnVV[cnt] = DnVV[cnt-1][1];
DnTL[cnt] = DnTL[cnt-1][1];
DnTX[cnt] = DnTX[cnt-1][1];
}
TL_Delete(DnTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(DnTX[cnt]);
if DnVV[cnt] > 0 Then
{
DnTX[cnt] = Text_New(sdate,stime,DnVV[cnt],NumToStr(DnVV[cnt],2));
Text_SetColor(DnTX[cnt],blue);
}
}
2
Inputs: shortperiod(9), midperiod(26), longperiod(52);
Variables: 기준선(0,data2), 전환선(0,data2), 후행스팬(0,data2), 선행스팬1(0,data2), 선행스팬2(0,data2),cnt(0,data2);
Array : UpTL[10](0,data2),UpTX[10](0,data2),UpVV[10](0,data2);
Array : DnTL[10](0,data2),DnTX[10](0,data2),DnVV[10](0,data2);
전환선 = data2((Highest(High, shortperiod) + Lowest(Low, shortperiod)) / 2);
기준선 = data2((Highest(High, midperiod) + Lowest(Low, midperiod)) / 2);
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = data2((Highest(High, longperiod) + Lowest(Low, longperiod)) / 2);
Plot1(선행스팬1,"선행스팬1");
Plot2(선행스팬2,"선행스팬2");
if data2(crossup(선행스팬1[25],선행스팬2[25])) Then
{
UpVV[0] = (선행스팬1[25]+선행스팬2[25])/2;
UpTL[0] = TL_New_Self(data2(sdate[1]),data2(stime[1]),UpVV[0],data2(sdate),data2(stime),UpVV[0]);
TL_SetColor(UpTL[0],RED);
TL_SetExtRight(UpTL[0],true);
UpTX[0] = Text_New_Self(data2(sdate),data2(stime),UpVV[0],NumToStr(UpVV[0],2));
Text_SetColor(UpTX[0],RED);
for cnt = 1 to 9
{
UpVV[cnt] = UpVV[cnt-1][1];
UpTL[cnt] = UpTL[cnt-1][1];
UpTX[cnt] = UpTX[cnt-1][1];
}
TL_Delete(UpTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(UpTX[cnt]);
if UpVV[cnt] > 0 Then
{
UpTX[cnt] = Text_New(data2(sdate),data2(stime),UpVV[cnt],NumToStr(UpVV[cnt],2));
Text_SetColor(UpTX[cnt],RED);
}
}
if data2(CrossDown(선행스팬1[25],선행스팬2[25])) Then
{
DnVV[0] = (선행스팬1[25]+선행스팬2[25])/2;
DnTL[0] = TL_New_Self(data2(sdate[1]),data2(stime[1]),DnVV[0],data2(sdate),data2(stime),DnVV[0]);
TL_SetColor(DnTL[0],BLUE);
TL_SetExtRight(DnTL[0],true);
DnTX[0] = Text_New_Self(data2(sdate),data2(stime),DnVV[0],NumToStr(DnVV[0],2));
Text_SetColor(DnTX[0],blue);
for cnt = 1 to 9
{
DnVV[cnt] = DnVV[cnt-1][1];
DnTL[cnt] = DnTL[cnt-1][1];
DnTX[cnt] = DnTX[cnt-1][1];
}
TL_Delete(DnTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(DnTX[cnt]);
if DnVV[cnt] > 0 Then
{
DnTX[cnt] = Text_New_Self(data2(sdate),data2(stime),DnVV[cnt],NumToStr(DnVV[cnt],2));
Text_SetColor(DnTX[cnt],blue);
}
}
즐거운 하루되세요
> 골든키 님이 쓴 글입니다.
> 제목 : 수식부탁드립니다
> #,아래수식에서 질문드립니다
1,음운과양운이 교차하는지점에서 연장선을 Y축까지 오른쪽그리기와 교차값을 텍스트 출력
하고 싶습니다, [이때,현재가로부터 이전5개(변수처리)의 교차점연장선과 값만 표시되게]
2,1식을 data2 적용할수있게 도움 부탁드립니다.
Inputs: shortperiod(9), midperiod(26), longperiod(52);
Variables: 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
전환선 = (Highest(High, shortperiod) + Lowest(Low, shortperiod)) / 2;
기준선 = (Highest(High, midperiod) + Lowest(Low, midperiod)) / 2;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, longperiod) + Lowest(Low, longperiod)) / 2;
Plot1(선행스팬1," 선행스팬1");
Plot2(선행스팬2, "선행스팬2");
##,언제나 늘 고맙습니다^^