커뮤니티
지표식 문의 드립니다
2020-09-17 11:06:44
850
글번호 142461
틱차트인데 90틱 차트에서
1. 4개의 봉을합쳐 1개의 봉으로 표현할려고 합니다
2. 5개의 봉을합쳐 1개의 봉으로 표현할려고 합니다
3. 4개의 봉을합쳐 1개의 봉으로 표현한 봉에대한 20이평선(MA)을 표현할려고 합니다
감사합니다.
답변 1
예스스탁 예스스탁 답변
2020-09-17 15:17:22
input : n1(4),n2(5),P(20);
var : D1(0),idx(0),TF1(0),TF2(0),cnt(0),sum1(0),mav1(0);
Array : O1[100](0),H1[100](0),L1[100](0),C1[100](0);
Array : O2[100](0),H2[100](0),L2[100](0),C2[100](0);
if Bdate != Bdate[1] Then
{
D1 = sdate;
idx = 0;
}
Else
idx = idx+1;
if D1 > 0 then
{
TF1 = idx%n1;
TF2 = idx%n2;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF1 < TF1[1]) Then
{
O1[0] = O;
H1[0] = H;
L1[0] = L;
for cnt = 1 to 99
{
O1[cnt] = O1[cnt-1][1];
H1[cnt] = H1[cnt-1][1];
L1[cnt] = L1[cnt-1][1];
C1[cnt] = C1[cnt-1][1];
}
}
if H > H1[0] then
H1[0] = H;
if L < L1[0] then
L1[0] = L;
C1[0] = C;
Plot1(O1[0],"n1봉합 시가");
Plot2(H1[0],"n1봉합 고가");
Plot3(L1[0],"n1봉합 저가");
Plot4(C1[0],"n1봉합 종가");
if C1[P-1] > 0 Then
{
sum1 = 0;
For cnt = 0 to P-1
{
sum1 = sum1 + C1[cnt];
}
mav1 = sum1/P;
Plot5(mav1,"이평1");
}
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) Then
{
O2[0] = O;
H2[0] = H;
L2[0] = L;
for cnt = 1 to 99
{
O2[cnt] = O2[cnt-1][1];
H2[cnt] = H2[cnt-1][1];
L2[cnt] = L2[cnt-1][1];
C2[cnt] = C2[cnt-1][1];
}
}
if H > H2[0] then
H2[0] = H;
if L < L2[0] then
L2[0] = L;
C2[0] = C;
Plot6(O2[0],"n2봉합 시가");
Plot7(H2[0],"n2봉합 고가");
Plot8(L2[0],"n2봉합 저가");
Plot9(C2[0],"n2봉합 종가");
}
> 무한대7 님이 쓴 글입니다.
> 제목 : 지표식 문의 드립니다
> 틱차트인데 90틱 차트에서
1. 4개의 봉을합쳐 1개의 봉으로 표현할려고 합니다
2. 5개의 봉을합쳐 1개의 봉으로 표현할려고 합니다
3. 4개의 봉을합쳐 1개의 봉으로 표현한 봉에대한 20이평선(MA)을 표현할려고 합니다
감사합니다.
다음글
이전글