커뮤니티
수정 부탁 드립니다
2018-12-28 14:09:06
159
글번호 124816
지표식에서 고점 및 저점에 해당 가격표시 및 변동틱수(고점-저점)를 표시 부탁 드립니다
Input:변동률(5),종가사용여부(0);
Var:TL1(0),신규구분(0);
Array:고[10,4](0),저[10,4](0); // 1:가격,2:Index,3:sDate,4:sTime
#==========================================#
Value1 = ChgRateZigZag(변동률, 종가사용여부, 고, 저, 신규구분);
If Value1 == 1 Then { // 고점
If 신규구분 == 1 Then // 신규
TL1 = TL_New(저[1,3],저[1,4],저[1,1],고[1,3],고[1,4],고[1,1]);
Else If 신규구분 == 2 Then // 연장
TL_SetEnd(TL1,고[1,3],고[1,4],고[1,1]);
} Else If Value1 == -1 Then { // 저점
If 신규구분 == 1 Then // 신규
TL1 = TL_New(고[1,3],고[1,4],고[1,1],저[1,3],저[1,4],저[1,1]);
Else If 신규구분 == 2 Then // 연장
TL_SetEnd(TL1,저[1,3],저[1,4],저[1,1]);
}
TL_SetSize(TL1,2);
답변 1
예스스탁 예스스탁 답변
2018-12-28 13:33:15
안녕하세요
예스스탁입니다.
Input:변동률(5),종가사용여부(0);
Var:TL1(0),신규구분(0),Tx1(0);
Array:고[10,4](0),저[10,4](0); // 1:가격,2:Index,3:sDate,4:sTime
#==========================================#
Value1 = ChgRateZigZag(변동률, 종가사용여부, 고, 저, 신규구분);
If Value1 == 1 Then { // 고점
If 신규구분 == 1 Then // 신규
{
TL1 = TL_New(저[1,3],저[1,4],저[1,1],고[1,3],고[1,4],고[1,1]);
Tx1 = Text_New(고[1,3],고[1,4],고[1,1],NumToStr(고[1,1],2)+"/+"+NumToStr(abs(고[1,1]-저[1,1])/PriceScale,0)+"틱");
Text_SetStyle(tx1,2,1);
}
Else If 신규구분 == 2 Then // 연장
{
TL_SetEnd(TL1,고[1,3],고[1,4],고[1,1]);
Text_SetLocation(tx1,고[1,3],고[1,4],고[1,1]);
Text_SetString(tx1,NumToStr(고[1,1],2)+"/+"+NumToStr(abs(고[1,1]-저[1,1])/PriceScale,0)+"틱");
}
} Else If Value1 == -1 Then { // 저점
If 신규구분 == 1 Then // 신규
{
TL1 = TL_New(고[1,3],고[1,4],고[1,1],저[1,3],저[1,4],저[1,1]);
Tx1 = Text_New(저[1,3],저[1,4],저[1,1],NumToStr(저[1,1],2)+"/-"+NumToStr(abs(고[1,1]-저[1,1])/PriceScale,0)+"틱");
Text_SetStyle(tx1,2,0);
}
Else If 신규구분 == 2 Then // 연장
{
TL_SetEnd(TL1,저[1,3],저[1,4],저[1,1]);
Text_SetLocation(tx1,저[1,3],저[1,4],저[1,1]);
Text_SetString(tx1,NumToStr(저[1,1],2)+"/-"+NumToStr(abs(고[1,1]-저[1,1])/PriceScale,0)+"틱");
}
}
TL_SetSize(TL1,2);
즐거운 하루되세요
> 헬리콥터 님이 쓴 글입니다.
> 제목 : 수정 부탁 드립니다
> 지표식에서 고점 및 저점에 해당 가격표시 및 변동틱수(고점-저점)를 표시 부탁 드립니다
Input:변동률(5),종가사용여부(0);
Var:TL1(0),신규구분(0);
Array:고[10,4](0),저[10,4](0); // 1:가격,2:Index,3:sDate,4:sTime
#==========================================#
Value1 = ChgRateZigZag(변동률, 종가사용여부, 고, 저, 신규구분);
If Value1 == 1 Then { // 고점
If 신규구분 == 1 Then // 신규
TL1 = TL_New(저[1,3],저[1,4],저[1,1],고[1,3],고[1,4],고[1,1]);
Else If 신규구분 == 2 Then // 연장
TL_SetEnd(TL1,고[1,3],고[1,4],고[1,1]);
} Else If Value1 == -1 Then { // 저점
If 신규구분 == 1 Then // 신규
TL1 = TL_New(고[1,3],고[1,4],고[1,1],저[1,3],저[1,4],저[1,1]);
Else If 신규구분 == 2 Then // 연장
TL_SetEnd(TL1,저[1,3],저[1,4],저[1,1]);
}
TL_SetSize(TL1,2);
ChgRateZigZag
Input:ChgRate(NumericSimple),useCLprice(NumericSimple),
oHiZZ[MaxSize1,MaxSize2](NumericArrayRef),
oLoZZ[MaxSize3,MaxSize4](NumericArrayRef),
oTL_NewBit(NumericRef);
Var:j(0),jj(0),HH(0),LL(0),hiBar(0),loBar(0),최종꼭지점(""),처리구분("");
#==========================================#
HH = IFF(useCLprice==1,C,H);
LL = IFF(useCLprice==1,C,L);
If Index == 0 Then {
oHiZZ[1,1] = HH;
oHiZZ[1,2] = 0;
oHiZZ[1,3] = sDate;
oHiZZ[1,4] = sTime;
oLoZZ[1,1] = LL;
oLoZZ[1,2] = 0;
oLoZZ[1,3] = sDate;
oLoZZ[1,4] = sTime;
}
If Index > 0 Then {
hiBar = hiBar + 1;
loBar = loBar + 1;
}
If HH[hiBar] < HH Then hiBar = 0;
If LL[loBar] > LL Then loBar = 0;
Condition1 = oLoZZ[1,1] * (1 + (ChgRate/100)) < HH and hiBar == 0;
Condition2 = oHiZZ[1,1] * (1 - (ChgRate/100)) > LL and loBar == 0;
처리구분 = "";
If Condition1 and Condition2 Then {
If oHiZZ[1,1] < HH and oLoZZ[1,1] > LL Then {
If HH - oHiZZ[1,1] > oLoZZ[1,1] - LL Then
처리구분 = "고점처리";
Else If HH - oHiZZ[1,1] < oLoZZ[1,1] - LL Then
처리구분 = "저점처리";
Else If 최종꼭지점 == "저점" Then
처리구분 = "고점처리";
Else
처리구분 = "저점처리";
} Else If oLoZZ[1,1] > LL Then 처리구분 = "저점처리";
Else If oHiZZ[1,1] < HH Then 처리구분 = "고점처리";
Else If 최종꼭지점 == "저점" Then 처리구분 = "고점처리";
Else 처리구분 = "저점처리";
} Else If Condition1 Then 처리구분 = "고점처리";
Else If Condition2 Then 처리구분 = "저점처리";
oTL_NewBit = 0;
#==========================================#
If 처리구분 == "고점처리" Then {
If 최종꼭지점 == "저점" Then {
For j = 10 DownTo 2 {
For jj = 1 To 4 {
oHiZZ[j,jj] = oHiZZ[j-1,jj];
}
}
oHiZZ[1,1] = HH;
oHiZZ[1,2] = Index;
oHiZZ[1,3] = sDate;
oHiZZ[1,4] = sTime;
hiBar = -1;
loBar = -1;
oTL_NewBit = 1;
} Else If oHiZZ[1,1] < HH Then {
oHiZZ[1,1] = HH;
oHiZZ[1,2] = Index;
oHiZZ[1,3] = sDate;
oHiZZ[1,4] = sTime;
hiBar = -1;
loBar = -1;
oTL_NewBit = 2;
}
최종꼭지점 = "고점";
}
#==========================================#
If 처리구분 == "저점처리" Then {
If 최종꼭지점 == "고점" then {
For j = 10 DownTo 2 {
For jj = 1 To 4 {
oLoZZ[j,jj] = oLoZZ[j-1,jj];
}
}
oLoZZ[1,1] = LL;
oLoZZ[1,2] = Index;
oLoZZ[1,3] = sDate;
oLoZZ[1,4] = sTime;
hiBar = -1;
loBar = -1;
oTL_NewBit = 1;
} Else If oLoZZ[1,1] > LL then {
oLoZZ[1,1] = LL;
oLoZZ[1,2] = Index;
oLoZZ[1,3] = sDate;
oLoZZ[1,4] = sTime;
hiBar = -1;
loBar = -1;
oTL_NewBit = 2;
}
최종꼭지점 = "저점";
}
If 최종꼭지점 == "고점" Then ChgRateZigZag = 1;
Else If 최종꼭지점 == "저점" Then ChgRateZigZag = -1;
Else ChgRateZigZag = 0;