커뮤니티
종가파라볼릭 피보나치
2022-08-13 20:39:27
1099
글번호 161488
첨부 이미지
그림1
"당일"시작하는 종가파라볼릭을 기준으로하여, 당일 당시 최고가(변동적)에서 -1P 이내는 무시하고 -1P보다 더 아래에서 시작하는 하락 종가파라볼릭이 생기면, 생길 때마다 그 하락파라의 상단을 당일 최고가로부터 61.8%로 간주하고 아래로 추가 38.2% 되는 지점을 상승파라가 생길 때까지 일자그래프로 표시.
또 같은 그 하락파라 상단을 50% 지점이라 가정하고 아래로 추가 50% 되는 지점을 하나 더 표시.
-1P 아래 조건을, -0.85P (소수점 두자리) 아래로, 이런 식으로도 변경 가능하게 부탁드립니다.
가능하다면 38.2% 지점 1틱 밑과, 50% 지점 1틱 밑에 라인 하나씩 더 추가해서 (총4개) 채우기 기능으로 보고 싶습니다. 채우기를 하면 봉이 잘 보이고, 채우기를 안하면 라인에 봉이 가려집니다.
- 1. 162254_111.png (0.09 MB)
답변 1
예스스탁 예스스탁 답변
2022-08-16 11:43:10
안녕하세요
예스스탁입니다.
Input : AF(0.02), AFMAX(0.2),pt(1);
Var : Direction(0), SAR_Value(Close), AF_Value(.02), HighValue(High), LowValue(Low), EP(0),CSarv(0);
var : box(0);
if Index == 0 or (Bdate != Bdate[1]) Then
{
Direction = 0;
SAR_Value = C;
AF_Value = 0.02;
HighValue = H;
LowValue = L;
EP = 0;
}
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = low;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = High;
}
}
CSarv = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
CSarv = SAR_Value;
}
else
{
if Direction == 0 then
{
if Close > Close[1] then Direction = 1;
else
if Close < Close[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if Close < Close[1] then
{
Direction = -1;
SAR_Value = HighValue;
CSarv = SAR_Value;
}
}
if Direction == -1 then
{
if Close > Close[1] then
{
Direction = 1;
SAR_Value = LowValue;
CSarv = SAR_Value;
}
}
}
LowValue = min(Low, LowValue);
HighValue = max(High, HighValue);
}
}
if Bdate != Bdate[1] Then
Condition1 = False;
if CrossUp(c,CSarv) Then
Condition1 = False;
if CrossDown(c,CSarv) Then
{
if CSarv <= DayHigh-pt Then
{
Condition1 = true;
var1 = CSarv;
Var2 = (DayHigh-var1)/618;
var3 = DayHigh-Var2*1000;
Var4 = var1-(DayHigh-var1);
}
}
Plot1(CSarv);
if Condition1 == true Then
{
if C < CSarv Then
{
plot2(Var3);
plot3(Var3-PriceScale);
}
Else
{
NoPlot(2);
NoPlot(3);
}
if C < CSarv Then
{
plot4(Var4);
plot5(Var4-PriceScale);
}
Else
{
NoPlot(4);
NoPlot(5);
}
}
Else
{
NoPlot(2);
NoPlot(3);
NoPlot(4);
NoPlot(5);
}
즐거운 하루되세요
> 고성 님이 쓴 글입니다.
> 제목 : 종가파라볼릭 피보나치
> "당일"시작하는 종가파라볼릭을 기준으로하여, 당일 당시 최고가(변동적)에서 -1P 이내는 무시하고 -1P보다 더 아래에서 시작하는 하락 종가파라볼릭이 생기면, 생길 때마다 그 하락파라의 상단을 당일 최고가로부터 61.8%로 간주하고 아래로 추가 38.2% 되는 지점을 상승파라가 생길 때까지 일자그래프로 표시.
또 같은 그 하락파라 상단을 50% 지점이라 가정하고 아래로 추가 50% 되는 지점을 하나 더 표시.
-1P 아래 조건을, -0.85P (소수점 두자리) 아래로, 이런 식으로도 변경 가능하게 부탁드립니다.
가능하다면 38.2% 지점 1틱 밑과, 50% 지점 1틱 밑에 라인 하나씩 더 추가해서 (총4개) 채우기 기능으로 보고 싶습니다. 채우기를 하면 봉이 잘 보이고, 채우기를 안하면 라인에 봉이 가려집니다.