커뮤니티
재문의드립니다
2018-07-24 14:48:29
227
글번호 120857
첨부 이미지
그림1
#,58736 답변에서
보내주신 수식을 적용결과 캔들조건에 부합되는 경우가 희박하여 캔들조건을 변경(하락추세에서 7양봉+13음봉=20캔들로 조정)하여 적용해도 라인이 출력이 되질 않습니다,
제가원하는것은 그림파일처럼 파동고점(318.70)에서파동저점(290.20)의 캔들수 조건이 부합될때에 고점에서 오른쪽그리기와 저점에서 오른쪽 그리기로 출력되길 원합니다
(그림파일 라인은 제가 임의로 그린것입니댜)
$$,언제나 늘 고맙습니다
- 1. 타이쿤.png (0.02 MB)
답변 1
예스스탁 예스스탁 답변
2018-07-24 16:13:32
안녕하세요
예스스탁입니다.
봉수 및 양봉갯수,음봉갯수를 외부변수 처리해 드립니다.
첨부된 그림과 같이 선이 나타납니다.
input : af(0.02), maxAF(0.2);
input : 텍스트출력(1);
input : 상승봉수(20),상승양봉(13),상승음봉(7);
input : 하락봉수(20),하락양봉(7),하락음봉(13);
var : T(0),HH(0),LL(0),HD(0),HT(0),LD(0),LT(0),TL1(0),TL2(0),cnt(0),count(0);
var : HH1(0),LL1(0),HD1(0),HT1(0),LD1(0),LT1(0),DarkGray(0);
var : TL3(0),TL4(0),TL5(0),TL6(0),tl7(0),tx1(0),tx2(0),tx11(0),tx22(0);
var : Li(0),Hi(0);
var1 = CSar(af,maxAF);
if crossup(c,var1) Then
{
T = 1;
HH = H;
HD = sdate;
HT = stime;
Hi = index;
HH1 = HH[1];
HD1 = HD[1];
HT1 = HT[1];
if LL > 0 Then
{
if 텍스트출력 == 1 then
{
Tx11 = Text_New(HD1,HT1,HH1,NumToStr((HH1-LL1)/PriceScale,0)+NewLine+NumToStr(HH1,2));
Text_SetStyle(tx11,2,1);
Text_SetColor(tx11,BLACK);
Text_Delete(tx1);
Tx1 = Text_New(HD,HT,HH,NumToStr((HH-LL[1])/PriceScale,0)+NewLine+NumToStr(HH,2));
Text_SetStyle(tx1,2,1);
Text_SetColor(tx1,BLACK);
}
}
}
if CrossDown(c,var1) Then
{
T = -1;
LL = L;
LD = sdate;
LT = stime;
Li = index;
LL1 = LL[1];
LD1 = LD[1];
LT1 = LT[1];
if HH > 0 Then
{
if 텍스트출력 == 1 then
{
Tx22 = Text_New(LD1,LT1,LL1,NumToStr((HH1-LL1)/PriceScale,0)+NewLine+NumToStr(LL1,2));
Text_SetStyle(tx22,2,0);
Text_SetColor(tx22,RED);
Text_Delete(tx2);
Tx2 = Text_New(LD,LT,LL,NumToStr((HH[1]-LL)/PriceScale,0)+NewLine+NumToStr(LL,2));
Text_SetStyle(tx2,2,0);
Text_SetColor(tx2,RED);
}
}
}
if T == 1 then
{
if H > HH Then
{
HH = H;
HD = sdate;
HT = stime;
Hi = index;
value1 = countif(C>O,상승봉수);
value2 = countif(C<O,상승봉수);
if Hi-Li == 상승봉수-1 and value1 == 상승양봉 and value2 == 상승음봉 Then
{
TL1 = TL_New(LD,LT,LL,HD,HT,HH);
TL_SetExtRight(TL1,true);
}
if 텍스트출력 == 1 then
{
Text_Delete(tx1);
Tx1 = Text_New(HD,HT,HH,NumToStr((HH-LL[1])/PriceScale,0)+NewLine+NumToStr(HH,2));
Text_SetStyle(tx1,2,1);
Text_SetColor(tx1,BLACK);
}
}
}
if T == -1 then
{
if L < LL Then
{
LL = L;
LD = sdate;
LT = stime;
Li = index;
value1 = countif(C>O,하락봉수);
value2 = countif(C<O,하락봉수);
MessageLog("%s %.f %.f ",Li-Hi == 하락봉수-1,value1,value2);
if Li-Hi == 하락봉수-1 and value1 == 하락양봉 and value2 == 하락음봉 Then
{
TL1 = TL_New(HD,HT,HH,LD,LT,LL);
TL_SetExtRight(TL1,true);
}
if 텍스트출력 == 1 then
{
Text_Delete(tx2);
Tx2 = Text_New(LD,LT,LL,NumToStr((HH[1]-LL)/PriceScale,0)+NewLine+NumToStr(LL,2));
Text_SetStyle(tx2,2,0);
Text_SetColor(tx2,RED);
}
}
}
즐거운 하루되세요
> 골든키 님이 쓴 글입니다.
> 제목 : 재문의드립니다
> #,58736 답변에서
보내주신 수식을 적용결과 캔들조건에 부합되는 경우가 희박하여 캔들조건을 변경(하락추세에서 7양봉+13음봉=20캔들로 조정)하여 적용해도 라인이 출력이 되질 않습니다,
제가원하는것은 그림파일처럼 파동고점(318.70)에서파동저점(290.20)의 캔들수 조건이 부합될때에 고점에서 오른쪽그리기와 저점에서 오른쪽 그리기로 출력되길 원합니다
(그림파일 라인은 제가 임의로 그린것입니댜)
$$,언제나 늘 고맙습니다