커뮤니티
수식점검부탁드립니다
2018-06-18 22:24:53
227
글번호 119856
첨부 이미지
그림1
그림2
###,58250 질문에 텍스트 컬러까지 신경써주신 답변수식에 대해 진심으로 감사드립니다,*꾸벅*
수식을 적용해보니까 첨부파일처럼 양운과음운이 교차시점이 제가 체크한부분(사각박스)을
자세히 보시면 차트에 표현된 시점과 구름떼 교차시점이 오차가 있네요,틱봉이나 분봉이
공히 오차범위의 차이가 조금다를뿐 같은 현상이고 그림2와 같이 여러선이 표현되기도
합니다 무슨이유일까요?
도움 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2018-06-19 11:32:14
안녕하세요
예스스탁입니다.
1
교차지점값을 알지는 못합니다.
수식은 완성봉의 값만 알수 있어
중간의 교차지점값을 알수가 없습니다.
교차시 2개의 선의 중간값으로 지정했습니다.
2
랭귀지의 crossup과 crossdown은
2개의 봉의 상태를 확인하는데
crossup(A,B)은 현재봉은 A가 B보다 크고 전봉은 A가 B보다 작거나 같으면 조건이 충족됩니다.
마찬가지로 crossdown(A,B)는 현재봉은 A가 B보다 작고 전봉은 A가 B보다 크거나 같으면
조건이 충족합니다.
선이 여러개 발생하는 것은 값이 같다가 커지거나 하는 조건이 여러번 반복할수 있기 때문입니다.
조건을 변경해 이전봉이 같은것은 제외하게 수정해 드립니다.
3
Inputs: shortperiod(9), midperiod(26), longperiod(52);
Variables: 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0),cnt(0),T(0);
Array : UpTL[10](0),UpTX[10](0),UpVV[10](0);
Array : DnTL[10](0),DnTX[10](0),DnVV[10](0);
전환선 = (Highest(High, shortperiod) + Lowest(Low, shortperiod)) / 2;
기준선 = (Highest(High, midperiod) + Lowest(Low, midperiod)) / 2;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, longperiod) + Lowest(Low, longperiod)) / 2;
Plot1(선행스팬1,"선행스팬1");
Plot2(선행스팬2,"선행스팬2");
if 선행스팬1[25] > 선행스팬2[25] Then
{
T = 1;
}
if 선행스팬1[25] < 선행스팬2[25] Then
{
T = -1;
}
if T == 1 and T[1] != 1 then
{
var1 = (선행스팬1[25]+선행스팬2[25])/2;
UpVV[0] = var1;
UpTL[0] = TL_New(sdate[1],stime[1],UpVV[0],sdate,stime,UpVV[0]);
TL_SetColor(UpTL[0],RED);
TL_SetExtRight(UpTL[0],true);
UpTX[0] = Text_New(sdate,stime,UpVV[0],NumToStr(UpVV[0],2));
Text_SetColor(UpTX[0],RED);
for cnt = 1 to 9
{
UpVV[cnt] = UpVV[cnt-1][1];
UpTL[cnt] = UpTL[cnt-1][1];
UpTX[cnt] = UpTX[cnt-1][1];
}
TL_Delete(UpTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(UpTX[cnt]);
if UpVV[cnt] > 0 Then
{
UpTX[cnt] = Text_New(sdate,stime,UpVV[cnt],NumToStr(UpVV[cnt],2));
Text_SetColor(UpTX[cnt],RED);
}
}
if T == -1 and T[1] != -1 then
{
var2 = (선행스팬1[25]+선행스팬2[25])/2;
DnVV[0] = var2;
DnTL[0] = TL_New(sdate[1],stime[1],DnVV[0],sdate,stime,DnVV[0]);
TL_SetColor(DnTL[0],BLUE);
TL_SetExtRight(DnTL[0],true);
DnTX[0] = Text_New(sdate,stime,DnVV[0],NumToStr(DnVV[0],2));
Text_SetColor(DnTX[0],blue);
for cnt = 1 to 9
{
DnVV[cnt] = DnVV[cnt-1][1];
DnTL[cnt] = DnTL[cnt-1][1];
DnTX[cnt] = DnTX[cnt-1][1];
}
TL_Delete(DnTL[5]);
}
for cnt = 0 to 4
{
Text_Delete(DnTX[cnt]);
if DnVV[cnt] > 0 Then
{
DnTX[cnt] = Text_New(sdate,stime,DnVV[cnt],NumToStr(DnVV[cnt],2));
Text_SetColor(DnTX[cnt],blue);
}
}
즐거운 하루되세요
> 골든키 님이 쓴 글입니다.
> 제목 : 수식점검부탁드립니다
> ###,58250 질문에 텍스트 컬러까지 신경써주신 답변수식에 대해 진심으로 감사드립니다,*꾸벅*
수식을 적용해보니까 첨부파일처럼 양운과음운이 교차시점이 제가 체크한부분(사각박스)을
자세히 보시면 차트에 표현된 시점과 구름떼 교차시점이 오차가 있네요,틱봉이나 분봉이
공히 오차범위의 차이가 조금다를뿐 같은 현상이고 그림2와 같이 여러선이 표현되기도
합니다 무슨이유일까요?
도움 부탁드립니다.
이전글