커뮤니티
수식 과 퓨처스챔피언 수식입니다.
2021-04-10 12:00:33
1103
글번호 147875
퓨처스챔피언에서 하이킨 아시 수식과 적용법과 고점과 저점을 잇는 지그재그 수식도 알려주시면 감사하겠습니다.
만약에 예스트레이더에서 해야한다면 어떻게 적용하고 퓨처스챔피언에서는 어떻게 적용하나요?
답변 1
예스스탁 예스스탁 답변
2021-04-12 11:30:18
안녕하세요
예스스탁입니다.
퓨쳐스챔피언은 저희회사의 프로그램이 아니라서
해당 프로그램에 대해서는 아는 부분이 없습니다.
예스트레이더 수식으로 작성해 드립니다.
아래식 강조식으로 작성해 차트에 적용하시면 됩니다.
수식 작성법등은 예스랭귀지 도움말 참고하시기 바랍니다.
Input : length(10),종가사용여부(0),수치표시(1),표시(0);
input : 추세두께(0),추세상승색(red),추세하락색(blue);
input : 고점연결두께(3),고점연결색상(LGREEN);
input : 저점연결두께(3),저점연결색상(MAGENTA);
Var:j(0),jj(0),HH(0),LL(0),최종고가(0),최종저가(0),최종꼭지점(""),처리구분(""),
TL1(0),Text1(0),TL11(0),TL12(0);
Array:고[10,4](0),저[10,4](0); // 1:가격,2:Index,3:sDate,4:sTime
var : xClose(0),xOpen(0),xHigh(0),xLow(0);
#Heiken Ashi 시고저종
if index == 0 then
{
xOpen = open;
xClose = (O+H+L+C)/4;
xHigh = MaxList( high, xOpen, xClose);
xLow = MinList( low, xOpen,xClose);
}
else
{
xClose = (O+H+L+C)/4;
xOpen = (xOpen [1] + xClose [1])/2 ;
xHigh = MaxList(High, xOpen, xClose) ;
xLow = MinList(Low, xOpen, xClose) ;
}
if XClose > Xopen Then
PlotPaintBar(Xhigh,Xlow,"강조",MAGENTA);
else if XClose < Xopen Then
PlotPaintBar(Xhigh,Xlow,"강조",CYAN);
else
PlotPaintBar(Xhigh,Xlow,"강조",GREEN);
HH = xHigh;
LL = xLow;
If Index == 0 Then
{
고[1,1] = HH;
저[1,1] = LL;
}
Condition1 = Highest(HH,length) == HH and 최종고가 <> HH;
Condition2 = Lowest (LL,length) == LL and 최종저가 <> LL;
처리구분 = "";
If Condition1 and Condition2 Then // 기간고점과 기간저점 동시 발생
{
If 최종꼭지점 == "저점" Then
{
If 저[1,1] > LL Then 처리구분 = "저점처리";
Else 처리구분 = "고점처리";
}
Else If 최종꼭지점 == "고점" Then
{
If 고[1,1] < HH Then 처리구분 = "고점처리";
Else 처리구분 = "저점처리";
}
}
Else If Condition1 Then 처리구분 = "고점처리";
Else If Condition2 Then 처리구분 = "저점처리";
#==========================================#
If 처리구분 == "고점처리" Then
{
최종고가 = HH; // 신규고점을 체크하기 위해 저장
If 최종꼭지점 == "저점" Then
{
For j = 10 DownTo 2
{
For jj = 1 To 4
{
고[j,jj] = 고[j-1,jj];
}
}
고[1,1] = HH;
고[1,2] = Index;
고[1,3] = sDate;
고[1,4] = sTime;
TL1 = TL_New(저[1,3],저[1,4],저[1,1],고[1,3],고[1,4],고[1,1]);
TL_SetSize(TL1,추세두께);
TL_SetColor(TL1,추세상승색);
}
Else If 고[1,1] < HH Then // 1번 고점보다 높은 고가 출현
{
고[1,1] = HH;
고[1,2] = Index;
고[1,3] = sDate;
고[1,4] = sTime;
TL_SetEnd(TL1,고[1,3],고[1,4],고[1,1]);
}
최종꼭지점 = "고점";
}
If 처리구분 == "저점처리" Then
{
최종저가 = LL;
If 최종꼭지점 == "고점" then
{
For j = 10 DownTo 2
{
For jj = 1 To 4
{
저[j,jj] = 저[j-1,jj];
}
}
저[1,1] = LL;
저[1,2] = Index;
저[1,3] = sDate;
저[1,4] = sTime;
TL1 = TL_New(고[1,3],고[1,4],고[1,1],저[1,3],저[1,4],저[1,1]);
TL_SetSize(TL1,추세두께);
TL_SetColor(TL1,추세하락색);
}
Else If 저[1,1] > LL then
{
저[1,1] = LL;
저[1,2] = Index;
저[1,3] = sDate;
저[1,4] = sTime;
TL_SetEnd(TL1,저[1,3],저[1,4],저[1,1]);
}
최종꼭지점 = "저점";
}
즐거운 하루되세요
> kingritu 님이 쓴 글입니다.
> 제목 : 수식 과 퓨처스챔피언 수식입니다.
> 퓨처스챔피언에서 하이킨 아시 수식과 적용법과 고점과 저점을 잇는 지그재그 수식도 알려주시면 감사하겠습니다.
만약에 예스트레이더에서 해야한다면 어떻게 적용하고 퓨처스챔피언에서는 어떻게 적용하나요?