커뮤니티
문의 드립니다.~~~~
2022-07-03 16:48:43
1626
글번호 160383
첨부 이미지
그림1
항상 감사합니다.
-전저점 대비 a틱(변수)이상 상승 후 b틱(변수)이상
하락시 고점처리 ( 챠트에 저점과 고점을 차이 틱수를 고점에 출력하고
저점과 고점을 연결하는 추세선(빨강)그림 )
-전고점 대비 b틱(변수)이상 하락 후 a틱(변수)이상
상승시 저점 처리( 챠트에 고점과 저점의 차이 차이 틱수를 저점에 출력하고
고점과 저점을 연결하는 추세선(파랑)그림)
-매수진입: 저점 형성후 전고점을 돌파하여 전고점대비 c틱(변수) 상승지점에서
매수 진입.
-매도진입: 고점 형성후 전저점을 돌파하여 전저점대비 c틱(변수) 하락지점에서
매도 진입.
- 장중 내내 위 진입을 계속 반복하는 수식 부탁드립니다.
- 1. 진입로직.JPG (0.13 MB)
답변 1
예스스탁 예스스탁 답변
2022-07-04 15:07:49
안녕하세요
예스스탁입니다.
올리신 내용에 기준이 되는 고점과 저점 판단에 대한 내용이 없습니다.
게시판에 많이 사용되는 지그재그 식을 이용해 작성해 드립니다.
input:length(5),a틱(10),b틱(10),c틱(5);
Var:j(0),lastHiVal(0),lastLoVal(0),sBar(0),eBar(0),TL1(0),Text1(0),process(0),T(0);
Array:HH[10,2](0),LL[10,2](0);
process = 0;
If Highest(H,length) == H and lastHiVal <> H and Lowest(L,length) == L and lastLoVal <> L Then
{
If LL[1,1] > L Then process = -1;
If HH[1,1] < H Then process = 1;
}
Else If Highest(H,length) == H and lastHiVal <> H Then process = 1;
Else If Lowest(L,length) == L and lastLoVal <> L Then process = -1;
If process == 1 Then
{
T = 1;
lastHiVal = H;
If HH[1,2] < LL[1,2] Then
{
For j = 10 DownTo 2
{
HH[j,1] = HH[j-1,1];
HH[j,2] = HH[j-1,2];
}
}
If HH[1,2] < LL[1,2] or HH[1,1] < H Then
{
HH[1,1] = H;
HH[1,2] = Index;
sBar = Index - LL[1,2];
eBar = 0;
If TL_GetBeginDate(TL1) == sDate[sBar] and TL_GetBeginTime(TL1) == sTime[sBar] Then
{
TL_Delete(TL1);
Text_Delete(Text1);
}
if LL[1,1] > 0 Then
{
TL1 = TL_New(sDate[sBar],sTime[sBar],LL[1,1],sDate[eBar],sTime[eBar],HH[1,1]);
Text1 = Text_New(sDate[eBar],sTime[eBar],HH[1,1],"+"+NumToStr(abs(HH[1,1]-LL[1,1])/PriceScale,0));
Text_SetStyle(Text1, 2, 1);
}
Else
{
Text_Delete(text1);
Text1 = Text_New(sDate[eBar],sTime[eBar],HH[1,1],"+"+NumToStr(abs(HH[1,1]-LL[1,1])/PriceScale,2));
Text_SetStyle(Text1, 2, 1);
}
Text_SetStyle(Text1, 2, 1);
}
if MarketPosition <= 0 and
HH[2,1] >= LL[2,1]+PriceScale*a틱 and
LL[1,1] <= HH[2,1]-PriceScale*b틱 Then
Buy("b",AtStop,HH[2,1]+PriceScale*c틱);
}
If process == -1 Then
{
T = -1;
lastLoVal = L;
If LL[1,2] < HH[1,2] Then
{
For j = 10 DownTo 2
{
LL[j,1] = LL[j-1,1];
LL[j,2] = LL[j-1,2];
}
}
If LL[1,2] < HH[1,2] or LL[1,1] > L Then
{
LL[1,1] = L;
LL[1,2] = Index;
sBar = Index - HH[1,2];
eBar = 0;
If TL_GetBeginDate(TL1) == sDate[sBar] and TL_GetBeginTime(TL1) == sTime[sBar] Then
{
TL_Delete(TL1);
Text_Delete(Text1);
}
if HH[1,1] > 0 Then
{
TL1 = TL_New(sDate[sBar],sTime[sBar],HH[1,1],sDate[eBar],sTime[eBar],LL[1,1]);
Text1 = Text_New(sDate[eBar],sTime[eBar],LL[1,1],"-"+NumToStr(abs(HH[1,1]-LL[1,1])/PriceScale,0));
Text_SetStyle(Text1, 2, 0);
}
Else
{
Text_Delete(text1);
Text1 = Text_New(sDate[eBar],sTime[eBar],LL[1,1],"-"+NumToStr(abs(HH[1,1]-LL[1,1])/PriceScale,0));
Text_SetStyle(Text1, 2, 0);
}
}
if MarketPosition >= 0 and
LL[2,1] <= HH[2,1]-PriceScale*a틱 and
HH[1,1] >= LL[2,1]+PriceScale*b틱 Then
Sell("s",AtStop,LL[2,1]-PriceScale*c틱);
}
즐거운 하루되세요
> 예스요 님이 쓴 글입니다.
> 제목 : 문의 드립니다.~~~~
> 항상 감사합니다.
-전저점 대비 a틱(변수)이상 상승 후 b틱(변수)이상
하락시 고점처리 ( 챠트에 저점과 고점을 차이 틱수를 고점에 출력하고
저점과 고점을 연결하는 추세선(빨강)그림 )
-전고점 대비 b틱(변수)이상 하락 후 a틱(변수)이상
상승시 저점 처리( 챠트에 고점과 저점의 차이 차이 틱수를 저점에 출력하고
고점과 저점을 연결하는 추세선(파랑)그림)
-매수진입: 저점 형성후 전고점을 돌파하여 전고점대비 c틱(변수) 상승지점에서
매수 진입.
-매도진입: 고점 형성후 전저점을 돌파하여 전저점대비 c틱(변수) 하락지점에서
매도 진입.
- 장중 내내 위 진입을 계속 반복하는 수식 부탁드립니다.