커뮤니티
Range bar로 매매
2021-12-16 16:30:22
662
글번호 154566
안녕하세요
수식지왕님의 Range bar 차트 수식이 있는데요(첨부파일),
이 Range bar를 참고해서 매매가 가능한가요?
ex) Range bar가 양봉이 연속으로 3개 뜨면 매수 진입
- 1. Range_Bar.yin (0.01 MB)
답변 1
예스스탁 예스스탁 답변
2021-12-17 10:31:21
안녕하세요
예스스탁입니다.
올리신 수식에 CC와 OO배열변수에 시가와 종가가
순차적으로 저장되고 있습니다.
for문으로 n개방의 값을 가져와 비교해 조건지정하시면 됩니ㅏㄷ.
Input:tick(20);
Var:j(0),k(0),n(0),trend(0),tickVal(0),oneTick(0),count(0),remain(0);
Array:OO[1000](0),HH[1000](0),LL[1000](0),CC[1000](0),val[4](0);
#==============================================================================#
# Range Bar Chart 계산
#==============================================================================#
If Index == 0 Then
{
tickVal = tick * PriceScale;
oneTick = PriceScale;
OO[0] = O;
HH[0] = O;
LL[0] = O;
CC[0] = O;
}
count = 0;
val[0] = O;
val[3] = C;
If O > C Then
{
val[1] = H;
val[2] = L;
If L < C Then trend = 1;
Else trend = -1;
}
Else If O < C Then
{
val[1] = L;
val[2] = H;
If H > C Then trend = -1;
Else trend = 1;
}
Else If C[1] > O Then
{
val[1] = L;
val[2] = H;
If H > C Then trend = -1;
Else trend = 1;
}
Else If C[1] < O Then
{
val[1] = H;
val[2] = L;
If L < C Then trend = 1;
Else trend = -1;
}
Else If trend == 1 Then
{
val[1] = H;
val[2] = L;
If L < C Then trend = 1;
Else trend = -1;
}
Else If trend == -1 Then
{
val[1] = L;
val[2] = H;
If H > C Then trend = -1;
Else trend = 1;
}
For k = 0 To 3
{
If HH[0] > 0 && HH[0] < val[k] Then
{
While val[k] - LL[0] > tickVal
{
HH[0] = LL[0] + tickVal;
CC[0] = HH[0];
For j = 998 DownTo 0
{
OO[j+1] = OO[j];
HH[j+1] = HH[j];
LL[j+1] = LL[j];
CC[j+1] = CC[j];
}
count = count + 1;
OO[0] = HH[1] + oneTick;
LL[0] = OO[0];
}
If val[k] - LL[0] <= tickVal Then
{
HH[0] = val[k];
CC[0] = val[k];
}
}
Else If LL[0] > val[k] Then
{
While HH[0] - val[k] > tickVal
{
LL[0] = HH[0] - tickVal;
CC[0] = LL[0];
For j = 998 DownTo 0
{
OO[j+1] = OO[j];
HH[j+1] = HH[j];
LL[j+1] = LL[j];
CC[j+1] = CC[j];
}
count = count + 1;
OO[0] = LL[1] - oneTick;
HH[0] = OO[0];
}
If HH[0] - val[k] <= tickVal Then
{
LL[0] = val[k];
CC[0] = val[k];
}
}
Else
{
CC[0] = val[k];
}
}
input : x(3);
var : ii(0), 양봉연속갯수(0),음봉연속갯수(0);
양봉연속갯수 = 0;
음봉연속갯수 = 0;
For ii = 0 to x-1
{
if CC[ii] > OO[ii] Then
양봉연속갯수 = 양봉연속갯수+1;
if CC[ii] < OO[ii] Then
음봉연속갯수 = 음봉연속갯수+1;
}
if 양봉연속갯수 == x Then
Buy();
if 음봉연속갯수 == x Then
sell();
즐거운 하루되세요
> 이만스닥 님이 쓴 글입니다.
> 제목 : Range bar로 매매
> 안녕하세요
수식지왕님의 Range bar 차트 수식이 있는데요(첨부파일),
이 Range bar를 참고해서 매매가 가능한가요?
ex) Range bar가 양봉이 연속으로 3개 뜨면 매수 진입
다음글
이전글