커뮤니티
수식 부탁 드립니다.
2023-03-16 13:04:46
1090
글번호 167233
안녕하세요?
지표식 분의 드립니다.
1.20일 atr 가격표시
2.20일 atr 2배수 가격 표시
3.당일가격 포함 20일 atr 가격표시
4.당일 가격 포함 atr 20일 2배수 가격 표시
5.당일고가 + 20일atr"H" 로 표시 후 빨간색으로 가격 표시
6.당일저가 - 20일 atr "L"로 표시후 파란색 으로 가격 표시
40일 60일 100일 등으로도 변환 가능 할수 있으니 표시 부탁 합니다.
atr 첫번째 봉을 날짜로 지정도 가능 한가요?
0시 기준
오전 8시 기준등.
답변 1
예스스탁 예스스탁 답변
2023-03-16 16:33:18
안녕하세요
예스스탁입니다.
1
input : Period(20);
var : cnt(0),TH(0),TL(0),TR(0);
var : sumTR(0),ATRV(0);
var : sumTR1(0),ATRV1(0);
sumTR = 0;
sumTR1 = 0;
for cnt = 0 to Period
{
If DayClose(cnt+1) > DayHigh(cnt) then
TH = DayClose(cnt+1);
else
TH = DayHigh(cnt);
If DayClose(cnt+1) < daylow(cnt) then
TL = DayClose(cnt+1);
else
TL = daylow(cnt);
TR = TH-TL;
if cnt < Period Then
sumTR = sumTR + TR;
if cnt > 0 Then
sumTR1 = sumTR1 + TR;
}
ATRV = sumTR/Period; #당일기준 일봉ATR
ATRV1 = sumTR1/Period; #전일기준 일봉ATR
#plot1(ATRV1,"전일기준ATR");
#plot2(ATRV1*2,"전일기준ATR*2");
#plot3(ATRV,"당일기준ATR");
#plot4(ATRV*2,"당일기준ATR*2");
plot5(dayhigh+ATRV1,"당일고가+전일기준ATR");
plot6(daylow-ATRV1,"당일저가-전일기준ATR");
plot7(dayhigh+ATRV1*2,"당일고가+전일기준ATR*2");
plot8(daylow-ATRV1*2,"당일저가-전일기준ATR*2");
var : tx1(0),tx2(0),tx3(0),tx4(0);
Text_Delete(tx1);
tx1 = Text_New_Self(sDate,sTime,DayHigh+ATRV1,"H:"+NumToStr(DayHigh+ATRV1,2));
Text_SetColor(tx1,Red);
Text_SetStyle(tx1,2,1);
Text_Delete(tx2);
tx2 = Text_New_Self(sDate,sTime,DayLow-ATRV1,"L:"+NumToStr(DayLow-ATRV1,2));
Text_SetColor(tx2,Blue);
Text_SetStyle(tx2,2,0);
Text_Delete(tx3);
tx3 = Text_New_Self(sDate,sTime,DayHigh+ATRV1*2,"H2:"+NumToStr(DayHigh+ATRV1*2,2));
Text_SetColor(tx3,Red);
Text_SetStyle(tx3,2,1);
Text_Delete(tx4);
tx4 = Text_New_Self(sDate,sTime,DayLow-ATRV1*2,"L2:"+NumToStr(DayLow-ATRV1*2,2));
Text_SetColor(tx4,Blue);
Text_SetStyle(tx4,2,0);
2
특정시간을 기준으로 하면 아래와 같습니다.
input : Period(20),ntime(80000);
var : cnt(0),TH(0),TL(0),TR(0);
var : sumTR(0),ATRV(0);
var : sumTR1(0),ATRV1(0);
if sTime == ntime Then
{
sumTR = 0;
for cnt = 0 to Period-1
{
If DayClose(cnt+1) > DayHigh(cnt) then
TH = DayClose(cnt+1);
else
TH = DayHigh(cnt);
If DayClose(cnt+1) < daylow(cnt) then
TL = DayClose(cnt+1);
else
TL = daylow(cnt);
TR = TH-TL;
sumTR = sumTR + TR;
}
ATRV = sumTR/Period; #당일기준 일봉ATR
ATRV1 = ATRV[1]; #전일기준 일봉ATR
}
#plot1(ATRV1,"전일기준ATR");
#plot2(ATRV1*2,"전일기준ATR*2");
#plot3(ATRV,"당일기준ATR");
#plot4(ATRV*2,"당일기준ATR*2");
plot5(dayhigh+ATRV1,"당일고가+전일기준ATR");
plot6(daylow-ATRV1,"당일저가-전일기준ATR");
var : tx1(0),tx2(0);
Text_Delete(tx1);
Text_Delete(tx2);
tx1 = Text_New_Self(sDate,sTime,DayHigh+ATRV1,"H:"+NumToStr(DayHigh+ATRV1,2));
tx2 = Text_New_Self(sDate,sTime,DayLow-ATRV1,"L:"+NumToStr(DayLow-ATRV1,2));
Text_SetColor(tx1,Red);
Text_SetColor(tx2,Blue);
Text_SetStyle(tx1,2,1);
Text_SetStyle(tx2,2,0);
즐거운 하루되세요
> 월드맨 님이 쓴 글입니다.
> 제목 : 수식 부탁 드립니다.
> 안녕하세요?
지표식 분의 드립니다.
1.20일 atr 가격표시
2.20일 atr 2배수 가격 표시
3.당일가격 포함 20일 atr 가격표시
4.당일 가격 포함 atr 20일 2배수 가격 표시
5.당일고가 + 20일atr"H" 로 표시 후 빨간색으로 가격 표시
6.당일저가 - 20일 atr "L"로 표시후 파란색 으로 가격 표시
40일 60일 100일 등으로도 변환 가능 할수 있으니 표시 부탁 합니다.
atr 첫번째 봉을 날짜로 지정도 가능 한가요?
0시 기준
오전 8시 기준등.