커뮤니티
문의 드립니다
2018-06-30 14:21:46
182
글번호 120189
수고많습니다 ^^*
선물지수가 상하 어느방향으로든 변곡이 된후에 이후 그방향으로 정확히 1P 가 진행되었을때
(* 이과정에서 눌림이 있던 없던 상관없이 결과적으로 1P 만 진행되면 조건만족)
그 1P에 해당되는 봉이 완성시 어떤식으로든 신호가 나왔으면 좋겠습니다
가능하면 해당봉에 기호로도 표시되고 음성신호도 동시에 발셍되면 좋겠습니다
부탁드립니다 !!!
답변 1
예스스탁 예스스탁 답변
2018-07-02 14:22:22
안녕하세요
예스스탁입니다.
전환점에 대한 정환한 정의가 없으셔서
사용자분들이 많은 사용하시는 지그재그 수식을 수정해 답변드립니다.
아래 수식 참고하시기 바랍니다.
아래수식은 수식지왕님이 작성하신 수식을 조금 변형에
시스템식으로 작성한 수식입니다.
Input:전환포인트(1);
Var:j(0),upTr(100),dnTr(-100),trnd(0),TL(0),
date11(0),date12(0),time11(0),time12(0),TL1(0),
date21(0),date22(0),time21(0),time22(0),TL2(0),
date31(0),date32(0),time31(0),time32(0),TL3(0);
Array:hiVal[10](0),loVal[10](0),hiBar[10](0),loBar[10](0);
var : TL13(0),TL14(0),color(0),Tx1(0),Tx2(0),tx3(0),tx4(0);
for j = 1 to 9 {
loBar[j] = loBar[j] + 1;
hiBar[j] = hiBar[j] + 1;
}
if hiVal[0] <= H or hiVal[0] == 0 then
{
hiVal[0] = H;
hiBar[0] = 0;
}
else
{
hiBar[0] = hiBar[0] + 1;
}
if loVal[0] >= L or loVal[0] == 0 then
{
loVal[0] = L;
loBar[0] = 0;
}
else
{
loBar[0] = loBar[0] + 1;
}
if trnd != dnTr && hiVal[0] > H && hiVal[0]-전환포인트 > L then
trnd = dnTr;
else if trnd != upTr && loVal[0] < L && loVal[0]+전환포인트 < H then
trnd = upTr;
if trnd[1] == upTr and trnd == dnTr then
{
SELL();
for j = 8 downto 1
{
hiVal[j+1] = hiVal[j];
hiBar[j+1] = hiBar[j];
}
hiVal[1] = hiVal[0];
hiBar[1] = hiBar[0];
hiVal[0] = H;
hiBar[0] = 0;
loVal[0] = L;
loBar[0] = 0;
date11 = date[loBar[1]]; //추세선 시작일. 전저점의 날짜
time11 = stime[loBar[1]]; //추세선 시작시간
Value11 = loVal[1]; //추세선 시작가격
date12 = date[hiBar[1]]; //추세선 종료일. 전고점의 날짜
time12 = stime[hiBar[1]]; //추세선 종료시간
Value12 = hiVal[1]; //추세선 종료가격
TL1 = TL_New(date11,time11,Value11,date12,time12,Value12);
}
if trnd[1] == dnTr and trnd == dnTr and
hiVal[1] < hiVal[0] and
hiVal[0]-전환포인트 > L then {
hiVal[1] = hiVal[0];
hiBar[1] = hiBar[0];
hiVal[0] = H;
hiBar[0] = 0;
loVal[0] = L;
loBar[0] = 0;
date12 = date[hiBar[1]]; //추세선 종료일
time12 = stime[hiBar[1]];
Value12 = hiVal[1];
TL_SetEnd(TL1, date12,time12,Value12);
}
if trnd[1] == dnTr and trnd == upTr then
{
BUY();
for j = 8 downto 1
{
loVal[j+1] = loVal[j];
loBar[j+1] = loBar[j];
}
loVal[1] = loVal[0];
loBar[1] = loBar[0];
loVal[0] = L;
loBar[0] = 0;
hiVal[0] = H;
hiBar[0] = 0;
date11 = date[hiBar[1]];
time11 = stime[hiBar[1]];
Value11 = hiVal[1];
date12 = date[loBar[1]];
time12 = stime[loBar[1]];
Value12 = loVal[1];
TL1 = TL_New(date11,time11,Value11,date12,time12,Value12);
}
if trnd[1] == upTr and trnd == upTr and
loVal[1] > loVal[0] and
loVal[0]+전환포인트 < H then
{
loVal[1] = loVal[0];
loBar[1] = loBar[0];
loVal[0] = L;
loBar[0] = 0;
hiVal[0] = H;
hiBar[0] = 0;
date12 = date[loBar[1]];
time12 = stime[loBar[1]];
Value12 = loVal[1];
TL_SetEnd(TL1, date12,time12,Value12);
}
if trnd == upTr and loVal[2] > loVal[1] then{
TL_SetColor(TL1,BLUE);
color = blue;
}
else if trnd == dnTr and hiVal[2] < hiVal[1] then{
TL_SetColor(TL1,RED);
color = RED;
}
else
{
TL_SetColor(TL1,BLACK);
color = BLACK;
}
TL_SetSize(TL1,2);
TL_SetColor(TL2,RED);
TL_SetColor(TL3,BLUE);
즐거운 하루되세요
> 유로파54 님이 쓴 글입니다.
> 제목 : 문의 드립니다
> 수고많습니다 ^^*
선물지수가 상하 어느방향으로든 변곡이 된후에 이후 그방향으로 정확히 1P 가 진행되었을때
(* 이과정에서 눌림이 있던 없던 상관없이 결과적으로 1P 만 진행되면 조건만족)
그 1P에 해당되는 봉이 완성시 어떤식으로든 신호가 나왔으면 좋겠습니다
가능하면 해당봉에 기호로도 표시되고 음성신호도 동시에 발셍되면 좋겠습니다
부탁드립니다 !!!