커뮤니티
문의드립니다.
2020-03-11 17:40:28
277
글번호 136803
5분봉에서 30분봉의 삼각이평( data2 )을 구현하고 싶은데
잘 안됩니다.
부탁합니다.
답변 1
예스스탁 예스스탁 답변
2020-03-12 10:03:14
안녕하세요
예스스탁입니다.
1
data2로 이용하시면 아래와 같습니다.
Input : Length1(5),Length2(20),Length3(60);
Var : TLen1(0,data2),TLen2(0,data2),TLen3(0,data2),Tma1(0,data2),Tma2(0,data2),Tma3(0,data2);
TLen1 = Ceiling((Length1 + 1) * .5);
TLen2 = Ceiling((Length2 + 1) * .5);
TLen3 = Ceiling((Length3 + 1) * .5);
Tma1 = data2(ma(ma(C, TLen1), TLen1));
Tma2 = data2(ma(ma(C, TLen2), TLen2));
Tma3 = data2(ma(ma(C, TLen3), TLen3));
Plot1(Tma1, "삼각가중1");
Plot2(Tma2, "삼각가중2");
Plot3(Tma3, "삼각가중3");
2
기본차트 자체에서 구현하시면 아래와 같습니다.
input : Atime1(30),P1(20),P2(100),P3(240);
var : cnt(0),count(0),TLen1(0),TLen2(0),TLen3(0);
var : sum11(0),sum12(0),sum13(0);
var : sum21(0),sum22(0),sum23(0);
var : Tma1(0),Tma2(0),Tma3(0);
Array : C1[800](0),mav1[800](0),mav2[800](0),mav3[800](0);
TLen1 = Ceiling((P1 + 1) * .5);
TLen2 = Ceiling((P2 + 1) * .5);
TLen3 = Ceiling((P3 + 1) * .5);
var1 = TimeToMinutes(stime)%Atime1;
if Bdate != Bdate[1] or (var1 < var1[1] and Bdate == Bdate[1]) Then{
for cnt = 1 to 129{
C1[cnt] = C1[cnt-1][1];
mav1[cnt] = mav1[cnt-1][1];
mav2[cnt] = mav2[cnt-1][1];
mav3[cnt] = mav3[cnt-1][1];
}
}
C1[0] = C;
sum11 = 0;
sum12 = 0;
sum13 = 0;
for count = 0 to TLen3{
if count < TLen1 Then
sum11 = sum11+C1[count];
if count < TLen2 Then
sum12 = sum12+C1[count];
if count < TLen3 Then
sum13 = sum13+C1[count];
}
if C1[TLen1-1] > 0 Then
mav1[0] = sum11/TLen1;
if C1[TLen2-1] > 0 Then
mav2[0] = sum12/Tlen2;
if C1[TLen3-1] > 0 Then
mav3[0] = sum13/Tlen3;
if mav1[TLen1-1] > 0 Then{
sum21 = 0;
for cnt = 0 to TLen1-1{
sum21 = sum21+mav1[cnt];
}
Tma1 = sum21/TLen1;
plot1(Tma1);
}
if mav2[TLen2-1] > 0 Then{
sum22 = 0;
for cnt = 0 to TLen2-1{
sum22 = sum22+mav2[cnt];
}
Tma2 = sum22/TLen2;
plot2(Tma2);
}
if mav3[TLen3-1] > 0 Then{
sum23 = 0;
for cnt = 0 to TLen3-1{
sum23 = sum23+mav3[cnt];
}
Tma3 = sum23/TLen3;
plot3(Tma3);
}
즐거운 하루되세요
> as8282 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 5분봉에서 30분봉의 삼각이평( data2 )을 구현하고 싶은데
잘 안됩니다.
부탁합니다.