커뮤니티
스토캐스틱및 MACD
2020-06-23 09:57:34
1235
글번호 140052
선물 09시 장시작시 질문드립니다.
분,틱차트에서 전일 움직임과 상관없이, 09시 장시작시 스토캐스틱은 기준선50에서, MACD는 기준선 0에서 부터 시작하도록(즉 기준선에서 출발) 할 수 있나요.
미리 감사드립니다.
답변 1
예스스탁 예스스탁 답변
2020-06-23 15:01:47
안녕하세요
예스스탁입니다.
당일분 데이타만 이용해거 계산되게 작성해 드립니다.
MACD는 기본이 0선기준이라 첫봉을 0으로 시작할수 있지만
스토케스틱은 최고가와 최저가 기준이라
첫봉을 50에서 시작하게할수는 없습니다.
첫봉에서는 첫봉의 고가와 저가 그리고 종가의 위이에 따라 계산됩니다.
1 스토케스틱
Input : Period1(10),Period2(5),Period3(5);
Var : HH(0),LL(0),FK(0),EP1(0),EP2(0),SK(0),SD(0),idx(0);
if Bdate != Bdate[1] Then
idx = 0;
idx = idx+1;
if idx <= Period1 Then{
HH = DayHigh;
LL = DayLow;
}
Else{
HH = highest(H,Period1);
LL = lowest(L,Period1);
}
FK = (Close - LL) / (HH - LL) * 100;
EP1 = 2/(Period2+1);
EP2 = 2/(Period3+1);
if idx == 1 Then{
SK = FK;
SD = SK;
}
Else{
SK = FK * EP1 + SK[1] * (1-EP1);
SD = SK * EP2 + SD[1] * (1-EP2);
}
plot1(SK,"%k");
plot2(SD,"%D");
PlotBaseLine1(20);
PlotBaseLine2(80);
2 MACD
Input : short(12),long(26),sig(9);
Var : Ep1(0),EP2(0),EP3(0),JISU1(0),JISU2(0),MACDV(0),MACDS(0);
Ep1 = 2/(short+1);
Ep2 = 2/(long+1);
Ep3 = 2/(sig+1);
if bdate != bdate[1] then
{
JISU1 = C;
JISU2 = C;
MACDV = Jisu1-jisu2;
MACDS = MACDV;
}
else{
JISU1 = C * EP1 + JISU1[1] * (1-EP1);
JISU2 = C * EP2 + JISU2[1] * (1-EP2);
MACDV = Jisu1-jisu2;
MACDS = MACDV * EP3 + MACDS[1] * (1-EP3);
}
plot1(MACDV,"MACDV");
plot2(MACDS,"MACDsignal");
PlotBaseLine1(0);
즐거운 하루되세요
> 산과바다 님이 쓴 글입니다.
> 제목 : 스토캐스틱및 MACD
> 선물 09시 장시작시 질문드립니다.
분,틱차트에서 전일 움직임과 상관없이, 09시 장시작시 스토캐스틱은 기준선50에서, MACD는 기준선 0에서 부터 시작하도록(즉 기준선에서 출발) 할 수 있나요.
미리 감사드립니다.
다음글
이전글