커뮤니티
수식 재문의
2018-08-24 14:23:37
130
글번호 121549
please check attaschment.
always thank you.
답변 1
예스스탁 예스스탁 답변
2018-08-24 14:11:54
안녕하세요
예스스탁입니다.
요청하신 내용은 아래와 같이 판단됩니다.
RSI밴드매수조건을 충족하고 저가가 B볼밴 상단보다 크면 다른조건 무시하고 매수
RSI밴드매수조건을 충족하고 저가가 B볼밴 상단보다 작으면
이후에 첫번째 A볼밴하단조건+기타조건 충족하면 매수,
이경우 A볼밴하단조건을 다시 만족하면 추가매수
RSI밴드매수조건을 충족하고 고가가 B볼밴 하단보다 작으면 다른조건 무시하고 매도
RSI밴드매수조건을 충족하고 고가가 B볼밴 하단보다 크면
이후에 첫번째 A볼밴상단조건+기타조건 충족하면 매도,
이경우 A볼밴상단조건을 다시 만족하면 추가매도
위내용으로 수정한 수식입니다.
죄송하지만 이후 수정이나 변경은 직접 처리해 보셔야 할것 같습니다.
아래 내용 참고하셔서 수정보완해 사용하시기 바랍니다.
Input : RSIPeriod(9);
Input : RSIBBPeriod(17),Dv(2);
Input : BBPeriod1(20),Dv1(2);
Input : BBPeriod2(40),Dv2(2);
input : n(10),x(10),x1(10000);
Var : RSIV(0),RSIBBmd(0),RSIBBup(0),RSIBBdn(0);
var : Aup(0),Adn(0),Bup(0),Bdn(0),T(0);
RSIV = RSI(RSIPeriod);
RSIBBmd = Ma(RSIV,RSIBBPeriod);
RSIBBup = Ma(RSIv,RSIBBPeriod) + Dv * std(RSIv,RSIBBPeriod);
RSIBBdn = ma(RSIv,RSIBBPeriod) - Dv * std(RSIv,RSIBBPeriod);
Aup = BollBandUp(BBPeriod1,dv1);
Adn = BollBandDown(BBPeriod1,dv1);
Bup = BollBandUp(BBPeriod2,dv2);
Bdn = BollBandDown(BBPeriod2,dv2);
Condition1 = CountIF(H-L >= PriceScale*x and H[1]-L[1] >= PriceScale*x,n) >= 1 or
countif(V >= x1,n) >= 1;
#RSI하단 돌파구간 1
if CrossUp(RSIV,RSIBBdn) Then
{
T = 1;
#돌파봉 저가가 B밴드상단보다 크면 매수
#T는 11
if L > Bup Then
{
buy("b1");
T = 11;
}
}
#RSI하단 이탈구간 -1
if CrossDown(RSIV,RSIBBdn) Then
T = -1;
#RSI상단 돌파구간 2
if CrossUp(RSIV,RSIBBup) Then
T = 2;
#RSI상단 이탈구간 -2
if CrossDown(RSIV,RSIBBup) Then
{
T = -2;
#이탈봉 고가가 B밴드 하단보다 작으면 매도
#T는 -22
if H < Bdn Then
sell("s1");
}
#T가 1인 구간이고
if MarketPosition <= 0 and T == 1 then
{
#종가는 A볼밴하단 위이고 현재봉이나 전봉은 저가가 Adn+1틱 미만이고 Condition1조건을 만족하면 매수
if C > Adn and (L < Adn+PriceScale*1 or L[1] < Adn[1]+PriceScale*1) and Condition1 == true Then
buy("b2");
}
#B2로 진입후 볼밴하단조건 재충족시 추가매수
if MarketPosition == 1 and IsEntryName("b2") == true and C > Adn and (L < Adn+PriceScale*1 or L[1] < Adn[1]+PriceScale*1) Then
buy("bb");
#T가 -2인 구간이고
if MarketPosition <= 0 and T == -2 then
{
#종가는 A볼밴상단 아래이고 현재봉이나 전봉은 고가가 Adn-1틱 이상이고 Condition1조건을 만족하면 매도
if C < Aup and (H > Aup-PriceScale*1 or H[1] > Aup[1]-PriceScale*1) and Condition1 == true Then
sell("s2");
}
#s2로 진입후 볼밴상단조건 재충족시 추가매도
if MarketPosition == -1 and IsEntryName("s2") == true and C < Aup and (H > Aup-PriceScale*1 or H[1] > Aup[1]-PriceScale*1) Then
sell("ss");
즐거운 하루되세요
> 흑수돌 님이 쓴 글입니다.
> 제목 : 수식 재문의
> please check attaschment.
always thank you.
다음글