커뮤니티
주봉값
2020-09-06 18:56:52
750
글번호 142116
안녕하세요. 항상 도움 많이 받고 있습니다.
분봉에서 주봉, 일봉의 keltner channel 값을 구하려면 어떻게 하면 될까요?
감사합니다.
답변 1
예스스탁 예스스탁 답변
2020-09-08 09:57:31
안녕하세요
예스스탁입니다.
1 주봉
input : MALEN(10),CONST(0.8),ATRs(0);
var : HH(0),LL(0),cnt(0);
var : sum(0),CENTLINE(0),sumTR(0),ATRV(0),UPPER(0), LOWER(0);
Array : CC[100](0),TH[100](0),TL[100](0);
if DayOfWeek(Bdate) < DayOfWeek(Bdate[1]) Then
{
HH = H;
LL = L;
for cnt = 1 to 99
{
TH[cnt] = TH[cnt-1][1];
TL[cnt] = TL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
}
}
if HH > 0 and H > HH Then
HH = H;
if LL > 0 and L < LL Then
LL = L;
CC[0] = c;
if CC[1] > 0 then
{
TH[0] = max(CC[1],HH);
TL[0] = Min(CC[1],LL);
}
if CC[MALEN-1] > 0 then
{
sum = 0;
for cnt = 0 to MALEN-1
{
sum = sum + CC[cnt];
}
CENTLINE = sum/MALEN;
}
if TH[MALEN-1] > 0 and TL[MALEN-1] > 0 then
{
sumTR = 0;
for cnt = 0 to MALEN-1
{
sumTR = sumTR + (TH[cnt]-TL[cnt]);
}
ATRV = sumTR/MALEN;
UPPER=CENTLINE+(ATRV*CONST);
LOWER=CENTLINE-(ATRV*CONST);
PLOT1(CENTLINE,"CENTLINE");
PLOT2(UPPER,"UPPER");
PLOT3(LOWER,"LOWER");
}
2 일봉
input : MALEN(10),CONST(0.8),ATRs(0);
var : sum(0),CENTLINE(0),UPPER(0),LOWER(0);
var : sumTR(0),TH(0),TL(0),cnt(0),ATRV(0);
sum = 0;
sumTR = 0;
for cnt = 0 to MALEN-1
{
sum = sum + DayClose(cnt);
If DayClose(cnt+1) > DayHigh(cnt) then
TH = DayClose(cnt+1);
else
TH = DayHigh(cnt);
If DayClose(cnt+1) < daylow(cnt) then
TL = DayClose(cnt+1);
else
TL = daylow(cnt);
sumTR = sumTR + (TH-TL);
}
CENTLINE = sum/MALEN;
ATRV = sumTR/MALEN;
UPPER=CENTLINE+(ATRV*CONST);
LOWER=CENTLINE-(ATRV*CONST);
PLOT1(CENTLINE,"CENTLINE");
PLOT2(UPPER,"UPPER");
PLOT3(LOWER,"LOWER");
즐거운 하루되세요
> 롬롬7 님이 쓴 글입니다.
> 제목 : 주봉값
> 안녕하세요. 항상 도움 많이 받고 있습니다.
분봉에서 주봉, 일봉의 keltner channel 값을 구하려면 어떻게 하면 될까요?
감사합니다.
다음글
이전글