커뮤니티
부탁드립니다.
2021-03-19 10:19:51
944
글번호 147239
안녕하세요...글번호 71442의수식중. 30분봉의수식을 60분 90분 120분 150분 차트별로
사용하고져 합니다.
71442의 30분봉의 모든수식을60분봉수식으로 변해주시면 그것을보고
제가90분120분150분을 만들려고 함니다.
1번에서58번수식을 그대로 있는 상태로 59번에서72번까지 60분봉의수식으로
만들어주시길 부탁드립니다.
수고하세요...꾸벅
답변 1
예스스탁 예스스탁 답변
2021-03-19 14:24:02
안녕하세요
예스스탁입니다.
plot은 plo99까지만 제공됩니다.
plot갯수문제로 다른주기를 계속 추가하기는 어렵습니다.
var : HH(0),LL(0),H1(0),L1(0);
var : NO(0),NH(0),NL(0),NH1(0),NL1(0),NC(0),NC1(0);
var : DO(0),DH(0),DL(0),DC(0),DO1(0),DH1(0),DL1(0),DC1(0),DC2(0),DO2(0);
var : DH2(0),DL2(0);
if DayOfWeek(bdate) < DayOfWeek(bdate[1]) Then
{
HH = H;
LL = L;
H1 = HH[1];
L1 = LL[1];
}
if stime >= 90000 and stime < 180000 then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
}
if stime == 90000 or (stime > 90000 and stime[1] < 90000) Then{
NH1 = NH[1];
NL1 = NL[1];
NC1 = NC[1];
DO = O;
DH = H;
DL = L;
DC = C;
DO1 = DO[1];
DH1 = DH[1];
DL1 = DL[1];
DC1 = DC[1];
DC2 = DC1[1];
DO2 = DO1[1];
DH2 = DH1[1];
DL2 = DL1[1];
}
if stime == 180000 or (stime > 180000 and stime[1] < 180000) Then{
NO = O;
NH = H;
NL = L;
NC = C;
}
if stime >= 180000 or stime < 90000 then{
if H > NH Then
NH = H;
if L < NL Then
NL = L;
NC = C;
}
if stime >= 90000 and stime < 180000 then{
if H > DH Then
DH = H;
if L < DL Then
DL = L;
DC = C;
}
if H1 > 0 and L1 > 0 Then{
plot1(H1,"전주주간장고점");
plot2(L1,"전주주간장저점");
plot3((H1+L1)/2,"전주주간장중심");
}
if stime >= 090000 and stime < 180000 then{
plot4(dayhigh(1),"전일고점");
plot5(daylow(1),"전일저점");
plot6((DayHigh(1)+daylow(1))/2,"전일중심");
plot7(DayOpen(1),"전일시가");
plot8(DayClose(1),"전일종가");
}
if NH1 > 0 and NL1 > 0 Then{
plot9(NH1,"전일야간고점");
plot10(NL1,"전일야간저점");
plot11((NH1+NL1)/2,"전일야간중심");
plot12(NC,"전일야간종가");
}
plot13(DayOpen(0),"당일시가");
plot14(DayClose(0),"당일종가");
plot15(dayhigh(0),"당일고점");
plot16(daylow(0),"당일저점");
plot17(daylow+(dayhigh-daylow)*0.875 ,"87.5");
plot18(daylow+(dayhigh-daylow)*0.750 ,"75.0");
plot19(daylow+(dayhigh-daylow)*0.618 ,"61.8");
plot20(daylow+(dayhigh-daylow)*0.500 ,"50.0");
plot21(daylow+(dayhigh-daylow)*0.382 ,"38.2");
plot22(daylow+(dayhigh-daylow)*0.250 ,"25.0");
plot23(daylow+(dayhigh-daylow)*0.125 ,"12.5");
if DO1 > 0 and DH1 > 0 and DL1 > 0 and DC1 > 0 Then{
if stime >= 090000 and stime < 180000 then{
plot24(DO1,"전일주간시가");
plot25(DH1,"전일주간고점");
plot26(DL1,"전일주간저점");
plot27(DC1,"전일주간종가");
plot28((DH1+DL1)/2,"전일주간장고점 + 전일주간장저점)/2");
plot29(DC1+PriceScale*2,"전일주간장종가 + 2틱");
Plot30(DC1-PriceScale*2,"전일주간장종가 - 2틱");
plot31(NC1+PriceScale*2,"전일야간장종가 + 2틱");
plot32(NC1-PriceScale*2,"전일야간장종가 - 2틱");
}
}
if NO > 0 Then{
plot41(NO,"당일야간시가");
plot42(NH,"당일야간고가");
plot43(NL,"당일야간저가");
plot44(NC,"당일야간종가");
}
if stime >= 180000 or stime < 90000 then{
plot51(DC,"주간장종가");
}
plot52(DH,"주간장고가");
plot53(DL,"주간장저가");
plot54(DC2,"전전일주간장종가");
plot55(DO2,"전전일주간장시가");
plot56((dayopen(0)+DayClose(1))/2,"시가갭중심라인");
plot57(DH2,"전전일주간장고가");
plot58(DH2,"전전일주간장저가");
input : a분(30),b분(60);
var : S1(0),D1(0),TM(0);
var : aTF(0),aMM(0),aMO(0),aMH(0),aML(0),aMC(0),apreMO(0),apreMH(0),apreML(0),apreMC1(0),apreMC2(0);
var : aMHH(0),aMLL(0),apreMHH(0),apreMLL(0),aMH1(0),aML1(0);
var : bTF(0),bMM(0),bMO(0),bMH(0),bML(0),bMC(0),bpreMO(0),bpreMH(0),bpreML(0),bpreMC1(0),bpreMC2(0);
var : bMHH(0),bMLL(0),bpreMHH(0),bpreMLL(0),bMH1(0),bML1(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
#30분
aTF = TM%a분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and a분 > 1 and aTF < aTF[1]) or
(Bdate == Bdate[1] and a분 > 1 and TM >= TM[1]+a분) or
(Bdate == Bdate[1] and a분 == 1 and TM > TM[1]) Then
{
if Bdate != Bdate[1] Then
aMM = 0;
aMM = aMM+1;
aMO = O;
aMH = 0;
aML = 0;
apreMO = amo[1];
apreMH = amh[1];
apreML = aml[1];
apreMC1 = amc[1];
apreMC2 = apreMC1[1];
aMHH = 0;
aMLL = 0;
apreMHH = aMHH[1];
apreMLL = aMLL[1];
}
if C > O and (aMH == 0 or (aMH > 0 and C > aMH)) Then
aMH = C;
if C < O and (aML == 0 or (aML > 0 and C < aML)) Then
aML = C;
aMC = C;
if aMHH == 0 or (aMHH > 0 and H > aMHH) Then
aMHH = H;
if aMLL == 0 or (aMLL > 0 and L < aMLL) Then
aMLL = L;
if aMM == 1 Then
{
aMH1 = aMH;
aML1 = aML;
}
plot59((apreMH+apreML)/2);
plot60((aMH1+aML1)/2);
plot61(apreMO);
plot62(apreMH);
plot63(apreML);
plot64(apreMC1);
if aMH > 0 Then
plot65(aMH);
if aML > 0 Then
plot66(aML);
plot67(apreMC2);
plot68(aMO);
Plot69(aMHH);
Plot70(aMLL);
Plot71(aPreMHH);
Plot72(apreMLL);
#60분
bTF = TM%b분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and b분 > 1 and bTF < bTF[1]) or
(Bdate == Bdate[1] and b분 > 1 and TM >= TM[1]+b분) or
(Bdate == Bdate[1] and b분 == 1 and TM > TM[1]) Then
{
if Bdate != Bdate[1] Then
bMM = 0;
bMM = bMM+1;
bMO = O;
bMH = 0;
bML = 0;
bpreMO = bmo[1];
bpreMH = bmh[1];
bpreML = bml[1];
bpreMC1 = bmc[1];
bpreMC2 = bpreMC1[1];
bMHH = 0;
bMLL = 0;
bpreMHH = bMHH[1];
bpreMLL = bMLL[1];
}
if C > O and (bMH == 0 or (bMH > 0 and C > bMH)) Then
bMH = C;
if C < O and (bML == 0 or (bML > 0 and C < bML)) Then
bML = C;
bMC = C;
if bMHH == 0 or (bMHH > 0 and H > bMHH) Then
bMHH = H;
if bMLL == 0 or (bMLL > 0 and L < bMLL) Then
bMLL = L;
if bMM == 1 Then
{
bMH1 = bMH;
bML1 = bML;
}
plot73((bpreMH+bpreML)/2);
plot74((bMH1+bML1)/2);
plot75(bpreMO);
plot76(bpreMH);
plot77(bpreML);
plot78(bpreMC1);
if bMH > 0 Then
plot79(bMH);
if bML > 0 Then
plot80(bML);
plot81(bpreMC2);
plot82(bMO);
Plot83(bMHH);
Plot84(bMLL);
Plot85(bPreMHH);
Plot86(bpreMLL);
}
즐거운 하루되세요
> 보인다 님이 쓴 글입니다.
> 제목 : 부탁드립니다.
> 안녕하세요...글번호 71442의수식중. 30분봉의수식을 60분 90분 120분 150분 차트별로
사용하고져 합니다.
71442의 30분봉의 모든수식을60분봉수식으로 변해주시면 그것을보고
제가90분120분150분을 만들려고 함니다.
1번에서58번수식을 그대로 있는 상태로 59번에서72번까지 60분봉의수식으로
만들어주시길 부탁드립니다.
수고하세요...꾸벅
다음글
이전글