커뮤니티
문의드립니다.
2022-10-06 13:16:51
899
글번호 162765
선물차트 기준으로 문의드립니다.
1. 1개 캔들의 몸통안에(시가와 종가사이에) -티론중간선(기간값50)과 삼각가중평균선(100선)-
이 모두 들어있는 캔들을 검색하고자 합니다. 검색이 불가하다면 강조로 하고자 합니다.
수식을 어떻게 작성해야 하는지요?
tirone levels의 기간값과 삼각가중평균선의 기간값은 수정가능하게 부탁드립니다.
그리고 검색이나 강조의 색상도 수정가능하게 부탁드립니다.(색상수정이 불가하다면 형광색으로 부탁드립니다.)
2. 위 1번에서 검색(또는 강조)된 캔들이 만약 100틱차트의 캔들이라면 이 캔들에 해당하는 50틱차트에서의 캔들을 검색 또는 강조할 수 있는지요? 가능하다면 수식을 부탁드립니다.
항상 감사드립니다. 수고하세요!!!
답변 1
예스스탁 예스스탁 답변
2022-10-06 17:02:04
안녕하세요
예스스탁입니다.
1
검색, 강조 모두 가능합니다.
1-1 검색식
input : Period(50),Length(100);
var : Hval(0),Lval(0),UPV(0),MID(0),dnv(0);
Var : TLen(0),Tma(0);
Hval = highest(H,Period);
Lval = Lowest(L,Period);
UPV = Hval - (Hval-Lval)/3;
MID = Lval + (Hval-Lval)/2;
DNV = Lval + (Hval-Lval)/3;
TLen = Ceiling((Length + 1) * .5);
Tma = ma(ma(C, TLen), TLen);
if max(C,O) >= max(MID,Tma) and min(MID,Tma) >= min(C,O) Then
Plot1(H,"검색",Pink);
1-2 강조식
input : Period(50),Length(100);
var : Hval(0),Lval(0),UPV(0),MID(0),dnv(0);
Var : TLen(0),Tma(0);
Hval = highest(H,Period);
Lval = Lowest(L,Period);
UPV = Hval - (Hval-Lval)/3;
MID = Lval + (Hval-Lval)/2;
DNV = Lval + (Hval-Lval)/3;
TLen = Ceiling((Length + 1) * .5);
Tma = ma(ma(C, TLen), TLen);
if max(C,O) >= max(MID,Tma) and min(MID,Tma) >= min(C,O) Then
PlotPaintBar(H,L,"강조",Pink);
2
50틱 차트에서 100틱값 계산해서 사용하셔야 합니다.
50틱에서 100틱은 두배이므로 N을 2로 지정하시면 됩니다.
2-1
input : N(2),Period(50),Length(100);
var : Hval(0),Lval(0),UPV(0),MID(0),dnv(0);
Var : TLen(0),Tma(0),idx(0),cnt(0),TF(0),sum(0);
Array : HH[200](0),LL[200](0),CC[200](0),mav[200](0);
if bdate != Bdate[1] Then
{
idx = 0;
}
Else
idx = idx+1;
TF = idx%N;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
For cnt = 199 DownTo 1
{
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
CC[cnt] = CC[cnt-1];
mav[cnt] = mav[cnt-1];
}
HH[0] = H;
LL[0] = L;
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if HH[Period-1] > 0 and LL[Period-1] > 0 Then
{
Hval = HH[0];
Lval = LL[0];
For cnt = 1 to Period-1
{
if HH[cnt] > Hval Then
Hval = HH[cnt];
if LL[cnt] < Lval Then
Lval = LL[cnt];
}
UPV = Hval - (Hval-Lval)/3;
MID = Lval + (Hval-Lval)/2;
DNV = Lval + (Hval-Lval)/3;
}
TLen = Ceiling((Length + 1) * 0.5);
if CC[TLen-1] > 0 Then
{
sum = 0;
For cnt = 0 to TLen-1
{
sum = sum + CC[cnt];
}
mav[0] = sum/Tlen;
}
if mav[TLen-1] > 0 Then
{
sum = 0;
For cnt = 0 to TLen-1
{
sum = sum + mav[cnt];
}
Tma = sum/Tlen;
}
if Mid > 0 and Tma > 0 and
max(C,O) >= max(MID,Tma) and min(MID,Tma) >= min(C,O) Then
Plot1(H,"검색",Pink);
2-2
input : N(2),Period(50),Length(100);
var : Hval(0),Lval(0),UPV(0),MID(0),dnv(0);
Var : TLen(0),Tma(0),idx(0),cnt(0),TF(0),sum(0);
Array : HH[200](0),LL[200](0),CC[200](0),mav[200](0);
if bdate != Bdate[1] Then
{
idx = 0;
}
Else
idx = idx+1;
TF = idx%N;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) Then
{
For cnt = 199 DownTo 1
{
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
CC[cnt] = CC[cnt-1];
mav[cnt] = mav[cnt-1];
}
HH[0] = H;
LL[0] = L;
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if HH[Period-1] > 0 and LL[Period-1] > 0 Then
{
Hval = HH[0];
Lval = LL[0];
For cnt = 1 to Period-1
{
if HH[cnt] > Hval Then
Hval = HH[cnt];
if LL[cnt] < Lval Then
Lval = LL[cnt];
}
UPV = Hval - (Hval-Lval)/3;
MID = Lval + (Hval-Lval)/2;
DNV = Lval + (Hval-Lval)/3;
}
TLen = Ceiling((Length + 1) * 0.5);
if CC[TLen-1] > 0 Then
{
sum = 0;
For cnt = 0 to TLen-1
{
sum = sum + CC[cnt];
}
mav[0] = sum/Tlen;
}
if mav[TLen-1] > 0 Then
{
sum = 0;
For cnt = 0 to TLen-1
{
sum = sum + mav[cnt];
}
Tma = sum/Tlen;
}
if Mid > 0 and Tma > 0 and
max(C,O) >= max(MID,Tma) and min(MID,Tma) >= min(C,O) Then
PlotPaintBar(H,L,"강조",Pink);
즐거운 하루되세요
> 해암 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 선물차트 기준으로 문의드립니다.
1. 1개 캔들의 몸통안에(시가와 종가사이에) -티론중간선(기간값50)과 삼각가중평균선(100선)-
이 모두 들어있는 캔들을 검색하고자 합니다. 검색이 불가하다면 강조로 하고자 합니다.
수식을 어떻게 작성해야 하는지요?
tirone levels의 기간값과 삼각가중평균선의 기간값은 수정가능하게 부탁드립니다.
그리고 검색이나 강조의 색상도 수정가능하게 부탁드립니다.(색상수정이 불가하다면 형광색으로 부탁드립니다.)
2. 위 1번에서 검색(또는 강조)된 캔들이 만약 100틱차트의 캔들이라면 이 캔들에 해당하는 50틱차트에서의 캔들을 검색 또는 강조할 수 있는지요? 가능하다면 수식을 부탁드립니다.
항상 감사드립니다. 수고하세요!!!
다음글
이전글