커뮤니티
타주기참조식
2021-07-14 08:36:08
950
글번호 150730
예를 들어 5분봉 챠트에서 60분봉 지표를 나타내고자 합니다
즉, 60분봉에서 볼린저밴드 상단보다 클경우 지표식을 5분봉 챠트에 나타나게 하고자 합니다
반대로 60분봉에서 볼린저밴드 하단보다 작을경우 지표식을 5분봉 챠트에 나타내고자 하는 지표식을 구합니다
감사합니다
답변 1
예스스탁 예스스탁 답변
2021-07-14 11:06:00
안녕하세요
예스스탁입니다.
input : 타주기분(60),P(20),Dv(2);
var : S1(0),D1(0),TM(0),TF(0),T(0);
var : cnt(0),SumSqrt(0),Stdv(0);
var : sum(0),BBmd(0),Bbup(0),BBdn(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P] > 0 then
{
sum = 0;
for cnt = 0 to P-1{
sum = sum + CC[cnt];
}
BBmd = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1 {
SumSqrt = SumSqrt + (CC[cnt] - BBmd)^2;
}
Stdv = SquareRoot(SumSqrt / P);
BBup = BBmd + (Dv * Stdv);
BBdn = BBmd - (Dv * Stdv);
if C > BBup Then
T = 1;
else if C < BBdn Then
T = -1;
Else
T = 0;
Plot1(T);
}
}
즐거운 하루되세요
> 느림보 님이 쓴 글입니다.
> 제목 : 타주기참조식
> 예를 들어 5분봉 챠트에서 60분봉 지표를 나타내고자 합니다
즉, 60분봉에서 볼린저밴드 상단보다 클경우 지표식을 5분봉 챠트에 나타나게 하고자 합니다
반대로 60분봉에서 볼린저밴드 하단보다 작을경우 지표식을 5분봉 챠트에 나타내고자 하는 지표식을 구합니다
감사합니다