커뮤니티
매수식 시뮬레이션 문의
2021-03-27 14:30:28
1151
글번호 147445
안녕하세요.
시뮬레이션 차트로 기법을 검증해 보고 싶어서 문의 드립니다.
조건 1. 일봉 5일선 위
2. 60분봉 10이평선 위에 캔들위치시
5분봉 10이평선 매수(손절 30틱 또는 5분봉 20이평선)
(익절 5분봉 2연속 음봉)
수고하세요^^
답변 1
예스스탁 예스스탁 답변
2021-03-29 14:46:59
안녕하세요
예스스탁입니다.
5분봉 차트에 적용하시면 됩니다.
5분봉 차트에서 일봉, 60분봉이평 계산해서 진입하게 됩니다.
input : dayp(5),ntime(60),Period(10),P1(10),P2(20);
var : S1(0),D1(0),TM(0),TF(0),cnt(0);
var : sum1(0),mav1(0),dsum(0),dmav(0);
Array : CC[100](0);
dsum = 0;
For cnt = 0 to dayp-1
{
dsum = dsum + DayClose(cnt);
}
dmav = dsum/dayp;
var1 = ma(c,P1);
var2 = ma(c,P2);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[Period-1] > 0 then
{
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1+CC[cnt];
}
mav1 = sum1/Period;
if C > dmav and C > mav1 and CrossUp(c,var1) Then
Buy();
}
if MarketPosition == 1 Then
{
if CrossDown(c,Var2) Then
ExitLong();
if CountIf(C<O,2) == 2 Then
exitlong();
}
}
SetStopLoss(PriceScale*30,PointStop);
즐거운 하루되세요
> 부활 님이 쓴 글입니다.
> 제목 : 매수식 시뮬레이션 문의
> 안녕하세요.
시뮬레이션 차트로 기법을 검증해 보고 싶어서 문의 드립니다.
조건 1. 일봉 5일선 위
2. 60분봉 10이평선 위에 캔들위치시
5분봉 10이평선 매수(손절 30틱 또는 5분봉 20이평선)
(익절 5분봉 2연속 음봉)
수고하세요^^
다음글
이전글