커뮤니티
문의합니다.
2021-06-24 23:24:12
1532
글번호 150266
Input : Period1(100),Period2(100);
var: upk(0);
upk = (highest(H,period1) + lowest(L,period2))/2;
Plot1(upk);
--------------------------------------
15분봉에서 쓰고 있는 지표인데요.
15분봉의 지표결과를 3분봉에 나오게 하고 싶습니다.
부탁드려요. 감사합니다.
답변 1
예스스탁 예스스탁 답변
2021-06-25 09:45:39
안녕하세요
예스스탁입니다.
3분봉 차트에서 15분봉의 100봉에 해당하는 값을 계산할만큰 데이타가 충분해야 지표가 출력됩니다.
전략실행차트의 최대 봉갯수가 1만개 봉이므로 가능한 최대로 조회하시고 적용하시기 바랍니다.
input : ntime(15),Period1(100),Period2(100);
var : S1(0),D1(0),TM(0),TF(0),cnt(0);
var : sum1(0),mav1(0),sum2(0),mav2(0),hv(0),lv(0),upk(0);
Array : HH[100](0),LL[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime > 1 and TM >= TM[1]+ntime) or
(Bdate == Bdate[1] and ntime == 1 and TM > TM[1]) Then
{
hh[0] = h;
ll[0] = l;
for cnt = 1 to 99
{
hh[cnt] = hh[cnt-1][1];
ll[cnt] = ll[cnt-1][1];
}
}
if hh[0] > 0 and h > hh[0] Then
hh[0] = h;
if ll[0] > 0 and l < ll[0] Then
ll[0] = l;
if hh[Period1-1] > 0 and ll[Period2-1] > 0 then
{
hv = hh[0];
lv = ll[0];
for cnt = 0 to max(Period1,Period2)-1
{
if cnt < Period1 and hh[cnt] > hv Then
hv = hh[cnt];
if cnt < Period2 and ll[cnt] < lv Then
lv = ll[cnt];
}
upk = (hv+lv)/2;
Plot1(upk);
}
}
즐거운 하루되세요
> Argo 님이 쓴 글입니다.
> 제목 : 문의합니다.
> Input : Period1(100),Period2(100);
var: upk(0);
upk = (highest(H,period1) + lowest(L,period2))/2;
Plot1(upk);
--------------------------------------
15분봉에서 쓰고 있는 지표인데요.
15분봉의 지표결과를 3분봉에 나오게 하고 싶습니다.
부탁드려요. 감사합니다.