커뮤니티
수식작성 부탁 드립니다
2020-03-03 14:48:10
325
글번호 136525
참조 데이타 사용시
선물 10분(5 이평선, 20 이평선)이평 크로스시 매수진입 이라는 진입 조건을 참조 데이타로
사용하면 크로스 발생 신호 다음봉 즉 10분 늦게 신호가 발생 되는것으로 알고 있습니다
선물 2분 이평선에서 단순히 수치를 *5 하여 (25 이평선,100 이평선)을 사용하면 10분(5,20)
이평선과는 다른 모습이 생성됩니다
선물 10분선의(5,20)이평선 크로스를 2분선에서 5개의 봉으로 시가와 종가를 이용 하여
이동평균선을 구하는 수식을 작성 해주시면 감사 하겠습니다.
input : Period1(5),Period2(20);
var1 = data2(ma(C, Period1));
var2 = data2(ma(C, Period2));
if var1 > var2 and 진입조건 then buy("b");
선물 2분 data2로 선물 10분선의 Macd(12,26,9)와 동일한 보조지표가 되도록
작성 부탁 드립니다.
Input : shortPeriod(12), longPeriod(26), signal(9);
Var : value(0,data2) , macdosc(0,data2) ;
value = data2(MACD(shortPeriod, longPeriod));
macdosc = data2(ema(value,signal));
답변 1
예스스탁 예스스탁 답변
2020-03-03 15:24:43
안녕하세요
예스스탁입니다.
1
input : ntime(10),P1(5),P2(20);
var : S1(0),D1(0),TM(0),TF(0),cnt(0);
var : sum1(0),sum11(0),sum2(0),sum21(0);
var : mav1(0),mav11(0),mav2(0),mav21(0);
Array : C1[50](0);
if Bdate != Bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
#10(ntime)봉 이평 계산
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
for cnt = 1 to 49
{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
if C1[P2] > 0 then{
sum1 = 0;
sum11 = 0;
sum2 = 0;
sum21 = 0;
for cnt = 0 to P2
{
if cnt < P1 Then
{
sum1 = sum1+C1[cnt];
sum11 = sum11+C1[cnt+1];
}
if cnt < P2 Then
{
sum2 = sum2+C1[cnt];
sum21 = sum21+C1[cnt+1];
}
}
mav1 = sum1/P1; #10분봉 현재봉 P1이평
mav11 = sum11/P1; #10분봉 전봉 P1이평
mav2 = sum2/P2; #10분봉 현재봉 P2이평
mav21 = sum21/P2; #10분봉 전봉 P2이평
if mav1 > mav2 and mav11 < mav21 and 매수진입조건 Then
buy("b");
if mav1 < mav2 and mav11 > mav21 and 매도진입조건 Then
sell("s");
}
}
2
input : short(12),long(26),sig(9);
input : ntime(10);
var : S1(0),D1(0),TM(0),EP1(0),EP2(0),EP3(0),MACDO(0);
var : TF(0),xma1(0),xma2(0),idx(0),Prexma1(0),Prexma2(0),MACDV(0),MACDS(0),PreMACDS(0);
Ep1 = 2/(short+1);
Ep2 = 2/(long+1);
Ep3 = 2/(sig+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
idx = idx + 1;
Prexma1 = xma1[1];
Prexma2 = xma2[1];
PreMACDS = MACDS[1];
}
if idx <= 1 then {
xma1 = C;
xma2 = C;
MACDV = xma1-xma2;
MACDS = MACDV;
MACDO = MACDV-MACDS;
}
else{
xma1 = C * EP1 + Prexma1 * (1-EP1);
xma2 = C * EP2 + Prexma2 * (1-EP2);
MACDV = xma1-xma2;
MACDS = MACDV * EP3 + PreMACDS * (1-EP3);
MACDO = MACDV-MACDS;
}
plot1(MACDV,"MACD");
plot2(MACDS,"signal");
plot3(MACDO,"Ocs");
}
즐거운 하루되세요
> 뎅이요 님이 쓴 글입니다.
> 제목 : 수식작성 부탁 드립니다
> 참조 데이타 사용시
선물 10분(5 이평선, 20 이평선)이평 크로스시 매수진입 이라는 진입 조건을 참조 데이타로
사용하면 크로스 발생 신호 다음봉 즉 10분 늦게 신호가 발생 되는것으로 알고 있습니다
선물 2분 이평선에서 단순히 수치를 *5 하여 (25 이평선,100 이평선)을 사용하면 10분(5,20)
이평선과는 다른 모습이 생성됩니다
선물 10분선의(5,20)이평선 크로스를 2분선에서 5개의 봉으로 시가와 종가를 이용 하여
이동평균선을 구하는 수식을 작성 해주시면 감사 하겠습니다.
input : Period1(5),Period2(20);
var1 = data2(ma(C, Period1));
var2 = data2(ma(C, Period2));
if var1 > var2 and 진입조건 then buy("b");
선물 2분 data2로 선물 10분선의 Macd(12,26,9)와 동일한 보조지표가 되도록
작성 부탁 드립니다.
Input : shortPeriod(12), longPeriod(26), signal(9);
Var : value(0,data2) , macdosc(0,data2) ;
value = data2(MACD(shortPeriod, longPeriod));
macdosc = data2(ema(value,signal));
다음글
이전글