커뮤니티
안녕하세요
2020-03-05 13:47:15
576
글번호 136601
5분봉에 일봉 볼린밴드(상단선 가운데선 하단선)을
TL함수를 이용해서 수평선으로 표현하고자 합니다.
선 두께 ,색상 조정 가능하게 부탁드립니다.
각수평선 가격데이타를 소수점아래 두자리까지 나타나게 부탁드립니다
kingtrader 버전이라 한글변수는 검증에러 생깁니다
늘 도움 주심에 감사합니다.
답변 1
예스스탁 예스스탁 답변
2020-03-05 14:43:00
안녕하세요
예스스탁입니다.
input : Period(20),Dv(2),width(2),color1(red),color2(GREEN),color3(blue),decimal(2);
var : sum(0),cnt(0),mav(0),SumSqrt(0),Stdv(0);
var : BBup(0),BBdn(0),Counter(0);
var : TL1(0),TL2(0),TL3(0),tX1(0),TX2(0),TX3(0);
If DayClose(Period) > 0 Then
{
sum = 0;
for cnt = 0 to Period-1{
sum = sum + DayClose(cnt);
}
mav = sum/Period;
SumSqrt = 0;
For Counter = 0 To Period - 1
{
SumSqrt = SumSqrt + (DayClose(Counter) - mav)^2;
}
Stdv = SquareRoot(SumSqrt / Period);
BBup = mav + (Dv * Stdv);
BBdn = mav - (Dv * Stdv);
TL_Delete(TL1);
TL_Delete(TL2);
TL_Delete(TL3);
TL1 = TL_New(sdate,stime,bbup,NextBarSdate,NextBarStime,bbup);
TL2 = TL_New(sdate,stime,mav,NextBarSdate,NextBarStime,mav);
TL3 = TL_New(sdate,stime,bbdn,NextBarSdate,NextBarStime,bbdn);
TL_SetExtLeft(TL1,true);
TL_SetExtLeft(TL2,true);
TL_SetExtLeft(TL3,true);
TL_SetSize(TL1,width);
TL_SetSize(TL2,width);
TL_SetSize(TL3,width);
TL_SetColor(TL1,color1);
TL_SetColor(TL2,color2);
TL_SetColor(TL3,color3);
Text_Delete(tX1);
Text_Delete(tX2);
Text_Delete(tX3);
TX1 = Text_New(NextBarSdate,NextBarStime,bbup,NumToStr(bbup,decimal));
TX2 = Text_New(NextBarSdate,NextBarStime,mav,NumToStr(mav,decimal));
TX3 = Text_New(NextBarSdate,NextBarStime,bbdn,NumToStr(bbdn,decimal));
Text_SetColor(TX1,color1);
Text_SetColor(TX2,color2);
Text_SetColor(TX3,color3);
}
즐거운 하루되세요
> CSI300 님이 쓴 글입니다.
> 제목 : 안녕하세요
> 5분봉에 일봉 볼린밴드(상단선 가운데선 하단선)을
TL함수를 이용해서 수평선으로 표현하고자 합니다.
선 두께 ,색상 조정 가능하게 부탁드립니다.
각수평선 가격데이타를 소수점아래 두자리까지 나타나게 부탁드립니다
kingtrader 버전이라 한글변수는 검증에러 생깁니다
늘 도움 주심에 감사합니다.