커뮤니티
지표 질문입니다
2022-10-27 21:43:54
975
글번호 163337
첨부 이미지
그림1
전일과 분리되어 당일부터 시작되는 종가 파라볼릭이 양전환되면 이번 바닥에서 직전 양전환시 상승폭과 직전 음전환시 하락폭 2배를 플러스한 위치를 표시한다. 파라볼릭이 음전환되면 이번 천정에서 직전 음전환시 하락폭과 직전 양전환시 상승폭 2배를 마이너스한 위치를 표시한다.
감사합니다
- 1. 2022.10.27-2.png (0.02 MB)
답변 1
예스스탁 예스스탁 답변
2022-10-28 11:10:46
안녕하세요
예스스탁입니다.
Input : AF(0.02), AFMAX(0.2);
Var : Direction(0), SAR_Value(Close), AF_Value(.02), HighValue(High), LowValue(Low), EP(0);
var : CSarv(0);
if Bdate != Bdate[1] Then
{
Direction = 0;
SAR_Value = c;
AF_Value = 0.02;
HighValue = H;
LowValue = L;
EP = 0;
}
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = low;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = High;
}
}
CSarv = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
CSarv = SAR_Value;
}
else
{
if Direction == 0 then
{
if Close > Close[1] then Direction = 1;
else
if Close < Close[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if Close < Close[1] then
{
Direction = -1;
SAR_Value = HighValue;
CSarv = SAR_Value;
}
}
if Direction == -1 then
{
if Close > Close[1] then
{
Direction = 1;
SAR_Value = LowValue;
CSarv = SAR_Value;
}
}
}
LowValue = min(Low, LowValue);
HighValue = max(High, HighValue);
}
}
var : diff1(0),diff2(0),diff3(0);
if CrossUp(C,CSarv) Then
{
var1 = CSarv;
var2 = var1[1];
diff1 = abs(var1-Var2);
diff2 = diff1[1];
diff3 = diff2[1];
value1 = var2-diff3-diff2*2;
}
if CrossDown(C,CSarv) Then
{
var1 = CSarv;
var2 = var1[1];
diff1 = abs(var1-Var2);
diff2 = diff1[1];
diff3 = diff2[1];
value2 = var2+diff3+diff2*2;
}
Plot1(CSarv,"당일종가파라",iff(C>CSarv,Red,Blue));
Plot2(value1);
plot3(Value2);
즐거운 하루되세요
> para 님이 쓴 글입니다.
> 제목 : 지표 질문입니다
> 전일과 분리되어 당일부터 시작되는 종가 파라볼릭이 양전환되면 이번 바닥에서 직전 양전환시 상승폭과 직전 음전환시 하락폭 2배를 플러스한 위치를 표시한다. 파라볼릭이 음전환되면 이번 천정에서 직전 음전환시 하락폭과 직전 양전환시 상승폭 2배를 마이너스한 위치를 표시한다.
감사합니다
다음글
이전글