커뮤니티
분봉에서 일봉 MACD 와 EMA를 표현하려고 합니다.
2019-10-22 12:12:44
113
글번호 133019
안녕하세요.
분봉에서 일봉의 EMA와 MACD를 표현하려고 하는데요.
생각처럼 쉽지가 않네요 ㅜㅜ.
도움 좀 부탁드리겠습니다.
좋은 하루되세요 !
답변 1
예스스탁 예스스탁 답변
2019-10-22 14:08:49
안녕하세요
예스스탁입니다.
지수이평계열은 과거의 값이 봉이 진행되면서 차츰 영향력이 소멸되는 타입니다.
분봉차트에 일봉의 기간이 길지 않으므로 일봉차트의 값과 차이가 있을수 있으므로
최대한 많은 봉을 조회해 적용하셔야 합니다.
1 분봉에서 일봉의 지수이평 5개
Input : P1(5),P2(20),P3(60),P4(120),P5(240);
Var : Ep1(0),emav1(0),Pre1(0),DINDEX(0);
Var : Ep2(0),emav2(0),Pre2(0);
Var : Ep3(0),emav3(0),Pre3(0);
Var : Ep4(0),emav4(0),Pre4(0);
Var : Ep5(0),emav5(0),Pre5(0);
Ep1 = 2/(P1+1);
Ep2 = 2/(P2+1);
Ep3 = 2/(P3+1);
Ep4 = 2/(P4+1);
Ep5 = 2/(P5+1);
if bdate != bdate[1] then {
DINDEX = DINDEX + 1;
Pre1 = emav1[1];
Pre2 = emav2[1];
Pre3 = emav3[1];
Pre4 = emav4[1];
Pre5 = emav5[1];
}
if DINDEX <= 1 then{
emav1 = C;
emav2 = C;
emav3 = C;
emav4 = C;
emav5 = C;
}
else{
emav1 = C * EP1 + Pre1 * (1-EP1);
emav2 = C * EP2 + Pre2 * (1-EP2);
emav3 = C * EP3 + Pre3 * (1-EP3);
emav4 = C * EP4 + Pre4 * (1-EP4);
emav5 = C * EP5 + Pre5 * (1-EP5);
}
plot1(emav1,"P1 일봉지수이평");
plot2(emav2,"P2 일봉지수이평");
plot3(emav3,"P3 일봉지수이평");
plot4(emav4,"P4 일봉지수이평");
plot5(emav5,"P5 일봉지수이평");
2 분봉에서 일봉 MACD
Input : Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDS(0);
var : MACDV(0),MACDS(0),MACDO(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
if bdate != bdate[1] Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDS = MACDS[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
MACDV = JiSu1-Jisu2;
MACDS = MACDV;
MACDO = MACDV-MACDS;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
MACDV = JiSu1-Jisu2;
MACDS = MACDV * EP3 + PreMACDS * (1-EP3);
MACDO = MACDV-MACDS;
}
plot1(MACDV,"MACD");
plot2(MACDs,"Signal");
plot3(MACDo,"osc");
PlotBaseLine1(0);
> 그냥백수 님이 쓴 글입니다.
> 제목 : 분봉에서 일봉 MACD 와 EMA를 표현하려고 합니다.
> 안녕하세요.
분봉에서 일봉의 EMA와 MACD를 표현하려고 하는데요.
생각처럼 쉽지가 않네요 ㅜㅜ.
도움 좀 부탁드리겠습니다.
좋은 하루되세요 !
다음글