커뮤니티
산식검토
2021-06-16 14:24:04
1133
글번호 149975
아래는 분봉에서 일봉이평을 구현하기위한 산식입니다
5일,10일,20일 이평을 구현하려고 했는데 처음부터 벽에 부딪히네요
분봉에서 하루전체가 직선으로 표현이 않돼서 질문합니다
수정부탁드립니다
Input : P1(5),P2(10),P3(20);
var : Count(0), SumV(0),mav(0);
sumv =0 ;
For Count = 0 to P1-1 {
sumv = sumv+DayClose(count);
}
Mav =sumv / P1 ;
Plot1(Mav,"일평");
답변 1
예스스탁 예스스탁 답변
2021-06-16 16:16:47
안녕하세요
예스스탁입니다.
1
분봉에서 당일값이 포함되면 차트에 수평으로 그려지지 않습니다.
input : P1(5),P2(10),P3(20);
var : cnt(0);
var : sumV1(0),sumV2(0),sumV3(0);
var : mav1(0),mav2(0),mav3(0);
sumV1 = 0;
sumV2 = 0;
sumV3 = 0;
for cnt = 0 to P3
{
if cnt < P1 Then
sumV1 = sumV1+DayClose(cnt);
if cnt < P2 Then
sumV2 = sumV2+DayClose(cnt);
if cnt < P3 Then
sumV3 = sumV3+DayClose(cnt);
}
maV1 = sumV1 / P1;
maV2 = sumV2 / P2;
maV3 = sumV3 / P3;
plot1(mav1);
plot2(mav2);
plot3(mav3);
2
전일기준으로 그리시면 아래와 같습니다.
input : P1(5),P2(10),P3(20);
var : cnt(0);
var : sumV1(0),sumV2(0),sumV3(0);
var : mav1(0),mav2(0),mav3(0);
sumV1 = 0;
sumV2 = 0;
sumV3 = 0;
for cnt = 1 to P3
{
if cnt <= P1 Then
sumV1 = sumV1+DayClose(cnt);
if cnt <= P2 Then
sumV2 = sumV2+DayClose(cnt);
if cnt <= P3 Then
sumV3 = sumV3+DayClose(cnt);
}
maV1 = sumV1 / P1;
maV2 = sumV2 / P2;
maV3 = sumV3 / P3;
plot1(mav1);
plot2(mav2);
plot3(mav3);
3
일반 지표출력함수인 plot으로는 현재시점값을 과거에 드리지 못합니다.
만약 당일값을 차트에 수평으로 그리고자 하시면 추세선함수를 이용하셔야 합니다.
다만 추세선 함수가 봉완성시(다음봉시가수신)에만 동작해서
차트 마지막봉기준으로는 그리지 못합니다.
차트의 마지막완성봉기준으로 그리는 식입니다.
input : P1(5),P2(10),P3(20);
var : cnt(0);
var : sumV1(0),sumV2(0),sumV3(0);
var : mav1(0),mav2(0),mav3(0);
var : TL1(0),TL2(0),TL3(0);
sumV1 = 0;
sumV2 = 0;
sumV3 = 0;
for cnt = 0 to P3
{
if cnt < P1 Then
sumV1 = sumV1+DayClose(cnt);
if cnt < P2 Then
sumV2 = sumV2+DayClose(cnt);
if cnt < P3 Then
sumV3 = sumV3+DayClose(cnt);
}
maV1 = sumV1 / P1;
maV2 = sumV2 / P2;
maV3 = sumV3 / P3;
TL_Delete(TL1);
TL_Delete(TL2);
TL_Delete(TL3);
TL1 = TL_New(sDate,sTime,mav1,NextBarSdate,NextBarStime,mav1);
TL2 = TL_New(sDate,sTime,mav2,NextBarSdate,NextBarStime,mav2);
TL3 = TL_New(sDate,sTime,mav3,NextBarSdate,NextBarStime,mav3);
TL_SetExtLeft(TL1,true);
TL_SetExtLeft(TL2,true);
TL_SetExtLeft(TL3,true);
TL_SetExtRight(TL1,true);
TL_SetExtRight(TL2,true);
TL_SetExtRight(TL3,true);
TL_SetColor(TL1,RED);
TL_SetColor(TL2,BLUE);
TL_SetColor(TL3,GREEN);
즐거운 하루되세요
> 티끌 님이 쓴 글입니다.
> 제목 : 산식검토
> 아래는 분봉에서 일봉이평을 구현하기위한 산식입니다
5일,10일,20일 이평을 구현하려고 했는데 처음부터 벽에 부딪히네요
분봉에서 하루전체가 직선으로 표현이 않돼서 질문합니다
수정부탁드립니다
Input : P1(5),P2(10),P3(20);
var : Count(0), SumV(0),mav(0);
sumv =0 ;
For Count = 0 to P1-1 {
sumv = sumv+DayClose(count);
}
Mav =sumv / P1 ;
Plot1(Mav,"일평");
다음글
이전글