커뮤니티
해선용 양방향 지표 부탁드립니다.
2021-01-26 21:10:13
1221
글번호 145826
지난번에 20이평위 확정봉발생시 매수 매도를 문의드렸었는데
하나의 이평이 아닌 60이평과 5이평 두이평을 모두위로확정봉 발생시
매수하고 두이평 모두 아래로 확정봉 발생이 매도하는데
단순히 매수 청산이 아닌 스위칭으로 주문이 나갈수 있게 부탁드립니다.
답변 2
예스스탁 예스스탁 답변
2021-01-27 11:29:21
안녕하세요
예스스탁입니다.
1 차트가 4시간(240분봉)봉일떄
input : P1(20),P2(60);
var : mav1(0),mav2(0);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
Condition1 = C > mav1 and C > mav2;
Condition2 = C < mav1 and C < mav2;
if Condition1 == true and Condition1[1] == False Then
Buy();
if Condition2 == true and Condition2[1] == False Then
Sell();
2 낮은 주기 차트에서 4시간(240분봉)봉의 이동평균을 계산할 때
input : ntime(240),P1(20),P2(60);
var : S1(0),D1(0),TM(0),TF(0),cnt(0);
var : sum1(0),mav1(0),sum2(0),mav2(0);
var : sum11(0),mav11(0),sum21(0),mav21(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P2] > 0 then
{
sum1 = 0;
sum11 = 0;
sum2 = 0;
sum21 = 0;
for cnt = 0 to P2
{
if cnt < P1 Then
{
sum1 = sum1+CC[cnt];
sum11 = sum11+CC[cnt+1];
}
if cnt < P2 Then
{
sum2 = sum2+CC[cnt];
sum21 = sum21+CC[cnt+1];
}
}
mav1 = sum1/P1;
mav11 = sum11/P1;
mav2 = sum2/P2;
mav21 = sum21/P2;
if (CC[0] > mav1 and CC[1] < mav11 and CC[0] > mav2) or
(CC[0] > mav2 and CC[1] < mav21 and CC[0] > mav1) Then
Buy();
if (CC[0] < mav1 and CC[1] > mav11 and CC[0] < mav2) or
(CC[0] < mav2 and CC[1] > mav21 and CC[0] < mav1) Then
Sell();
}
}
즐거운 하루되세요
> beautyin 님이 쓴 글입니다.
> 제목 : 해선용 양방향 지표 부탁드립니다.
> 지난번에 20이평위 확정봉발생시 매수 매도를 문의드렸었는데
하나의 이평이 아닌 60이평과 5이평 두이평을 모두위로확정봉 발생시
매수하고 두이평 모두 아래로 확정봉 발생이 매도하는데
단순히 매수 청산이 아닌 스위칭으로 주문이 나갈수 있게 부탁드립니다.
beautyin
2021-01-27 14:08:46
빠르고 친절한 답변 항상 감사드립니다^^