커뮤니티
지표부탁드립니다.
2018-08-02 09:11:46
190
글번호 121074
1.100틱차트에서 500틱 볼밴 나타내는 수식부탁드립니다
2.100틱차트에서 700틱 볼밴 나타내는 수식부탁드립니다
3.100틱차트에서 500틱 일목기준 나타내는 수식부탁드립니다
더운 날씨에도 항상 감사드립니다
답변 1
예스스탁 예스스탁 답변
2018-08-02 14:21:03
안녕하세요
예스스탁입니다.
1
2번은 아래식의 N을 7로만 변경하시면 됩니다.
input : N(5),P(20),Dv(2);
var : D1(0),TF(0),idx(0);
var : cnt(0),SumSqrt(0),Stdv(0);
var : sum(0),BBmd(0),Bbup(0),BBdn(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
D1 = sdate;
idx = 0;
}
Else
idx = idx+1;
if D1 > 0 then
{
TF = idx%N;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P] > 0 then
{
sum = 0;
for cnt = 0 to P-1
{
sum = sum + CC[cnt];
}
BBmd = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1
{
SumSqrt = SumSqrt + (CC[cnt] - BBmd)^2;
}
Stdv = SquareRoot(SumSqrt / P);
BBup = BBmd + (Dv * Stdv);
BBdn = BBmd - (Dv * Stdv);
plot1(BBmd);
plot2(BBup);
plot3(BBdn);
}
}
3
58817문의의 2번에서 N만 5로 변경하시면 됩니다.
input : N(5);
input : 전환선기간(9),기준선기간(26),선행스팬2기간(52);
var : TF(0),S1(0),D1(0),TM(0),cnt(0),idx(0);
var : H1(0),L1(0),H11(0),L11(0),H2(0),L2(0),H22(0),L22(0),H3(0),L3(0);
var : 전환선(0),기준선(0),선행스팬1(0),선행스팬2(0);
Array : HH[100](0),LL[100](0);
if Bdate != Bdate[1] Then{
idx = 0;
S1 = TimeToMinutes(stime);
D1 = sdate;
}
Else
idx = idx+1;
if D1 > 0 then{
TF = idx%N;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if HH[선행스팬2기간+25] > 0 and LL[선행스팬2기간+25] > 0 then
{
H1 = HH[0];
L1 = LL[0];
H11 = HH[25];
L11 = LL[25];
H2 = HH[0];
L2 = LL[0];
H22 = HH[25];
L22 = LL[25];
H3 = HH[25];
L3 = LL[25];
for cnt = 0 to 선행스팬2기간-1{
if cnt < 전환선기간 Then{
if HH[cnt] > H1 Then
H1 = HH[cnt];
if LL[cnt] < L1 Then
L1 = LL[cnt];
if HH[cnt+25] > H11 Then
H11 = HH[cnt+25];
if LL[cnt+25] < L11 Then
L11 = LL[cnt+25];
}
if cnt < 기준선기간 Then{
if HH[cnt] > H2 Then
H2 = HH[cnt];
if LL[cnt] < L2 Then
L2 = LL[cnt];
if HH[cnt+25] > H22 Then
H22 = HH[cnt+25];
if LL[cnt+25] < L22 Then
L22 = LL[cnt+25];
}
if HH[cnt+25] > H3 Then
H3 = HH[cnt+25];
if LL[cnt+25] < L3 Then
L3 = LL[cnt+25];
}
전환선 = (H1 + L1)/2;
기준선 = (H2 + L2)/2;
선행스팬1 = ((H11+L11)/2 + (H22+L22)/2) / 2 ;
선행스팬2 = (H3+L3) / 2;
plot1(전환선);
plot2(기준선);
plot3(선행스팬1);
plot4(선행스팬2);
}
}
즐거운 하루되세요
> 장군777 님이 쓴 글입니다.
> 제목 : 지표부탁드립니다.
> 1.100틱차트에서 500틱 볼밴 나타내는 수식부탁드립니다
2.100틱차트에서 700틱 볼밴 나타내는 수식부탁드립니다
3.100틱차트에서 500틱 일목기준 나타내는 수식부탁드립니다
더운 날씨에도 항상 감사드립니다
다음글
이전글