커뮤니티
시스템 일봉to 분봉화
2020-09-06 14:11:48
788
글번호 142115
나날이 발전하는 예스트레이더에 감사드리며,
오늘도 좋은 하루 되길 빕니다.
아래의 일봉기준 RVI(relative volatility Index)의 분봉차트에 적용하고자 합니다.
/*------------------*/
input: p50(13),LPercent(20), SPercent(80);
Var: SD10(0), UF(0),DN(0),UE(0), de(0),UM(0), dm(0), rv1(0), rv2(0), rvI1(0), RVI2(0);
SD10=STD(C,10);
UF= IFF(C>C[1], SD10,0);
DN=IFF(C<C[1], SD10,0);
UE=EMA(UF,P50);
DE=EMA(DN,P50);
UM=MA(UF,P50);
DM=MA(DN,P50);
RV1=UM/DM;
RVI1=100-100/(1+RV1);
RV2=UE/DE;
RVI2=100-100/(1+RV2);
# 매수/매도청산
If CrossUP(RVI1, LPercent) Then
{
Buy();
}
# 매도/매수청산
If CrossDown(RVI1, SPercent) Then
{
Sell();
}
/*------------------*/
답변 1
예스스탁 예스스탁 답변
2020-09-08 09:46:47
안녕하세요
예스스탁입니다.
input: stdp(10),p50(13),LPercent(20), SPercent(80);
Var: SD10(0), UF(0),DN(0),UE(0),DE(0),UM(0), dm(0), rv1(0), rv2(0), rvI1(0), RVI2(0);
var : sum(0),cnt(0),cnt1(0),mav(0),SumSqrt(0);
Var : DINDEX(0),Ep(0),UE1(0),DE1(0),std10(0);
var : sum1(0),sum2(0);
If DayClose(stdp) > 0 Then
{
sum = 0;
for cnt = 0 to stdp-1
{
sum = sum + DayClose(cnt);
}
mav = sum/stdp;
SumSqrt = 0;
For cnt = 0 To stdp - 1
{
SumSqrt = SumSqrt + (DayClose(cnt) - mav)^2;
}
SD10 = SquareRoot(SumSqrt / stdp);
UF = IFF(DayClose(0) > DayClose(1), SD10,0);
DN = IFF(DayClose(0) < DayClose(1), SD10,0);
Ep = 2/(p50+1);
if bdate != bdate[1] then
{
DINDEX = DINDEX + 1;
UE1 = UE[1];
DE1 = DE[1];
}
if DINDEX <= 1 then
{
UE = UF;
DE = DN;
}
else
{
UE = UF * EP + UE1* (1-EP);
DE = DN * EP + DE1* (1-EP);
}
RV2=UE/DE;
RVI2=100-100/(1+RV2);
if DayClose(P50+stdp) > 0 Then
{
sum1 = 0;
sum2 = 0;
For cnt = 0 to P50-1
{
sum = 0;
for cnt1 = 0+cnt to stdp-1+cnt
{
sum = sum + DayClose(cnt1);
}
mav = sum/stdp;
SumSqrt = 0;
For cnt1 = 0+cnt To stdp-1+cnt
{
SumSqrt = SumSqrt + (DayClose(cnt1) - mav)^2;
}
std10 = SquareRoot(SumSqrt / stdp);
sum1 = sum1 + IFF(DayClose(cnt) > DayClose(cnt+1), std10,0);
sum2 = sum2 + IFF(DayClose(cnt) < DayClose(cnt+1), std10,0);
}
UM = sum1/P50;
DM = sum2/P50;
RV1 = UM/DM;
RVI1 = 100-100/(1+RV1);
If CrossUP(RVI1, LPercent) Then
{
Buy();
}
If CrossDown(RVI1, SPercent) Then
{
Sell();
}
}
}
즐거운 하루되세요
> 하운드독 님이 쓴 글입니다.
> 제목 : 시스템 일봉to 분봉화
> 나날이 발전하는 예스트레이더에 감사드리며,
오늘도 좋은 하루 되길 빕니다.
아래의 일봉기준 RVI(relative volatility Index)의 분봉차트에 적용하고자 합니다.
/*------------------*/
input: p50(13),LPercent(20), SPercent(80);
Var: SD10(0), UF(0),DN(0),UE(0), de(0),UM(0), dm(0), rv1(0), rv2(0), rvI1(0), RVI2(0);
SD10=STD(C,10);
UF= IFF(C>C[1], SD10,0);
DN=IFF(C<C[1], SD10,0);
UE=EMA(UF,P50);
DE=EMA(DN,P50);
UM=MA(UF,P50);
DM=MA(DN,P50);
RV1=UM/DM;
RVI1=100-100/(1+RV1);
RV2=UE/DE;
RVI2=100-100/(1+RV2);
# 매수/매도청산
If CrossUP(RVI1, LPercent) Then
{
Buy();
}
# 매도/매수청산
If CrossDown(RVI1, SPercent) Then
{
Sell();
}
/*------------------*/