커뮤니티
진입청산 설정문의 드립니다.
2021-02-02 06:02:09
743
글번호 146030
이평선매매에서
진입은 30분봉 / 청산은 15분봉
이렇게 달리설정해서 시스템트레이딩가능한지요..
감사합니다.
별도 수식이 있으면 부탁드립니다.
지수이평
진입 : 30분봉 5-10선 (골드/데드)
청산 : 15분봉 5-10선 (골드/데드)
답변 1
예스스탁 예스스탁 답변
2021-02-02 15:53:22
안녕하세요
예스스탁입니다.
15분 차트에서서 30분 지수이평을 별도 계산해서 사용하셔야 전략구현하셔야 합니다.
아래식 참고하시기 바랍니다.
지수이평이 차트 과거봉수에 영향을 받습니다.
차트에 최대한 많은봉 조회하고 적용하시기 바랍니다.
Input : ntime(30),P1(5),P2(10);
var : S1(0),D1(0),TM(0),TF1(0),Ema1(0),Ema2(0);
Var : Ep1(0), JISU1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Ema1 = Ema(C,P1);
Ema2 = Ema(C,P2);
Ep1 = 2/(P1+1);
Ep2 = 2/(P2+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
#타분봉 지수이평 계산
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF1 < TF1[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
value1 = value1+1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
}
if value1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
if CrossUp(JISU1,JISU2) Then
Buy("b");
if CrossDown(JISU1,JISU2) Then
Sell("s");
if MarketPosition == 1 and CrossDown(Ema1,Ema2) Then
ExitLong("bx");
if MarketPosition == -1 and CrossUp(Ema1,Ema2) Then
ExitShort("sx");
}
즐거운 하루되세요
> 유샘 님이 쓴 글입니다.
> 제목 : 진입청산 설정문의 드립니다.
> 이평선매매에서
진입은 30분봉 / 청산은 15분봉
이렇게 달리설정해서 시스템트레이딩가능한지요..
감사합니다.
별도 수식이 있으면 부탁드립니다.
지수이평
진입 : 30분봉 5-10선 (골드/데드)
청산 : 15분봉 5-10선 (골드/데드)
다음글
이전글