커뮤니티
분봉에서 일봉 사용하기 질문입니다.
2007-07-16 07:39:53
1041
글번호 13064
5분 5000봉에서
일봉 MACD, DIMinus 를 사용 할 수있는 소스를 게시판에서 찾아서 했으나,
3시 종가 기준(주식) 분봉에서 일봉의 MACD, DIMinus 와 수치가 다르게 나옵니다.
다시 한번 각각의 소스 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2007-07-16 17:32:54
안녕하세요
예스스탁입니다.
분봉에서 일봉의 지수이평과 같은 경우 같이 보는 분봉과 일봉의
날짜를 동일하게 마추어야 같은 값을 보실수 있습니다.
지수이평과 같은 경우에는 20지수이평이라고 해도 차트 첫봉부터 계산되어
영향을 주므로 서로 기간이 같아야 같은 값을 볼 수 있습니다.
예를 들어 5분봉 차트의 첫봉이 4월1일 이라면 일봉차트도 동일하게 4월1일부터
나오게 만드신후 비교하시면 됩니다.
식 2개 올려드립니다.
선물에서 0.01정도의 값차이가 계산상 발생할 수 있습니다.
1. MACD
Input : sPeriod(12),lperiod(26);
Var : sEp(0), sJISU(0), sPreJISU(0),DINDEX(0);
Var : lEp(0), lJISU(0), lPreJISU(0),macdv(0);
sEp = 2/(sPeriod+1);
lEp = 2/(lPeriod+1);
if date != date[1] then {
DINDEX = DINDEX + 1;
sPreJISU = sJISU[1];
lPreJISU = lJISU[1];
}
if DINDEX <= 1 then {
sJISU = dayclose();
lJISU = dayclose();
}
else{
sJISU = dayclose() * sEP + sPreJISU * (1-sEP);
lJISU = dayclose() * lEP + lPreJISU * (1-lEP);
}
MACDv = sJISU-lJISU;
plot1(macdv);
2 DIMinus
Input : DMIPeriod(14);
Var : cnt1(0),cnt2(0),sum1(0),sum2(0),mav1(0),mav2(0),dim(0);
var : DIM1(0);
array : VV[14](0),AA[14](0);
## 분봉에서 일봉의 DiMinus
if date != date[1] then{
for cnt1 = 1 to DMIPeriod-1{
VV[cnt1] = VV[cnt1-1][1];
AA[cnt1] = AA[cnt1-1][1];
}
DIM1 = DIM[1];
}
If daylow(1)-dayLow(0)>0 && dayHigh(0)-dayhigh(1) < dayLow(1)-daylow(0) Then
VV[0] = dayLow(1)-dayLow(0);
Else
VV[0] = 0;
AA[0] = max(dayhigh(0)-dayLow(0),abs(dayClose(1)-dayhigh(0)),abs(dayClose(1)-dayLow(0)));
sum1 = 0;
sum2 = 0;
for cnt2 = 0 to DMIPeriod-1{
sum1 = sum1+VV[cnt2];
sum2 = sum2+AA[cnt2];
}
MAV1 = Sum1/DMIPeriod;
MAV2 = Sum2/DMIPeriod;
DIM = MAV1/mav2*100;
plot1(dim);
즐거운 하루되세요
> postdog 님이 쓴 글입니다.
> 제목 : 분봉에서 일봉 사용하기 질문입니다.
> 5분 5000봉에서
일봉 MACD, DIMinus 를 사용 할 수있는 소스를 게시판에서 찾아서 했으나,
3시 종가 기준(주식) 분봉에서 일봉의 MACD, DIMinus 와 수치가 다르게 나옵니다.
다시 한번 각각의 소스 부탁드립니다.