커뮤니티
지표식구합니다
2022-01-15 17:11:46
1173
글번호 155477
일봉의 일목균형표를 틱봉에 표시하는 지표식과
60분봉의 일목균형표를 틱봉에 표시하는 지표식을 구합니다
감사합니다
답변 1
예스스탁 예스스탁 답변
2022-01-17 10:05:58
안녕하세요
예스스탁입니다.
1
Input : 전환선기간(9), 기준선기간(26), 선행스팬2기간(52);
Var : 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
var : cnt(0),H1(0),L1(0),H11(0),L11(0),H2(0),L2(0),H22(0),L22(0),H3(0),L3(0);
H1 = dayhigh(0);
L1 = daylow(0);
H11 = dayhigh(25);
L11 = daylow(25);
H2 = dayhigh(0);
L2 = daylow(0);
H22 = dayhigh(25);
L22 = daylow(25);
H3 = dayhigh(25);
L3 = daylow(25);
for cnt = 0 to 선행스팬2기간-1
{
if cnt < 전환선기간 Then
{
if dayhigh(cnt) > H1 Then
H1 = dayhigh(cnt);
if daylow(cnt) < L1 Then
L1 = DayLow(cnt);
if dayhigh(cnt+25) > H11 Then
H11 = dayhigh(cnt+25);
if daylow(cnt+25) < L11 Then
L11 = DayLow(cnt+25);
}
if cnt < 기준선기간 Then
{
if dayhigh(cnt) > H2 Then
H2 = dayhigh(cnt);
if daylow(cnt) < L2 Then
L2 = DayLow(cnt);
if dayhigh(cnt+25) > H22 Then
H22 = dayhigh(cnt+25);
if daylow(cnt+25) < L22 Then
L22 = DayLow(cnt+25);
}
if dayhigh(cnt+25) > H3 Then
H3 = dayhigh(cnt+25);
if DayLow(cnt+25) < L3 Then
L3 = DayLow(cnt+25);
}
전환선 = (H1 + L1)/2;
기준선 = (H2 + L2) / 2;
선행스팬1 = ( (H11+L11)/2 + (H22+L22)/2) / 2 ;
선행스팬2 = (H3+L3) / 2;
plot1(전환선);
plot2(기준선);
plot3(선행스팬1);
plot4(선행스팬2);
2
input : ntime1(60);
input : 전환선기간(9),기준선기간(26),선행스팬2기간(52);
var : TF(0),S1(0),D1(0),TM(0),cnt(0);
var : H1(0),L1(0),H11(0),L11(0),H2(0),L2(0),H22(0),L22(0),H3(0),L3(0);
var : 전환선(0),기준선(0),선행스팬1(0),선행스팬2(0);
Array : HH[100](0),LL[100](0);
if Bdate != Bdate[1] Then{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime1 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime1 > 1 and TM >= TM[1]+ntime1) or
(Bdate == Bdate[1] and ntime1 == 1 and TM > TM[1]) Then
{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if HH[선행스팬2기간+25] > 0 and LL[선행스팬2기간+25] > 0 then
{
H1 = HH[0];
L1 = LL[0];
H11 = HH[25];
L11 = LL[25];
H2 = HH[0];
L2 = LL[0];
H22 = HH[25];
L22 = LL[25];
H3 = HH[25];
L3 = LL[25];
for cnt = 0 to 선행스팬2기간-1{
if cnt < 전환선기간 Then{
if HH[cnt] > H1 Then
H1 = HH[cnt];
if LL[cnt] < L1 Then
L1 = LL[cnt];
if HH[cnt+25] > H11 Then
H11 = HH[cnt+25];
if LL[cnt+25] < L11 Then
L11 = LL[cnt+25];
}
if cnt < 기준선기간 Then{
if HH[cnt] > H2 Then
H2 = HH[cnt];
if LL[cnt] < L2 Then
L2 = LL[cnt];
if HH[cnt+25] > H22 Then
H22 = HH[cnt+25];
if LL[cnt+25] < L22 Then
L22 = LL[cnt+25];
}
if HH[cnt+25] > H3 Then
H3 = HH[cnt+25];
if LL[cnt+25] < L3 Then
L3 = LL[cnt+25];
}
전환선 = (H1 + L1)/2;
기준선 = (H2 + L2)/2;
선행스팬1 = ((H11+L11)/2 + (H22+L22)/2) / 2 ;
선행스팬2 = (H3+L3) / 2;
plot1(전환선);
plot2(기준선);
plot3(선행스팬1);
plot4(선행스팬2);
}
}
즐거운 하루되세요
> 느림보 님이 쓴 글입니다.
> 제목 : 지표식구합니다
>
일봉의 일목균형표를 틱봉에 표시하는 지표식과
60분봉의 일목균형표를 틱봉에 표시하는 지표식을 구합니다
감사합니다