커뮤니티
수식문의드립니다.
2018-07-12 15:18:57
154
글번호 120524
해외선물 100틱 차트에서
30분봉 20일선 60일선
60분봉 20일선 50일선
120분봉 20일선
일봉 10일선 을
100틱차트에서 보일 수 있도록 설정하고 싶습니다.
수식 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2018-07-12 17:42:05
안녕하세요
예스스탁입니다.
input : ntime1(30),P1(20),P2(60);
input : ntime2(60),Period1(20),Period2(50);
input : ntime3(120),Length1(20);
input : dayPeriod(10);
var : cnt(0),S1(0),D1(0),TM(0);
var : TF1(0),sum11(0),mav11(0),sum12(0),mav12(0);
var : TF2(0),sum21(0),mav21(0),sum22(0),mav22(0);
var : TF3(0),sum31(0),mav31(0);
var : sum41(0),mav41(0);
Array : C1[100](0),C2[100](0),C3[100](0);
if Bdate != Bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%ntime1;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF1 < TF1[1]) Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
if C1[P2] > 0 then
{
sum11 = 0;
sum12 = 0;
for cnt = 0 to P2-1{
if cnt < P1 then
sum11 = sum11+C1[cnt];
if cnt < P2 then
sum12 = sum12+C1[cnt];
}
mav11 = sum11/P1;
mav12 = sum12/P2;
plot1(mav11);
plot2(mav12);
}
TF2 = TM%ntime2;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) Then
{
for cnt = 1 to 99
{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
if C2[Period2] > 0 then
{
sum21 = 0;
sum22 = 0;
for cnt = 0 to Period2-1{
if cnt < Period1 then
sum21 = sum21+C2[cnt];
if cnt < Period2 then
sum22 = sum22+C2[cnt];
}
mav21 = sum21/Period1;
mav22 = sum22/Period2;
plot3(mav21);
plot4(mav22);
}
TF3 = TM%ntime3;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF3 < TF3[1]) Then
{
for cnt = 1 to 99
{
C3[cnt] = C3[cnt-1][1];
}
}
C3[0] = C;
if C3[Length1] > 0 then
{
sum31 = 0;
for cnt = 0 to Length1-1{
if cnt < Length1 then
sum31 = sum31+C3[cnt];
}
mav31 = sum31/Length1;
plot5(mav31);
}
if DayClose(dayPeriod) > 0 then
{
sum41 = 0;
for cnt = 0 to dayPeriod-1{
if cnt < dayPeriod then
sum41 = sum41+DayClose(cnt);
}
mav41 = sum41/dayPeriod;
plot6(mav41);
}
}
즐거운 하루되세요
> 글루비ever1 님이 쓴 글입니다.
> 제목 : 수식문의드립니다.
> 해외선물 100틱 차트에서
30분봉 20일선 60일선
60분봉 20일선 50일선
120분봉 20일선
일봉 10일선 을
100틱차트에서 보일 수 있도록 설정하고 싶습니다.
수식 부탁드립니다.