커뮤니티
분봉시스템식에서일봉지표값
2020-03-21 14:18:37
410
글번호 137077
안녕하세요
당일분봉시스템식진입조건에
일봉지표수치를필터링으로사용하고싶습니다
일봉 rsi 값이30이하 ,70이상
아래수식 설명부탁드리고 rsi랑똑같이일봉값을사용할수잇게코딩부탁합니다
Input : Period(20), D(2);
var : Bdown(0),BUp(0),Band(0);
BDown = BollBandDown(Period,D);
BUp = BollBandUp(Period,D);
Band = ((C-BDown)/(BUp-BDown))*100;//주석및 30이하,70이상시 나타내는시장성향
위 두가지일봉지표값이가각30이하 70이상인 선물종목을찾아낼려면
검색식으로사용해야하나요?강조식으로사용해야하나요?
해당식으로코팅부탁합니다
감사합니다
답변 1
예스스탁 예스스탁 답변
2020-03-24 09:18:39
안녕하세요
예스스탁입니다.
1 일봉 RSI
RSI가 차트 과거기간에 영향을 받습니다.
차트의 기간에 따라 일봉차트와 분봉차트의 값이 다를수 있습니다.
Input : Length(9);
var : cnt(0),SigSum(0),count2(0),RSIsig(0);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
var : idx(0), PreUpAvg(0), preDownAvg(0),RSIV(0);
Array : C1[100](0);
if Bdate != Bdate[1] Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
idx = idx + 1;
}
C1[0] = C;
If idx == Length+2 Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1
{
UpAmt = C1[Counter] - C1[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
}
If idx > Length+2 Then
{
UpAmt = C1[0] - C1[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (PreUpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (preDownAvg * (Length - 1) + DownAmt) / Length;
}
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIv,"RSI");
PlotBaseLine1(30, "기준선 30");
PlotBaseLine2(70, "기준선 70");
2 일봉 Band%B
Band%B는 볼린져밴드폭을 기준으로 현재주가의 위치를 백분률로 나타낸 값입니다.
input : Period(20),Dv(2);
var : sum(0),cnt(0),mav(0),SumSqrt(0),Stdv(0);
var : BUp(0),BDown(0),Counter(0),Band(0);
If DayClose(Period) > 0 Then
{
sum = 0;
for cnt = 0 to Period-1{
sum = sum + DayClose(cnt);
}
mav = sum/Period;
SumSqrt = 0;
For Counter = 0 To Period - 1 {
SumSqrt = SumSqrt + (DayClose(Counter) - mav)^2;
}
Stdv = SquareRoot(SumSqrt / Period);
BUp = mav + (Dv * Stdv);
BDown = mav - (Dv * Stdv);
Band = ((C-BDown)/(BUp-BDown))*100;
}
즐거운 하루되세요
> CSI300 님이 쓴 글입니다.
> 제목 : 분봉시스템식에서일봉지표값
> 안녕하세요
당일분봉시스템식진입조건에
일봉지표수치를필터링으로사용하고싶습니다
일봉 rsi 값이30이하 ,70이상
아래수식 설명부탁드리고 rsi랑똑같이일봉값을사용할수잇게코딩부탁합니다
Input : Period(20), D(2);
var : Bdown(0),BUp(0),Band(0);
BDown = BollBandDown(Period,D);
BUp = BollBandUp(Period,D);
Band = ((C-BDown)/(BUp-BDown))*100;//주석및 30이하,70이상시 나타내는시장성향
위 두가지일봉지표값이가각30이하 70이상인 선물종목을찾아낼려면
검색식으로사용해야하나요?강조식으로사용해야하나요?
해당식으로코팅부탁합니다
감사합니다
다음글
이전글