커뮤니티
지표 여러개 합치기
2020-09-09 09:54:57
805
글번호 142205
완전 생초보라 문의 드려요..
지표하나로 예를들어 볼린져밴드 , 일목균형표 등을 하나의 수식으로 합치는건
어떻게 하나요? 하나하나 불러올라니 성가시기도 해서요..^^
항상 감사합니다.
답변 1
예스스탁 예스스탁 답변
2020-09-09 15:37:23
안녕하세요
예스스탁입니다.
1
별도로 합치는 기능이 있지는 않습니다.
새로운 이름으로 지표식을 새로 작성하셔야 합니다.
Input : Period(20), MultiD(2);
var : MAv(0),BBup(0),BBdn(0);
MAv = ma(C,Period);
BBup = BollBandUp(Period,MultiD);
BBdn = BollBandDown(Period,MultiD);
Plot1(MAv, "이평");
Plot2(BBup, "상단밴드");
Plot3(BBdn, "하단밴드");
Inputs: TurnLen(9), StdLen(26), PrdLen(52);
Variables: 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
전환선 = (Highest(High, TurnLen) + Lowest(Low, TurnLen)) / 2;
기준선 = (Highest(High, StdLen) + Lowest(Low, StdLen)) / 2;
후행스팬 = Close ;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, PrdLen) + Lowest(Low, PrdLen)) / 2;
Plot1(전환선, "전환선");
Plot2(기준선, "기준선");
Plot3(후행스팬, "후행스팬");
Plot4(선행스팬1,"선행스팬1");
Plot5(선행스팬2, "선행스팬2");
위 2개의 지표식을 합치면 아래와 같습니다.
수식을 합치실때 각수식에서 사용하는 변수나 plot번호등이 겹치지 않게 수정해서 합치셔야 합니다.
아래와 내용으로 지표식 새로 작성하시고 문법검증 후에 f5키를 누르시면 지표속성화면이 나타납니다.
지표속성화면 차트표시탭에서 후행스팬은 수평이동에 -25, 선행스팬1과 선행스팬2는 수평이동에 25를 지정하고
Y축표시는 가격으로 지정해서 식을 저장하신 후에 차트에 적용하시면 됩니다.
Input : Period(20), MultiD(2);
Inputs: TurnLen(9), StdLen(26), PrdLen(52);
Var : 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
var : MAv(0),BBup(0),BBdn(0);
MAv = ma(C,Period);
BBup = BollBandUp(Period,MultiD);
BBdn = BollBandDown(Period,MultiD);
전환선 = (Highest(High, TurnLen) + Lowest(Low, TurnLen)) / 2;
기준선 = (Highest(High, StdLen) + Lowest(Low, StdLen)) / 2;
후행스팬 = Close ;
선행스팬1 = (전환선 + 기준선) / 2 ;
선행스팬2 = (Highest(High, PrdLen) + Lowest(Low, PrdLen)) / 2;
Plot1(MAv, "이평");
Plot2(BBup, "상단밴드");
Plot3(BBdn, "하단밴드");
Plot4(전환선, "전환선");
Plot5(기준선, "기준선");
Plot6(후행스팬, "후행스팬");
Plot7(선행스팬1,"선행스팬1");
Plot8(선행스팬2, "선행스팬2");
즐거운 하루되세요
> 수식쌩짜 님이 쓴 글입니다.
> 제목 : 지표 여러개 합치기
> 완전 생초보라 문의 드려요..
지표하나로 예를들어 볼린져밴드 , 일목균형표 등을 하나의 수식으로 합치는건
어떻게 하나요? 하나하나 불러올라니 성가시기도 해서요..^^
항상 감사합니다.
다음글
이전글