커뮤니티
식 문의드립니다.
2019-06-13 13:26:30
333
글번호 129419
안녕하세요 식문의드립니다.
지그재그 차트를 나타낼수 있게 부탁드립니다.
분봉상으로 보려고 하며 종가기준이며
전환비율(%)을 설정할수 있게 부탁드립니다.
상승시 빨간선, 하락시 파랑선 부탁드립니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2019-06-13 15:18:59
안녕하세요
예스스탁입니다.
Input:rate(10),두께(2);
Var:j(0),hiBar(0),loBar(0),sBar(0),eBar(0),TL1(0),Text1(0),처리구분(""),최종변곡점("");
Array:고점[10,2](0),저점[10,2](0); //가격,위치
#==========================================#
If Index == 0 Then
{
고점[1,1] = c;
저점[1,1] = c;
}
If Index > 0 Then // Index가 0일때는 이전 봉이 없으므로 Index가 1일때부터 1씩 증가
{
hiBar = hiBar + 1;
loBar = loBar + 1;
}
If c[hiBar] <= c Then hiBar = 0; // 고점이 새로이 생기면 고점까지의 봉개수는 0
If c[loBar] >= c Then loBar = 0;
Condition1 = c[hiBar] > c and c[hiBar] * (1 - (rate/100)) > c;
Condition2 = c[loBar] < c and c[loBar] * (1 + (rate/100)) < c;
처리구분 = "";
If Condition1 and Condition2 Then
{
If 최종변곡점 == "저점" Then 처리구분 = "저고점처리"; // 저 - 고 순으로 두번 처리
Else 처리구분 = "고저점처리"; // 고 - 저 순으로 두번 처리
}
Else If Condition1 Then 처리구분 = "고점처리";
Else If Condition2 Then 처리구분 = "저점처리";
#==========================================#
If 처리구분 == "고저점처리" Then
{
If 고점[1,1] < c[hiBar] Then
{
고점[1,1] = c[hiBar];
고점[1,2] = Index - hiBar;
eBar = Index - 고점[1,2]; // 끝점까지의 거리
TL_SetEnd(TL1,sDate[eBar],sTime[eBar],고점[1,1]); // 추세선의 끝점을 새로 설정
}
처리구분 = "저점처리";
}
#==========================================#
If 처리구분 == "저고점처리" Then
{
If 저점[1,1] > c[loBar] Then
{
저점[1,1] = c[loBar];
저점[1,2] = Index - loBar;
eBar = Index - 저점[1,2];
TL_SetEnd(TL1,sDate[eBar],sTime[eBar],저점[1,1]);
}
처리구분 = "고점처리";
}
#==========================================#
If 처리구분 == "고점처리" Then
{
If 최종변곡점 == "저점" Then
{
For j = 10 DownTo 2
{
고점[j,1] = 고점[j-1,1];
고점[j,2] = 고점[j-1,2];
}
고점[1,1] = c[hiBar];
고점[1,2] = Index - hiBar;
loBar = 0;
hiBar = 0;
sBar = Index - 저점[1,2]; // 시작점까지의 거리
eBar = Index - 고점[1,2];
TL1 = TL_New(sDate[sBar],sTime[sBar],저점[1,1],sDate[eBar],sTime[eBar],고점[1,1]); // 추세선을 새로 생성
TL_SetColor(TL1,RED);
TL_SetSize(TL1,두께);
}
Else If 고점[1,1] < c[hiBar] Then
{
고점[1,1] = c[hiBar];
고점[1,2] = Index - hiBar;
loBar = 0;
hiBar = 0;
eBar = Index - 고점[1,2];
TL_SetEnd(TL1,sDate[eBar],sTime[eBar],고점[1,1]);
}
최종변곡점 = "고점";
}
#==========================================#
If 처리구분 == "저점처리" Then
{
If 최종변곡점 == "고점" Then
{
For j = 10 DownTo 2
{
저점[j,1] = 저점[j-1,1];
저점[j,2] = 저점[j-1,2];
}
저점[1,1] = c[loBar];
저점[1,2] = Index - loBar;
loBar = 0;
hiBar = 0;
sBar = Index - 고점[1,2];
eBar = Index - 저점[1,2];
TL1 = TL_New(sDate[sBar],sTime[sBar],고점[1,1],sDate[eBar],sTime[eBar],저점[1,1]);
TL_SetColor(TL1,blue);
TL_SetSize(TL1,두께);
}
Else If 저점[1,1] > c[loBar] Then
{
저점[1,1] = c[loBar];
저점[1,2] = Index - loBar;
loBar = 0;
hiBar = 0;
eBar = Index - 저점[1,2];
TL_SetEnd(TL1,sDate[eBar],sTime[eBar],저점[1,1]);
}
최종변곡점 = "저점";
}
#==========================================#
즐거운 하루되세요
> 스누피독 님이 쓴 글입니다.
> 제목 : 식 문의드립니다.
> 안녕하세요 식문의드립니다.
지그재그 차트를 나타낼수 있게 부탁드립니다.
분봉상으로 보려고 하며 종가기준이며
전환비율(%)을 설정할수 있게 부탁드립니다.
상승시 빨간선, 하락시 파랑선 부탁드립니다.
감사합니다.