커뮤니티
지표 부탁드립니다
2022-03-19 23:20:53
1219
글번호 157315
안녕하세요
일목균형표의 모든 수식은 계속 이어져 화면에 표시되고 있는것으로 알고 있습니다.
그래서 당일 시작하는 시간의 상품에 맞춰 일목균형표가 시작되는것을 한번 적용해보고
싶습니다.
(예 국선 9시, 나스닥 7시, 항셍 10시 15분)
틱챠트든 분챠트든 처음에는 안나오겠지요~
답변 1
예스스탁 예스스탁 답변
2022-03-21 13:53:13
안녕하세요
예스스탁입니다.
항셍과 같이 별도시간을 하루의 시작으로 보는 경우에는 2번수식과 같이
별도로 시간을 지정하셔야 합니다.
1
var : 전환선(0),기준선(0),후행스팬(0),선행스팬1(0),선행스팬2(0);
var : idx(0);
if CurrentDate == sDate Then
{
if Bdate != Bdate[1] Then
idx = 0;
idx = idx+1;
if idx >= 9 Then
{
전환선 = (highest(H,9)+lowest(L,9))/2;
Plot1(전환선, "전환선");
}
Else
NoPlot(1);
if idx >= 26 Then
{
기준선 = (highest(H,26)+lowest(L,26))/2;
선행스팬1 = (전환선+기준선)/2;
Plot2(기준선, "기준선");
Plot3(선행스팬1, "선행스팬1");
}
Else
{
NoPlot(2);
NoPlot(3);
}
if idx >= 52 Then
{
선행스팬2 = (highest(H,52)+lowest(L,52))/2;
Plot4(선행스팬2, "선행스팬2");
}
Else
NoPlot(4);
후행스팬 = C;
Plot5(후행스팬, "후행스팬");
FixPlotShift(3,25);
FixPlotShift(4,25);
FixPlotShift(5,-25);
}
2
input : ntime(101500);
var : 전환선(0),기준선(0),후행스팬(0),선행스팬1(0),선행스팬2(0);
var : idx(0),Tcond(False);
if CurrentDate == sDate Then
{
if (sdate != sdate[1] and stime >= ntime) or
(sdate == sdate[1] and stime >= ntime and stime[1] < ntime) Then
{
idx = 0;
Tcond = true;
}
if Tcond == true Then
idx = idx+1;
if idx >= 9 Then
{
전환선 = (highest(H,9)+lowest(L,9))/2;
Plot1(전환선, "전환선");
}
Else
NoPlot(1);
if idx >= 26 Then
{
기준선 = (highest(H,26)+lowest(L,26))/2;
선행스팬1 = (전환선+기준선)/2;
Plot2(기준선, "기준선");
Plot3(선행스팬1, "선행스팬1");
}
Else
{
NoPlot(2);
NoPlot(3);
}
if idx >= 52 Then
{
선행스팬2 = (highest(H,52)+lowest(L,52))/2;
Plot4(선행스팬2, "선행스팬2");
}
Else
NoPlot(4);
후행스팬 = C;
Plot5(후행스팬, "후행스팬");
FixPlotShift(3,25);
FixPlotShift(4,25);
FixPlotShift(5,-25);
}
즐거운 하루되세요
> 라몬 님이 쓴 글입니다.
> 제목 : 지표 부탁드립니다
> 안녕하세요
일목균형표의 모든 수식은 계속 이어져 화면에 표시되고 있는것으로 알고 있습니다.
그래서 당일 시작하는 시간의 상품에 맞춰 일목균형표가 시작되는것을 한번 적용해보고
싶습니다.
(예 국선 9시, 나스닥 7시, 항셍 10시 15분)
틱챠트든 분챠트든 처음에는 안나오겠지요~