커뮤니티
타주기분 지표식 부탁드립니다.
2022-10-24 14:29:55
1177
글번호 163234
아래의 지표식을 타주기분(15분)으로 변경 부탁드립니다
===========================
input : RSIPeriod(14),Period(14),K(3),D(3);
var : RSIV(0),StoRsi(0);
var : StoK(0),StoD(0);
RSIv = RSI(RSIPeriod);
StoRsi = (RSIv- lowest(RSIv,Period)) / ( highest(RSIv,Period)-lowest(RSIv,Period) ) *100 ;
StoK = ma(StoRsi,K);
StoD = ma(StoK,D);
Plot1(StoK, "StoRsiK");
Plot2(StoD, "StoRsiD");
PlotBaseLine1(20, "기준선 20");
PlotBaseLine2(80, "기준선 80");
PlotBaseLine3(50, "기준선 50");
답변 1
예스스탁 예스스탁 답변
2022-10-25 10:10:08
안녕하세요
예스스탁입니다.
Input : 타주기분(15), RSIPeriod(14),Period(14),K(3),D(3);
var : cnt(0),S1(0),D1(0),TM(0),TF(0);
var : SigSum(0),count2(0),RSIsig(0);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
var : idx(0), PreUpAvg(0), preDownAvg(0),HH(0),LL(0),sum1(0),sum2(0);
Array : C1[100](0),RSIV[100](-1),StoRsi[100](-1),Stok[100](-1),StoD[100](-1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
RSIv[cnt] = RSIv[cnt-1][1];
StoRsi[cnt] = StoRsi[cnt-1][1];
Stok[cnt] = Stok[cnt-1][1];
Stod[cnt] = Stod[cnt-1][1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
idx = idx + 1;
}
C1[0] = C;
If idx == RSIPeriod+2 Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To RSIPeriod - 1 {
UpAmt = C1[Counter] - C1[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / RSIPeriod;
DownAvg = DownSum / RSIPeriod;
}
If idx > RSIPeriod+2 Then {
UpAmt = C1[0] - C1[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else {
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (PreUpAvg * (RSIPeriod - 1) + UpAmt) / RSIPeriod;
DownAvg = (preDownAvg * (RSIPeriod - 1) + DownAmt) / RSIPeriod;
}
If UpAvg + DownAvg <> 0 Then
RSIv[0] = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv[0] = 0;
if RSIV[Period-1] >= 0 Then
{
hh = RSIV[0];
LL = RSIV[0];
For cnt = 0 to Period-1
{
if RSIV[cnt] > hh Then
hh = RSIV[cnt];
if RSIV[cnt] < ll Then
ll = RSIV[cnt];
}
StoRsi[0] = (RSIv[0]- LL) / (HH-LL) *100 ;
}
if StoRsi[K-1] >= 0 Then
{
sum1 = 0;
For cnt = 0 to K-1
{
sum1 = sum1 + StoRsi[cnt];
}
stok[0] = sum1/K;
plot1(stok[0],"stoRSIK");
}
if Stok[D-1] >= 0 Then
{
sum2 = 0;
For cnt = 0 to D-1
{
sum2 = sum2 + StoK[cnt];
}
stod[0] = sum2/d;
plot2(stoD[0],"stoRSID");
}
PlotBaseLine1(20, "기준선 20");
PlotBaseLine2(80, "기준선 80");
PlotBaseLine3(50, "기준선 50");
}
즐거운 하루되세요
> 당일선물 님이 쓴 글입니다.
> 제목 : 타주기분 지표식 부탁드립니다.
> 아래의 지표식을 타주기분(15분)으로 변경 부탁드립니다
===========================
input : RSIPeriod(14),Period(14),K(3),D(3);
var : RSIV(0),StoRsi(0);
var : StoK(0),StoD(0);
RSIv = RSI(RSIPeriod);
StoRsi = (RSIv- lowest(RSIv,Period)) / ( highest(RSIv,Period)-lowest(RSIv,Period) ) *100 ;
StoK = ma(StoRsi,K);
StoD = ma(StoK,D);
Plot1(StoK, "StoRsiK");
Plot2(StoD, "StoRsiD");
PlotBaseLine1(20, "기준선 20");
PlotBaseLine2(80, "기준선 80");
PlotBaseLine3(50, "기준선 50");
다음글
이전글