커뮤니티
틱차트 분차트 표현
2020-08-23 20:55:34
998
글번호 141703
90틱 차트에서 5분봉의 20선과 30분봉의 5선을 같이 표현하고 싶습니다.
답변 1
예스스탁 예스스탁 답변
2020-08-24 16:23:51
안녕하세요
예스스탁입니다.
틱봉에서 분봉의 값은 정확한 값 계산이 불가능합니다.
랭귀지는 봉의 시고저종만 알수 있습니다.
틱봉 중간에 분봉의 경계가 있는 경우가 많은데 하나으 봉의 세분해
특정시간을 값을 알수 없습니다.
아래는 근사값으로 계산되는 지표입니다.
input : ntime1(5),P1(20);
input : ntime2(30),P2(5);
var : S1(0),D1(0),TM(0),TF1(0),TF2(0),cnt(0);
var : sum1(0),mav1(0),sum2(0),mav2(0);
Array : C1[100](0),C2[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%ntime1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime1 > 1 and TF1 < TF1[1]) or
(Bdate == Bdate[1] and ntime1 > 1 and TM >= TM[1]+ntime1) or
(Bdate == Bdate[1] and ntime1 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
if C1[P1-1] > 0 then
{
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1+C1[cnt];
}
mav1 = sum1/P1;
Plot1(mav1);
}
TF2 = TM%ntime2;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime2 > 1 and TF2 < TF2[1]) or
(Bdate == Bdate[1] and ntime2 > 1 and TM >= TM[1]+ntime2) or
(Bdate == Bdate[1] and ntime2 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
if C2[P2-1] > 0 then
{
sum2 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2+C2[cnt];
}
mav2 = sum2/P2;
Plot2(mav2);
}
}
즐거운 하루되세요
> 중추신경 님이 쓴 글입니다.
> 제목 : 틱차트 분차트 표현
> 90틱 차트에서 5분봉의 20선과 30분봉의 5선을 같이 표현하고 싶습니다.
다음글
이전글