커뮤니티
문의드립니다.
2018-07-17 00:03:43
212
글번호 120651
무더위에 고생 많으십니다.
다름이 아니오라 아래와 같은 지표수식 부탁드립니다.
1. 1분봉차트에서 5분봉차트의 스토캐스틱 지표를 사용하려하는데
수식 부탁드립니다.
2. 300틱차트에서 900틱차트의 스토캐스틱 지표를 사용하려하는데
수식 부탁드립니다.
초복 잘 보내세요...
답변 1
예스스탁 예스스탁 답변
2018-07-17 10:33:09
안녕하세요
예스스탁입니다.
1
input : 분(5),Sto1(10),Sto2(5),Sto3(5);
var : S1(0),D1(0),TM(0),TF(0);
var : cnt(0), Hv(0), LV(0), FK(0), SK(0), SD(0);
var : Ep1(0), EP2(0), JISU(0), DINDEX(0), PreSK(0), PreSD(0);
Array : HH[50](0),LL[50](0);
Ep1 = 2/(sto2+1);
Ep2 = 2/(sto3+1);
if Bdate != Bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TimeToMinutes(stime)%분;
if bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) or stime == 154500 Then{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if HH[sto1-1] > 0 and LL[sto1-1] > 0 then
{
if bdate != bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) or stime == 154500 Then{
DINDEX = DINDEX+1;
PreSK = SK[1];
PreSD = SD[1];
}
Hv = HH[0];
LV = LL[0];
for cnt = 0 to sto1-1 {
if HH[cnt] > Hv then
Hv = HH[cnt];
if LL[cnt] < LV then
LV = LL[cnt];
}
FK = (C-LV)/(HV-LV)*100;
if DINDEX <= 1 then
{
SK = FK;
SD = SK;
}
else
{
SK = FK * EP1 + PreSK * (1-EP1);
SD = SK * EP2 + PreSD * (1-EP2);
}
plot1(PreSK);
plot2(PreSD);
PlotBaseLine1(20);
PlotBaseLine2(80);
}
}
2
input : N(3),Sto1(10),Sto2(5),Sto3(5);
var : idx(0),TF(0);
var : cnt(0), Hv(0), LV(0), FK(0), SK(0), SD(0);
var : Ep1(0), EP2(0), JISU(0), DINDEX(0), PreSK(0), PreSD(0);
Array : HH[50](0),LL[50](0);
Ep1 = 2/(sto2+1);
Ep2 = 2/(sto3+1);
if Bdate != Bdate[1] Then{
idx = 0;
}
Else
idx = idx+1;
TF = idx%N;
if bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 49
{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if HH[sto1-1] > 0 and LL[sto1-1] > 0 then
{
if bdate != bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
DINDEX = DINDEX+1;
PreSK = SK[1];
PreSD = SD[1];
}
Hv = HH[0];
LV = LL[0];
for cnt = 0 to sto1-1
{
if HH[cnt] > Hv then
Hv = HH[cnt];
if LL[cnt] < LV then
LV = LL[cnt];
}
FK = (C-LV)/(HV-LV)*100;
if DINDEX <= 1 then
{
SK = FK;
SD = SK;
}
else
{
SK = FK * EP1 + PreSK * (1-EP1);
SD = SK * EP2 + PreSD * (1-EP2);
}
plot1(PreSK);
plot2(PreSD);
PlotBaseLine1(20);
PlotBaseLine2(80);
}
즐거운 하루되세요
> 웹피 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 무더위에 고생 많으십니다.
다름이 아니오라 아래와 같은 지표수식 부탁드립니다.
1. 1분봉차트에서 5분봉차트의 스토캐스틱 지표를 사용하려하는데
수식 부탁드립니다.
2. 300틱차트에서 900틱차트의 스토캐스틱 지표를 사용하려하는데
수식 부탁드립니다.
초복 잘 보내세요...
다음글