커뮤니티
하이킨 아시 타주기
2023-05-14 09:43:59
890
글번호 168941
var : xClose(0),xOpen(0),xHigh(0),xLow(0);
if index == 0 then
{
xOpen = open;
xClose = (O+H+L+C)/4;
xHigh = MaxList( high, xOpen, xClose);
xLow = MinList( low, xOpen,xClose);
}
else
{
xClose = (O+H+L+C)/4;
xOpen = (xOpen [1] + xClose [1])/2 ;
xHigh = MaxList(High, xOpen, xClose) ;
xLow = MinList(Low, xOpen, xClose) ;
}
if XClose > Xopen Then
PlotPaintBar(h,l,"강조",Red);
else if XClose < Xopen Then
PlotPaintBar(h,l,"강조",Blue);
else
PlotPaintBar(h,l,"강조",GREEN);
a,15틱 차트에 150틱 타주기 설치.
b,수정된 타주기 수식이 음전환되면 바 상단에 네모 표시.
당일 고점 -1p 아래에서 양전환되면 하단에 네모 표시. 감사합니다.
답변 1
예스스탁 예스스탁 답변
2023-05-15 10:41:26
안녕하세요
예스스탁입니다.
1
N에 기본차트의 배수를 지정해 주시면 됩니다.
15틱차트에서 150틱은 10배 이므로 10으로 지정하시면 됩니다.
2
색상이 종가와 시가기준으로 변경이 되므로
타주기 작성하면 중간중간 종가 위치에 따라 한구간 색상이 계속 변경이 됩니다.
3번식은 색 변경시 마다 표시를 하고
4번식은 하나의 구간이 끝나면 표시를 하게 됩니다.
3
input : n(10);
var : D1(0),idx(0),TF(0),T(0),T1(0),tx(0);
var : oo(0),hh(0),ll(0),cc(0);
var : xopen(0),xhigh(0),xlow(0),xclose(0);
var : xopen1(0),xhigh1(0),xlow1(0),xclose1(0);
if Bdate != Bdate[1] or Index == 0 Then
{
D1 = sdate;
idx = 0;
}
Else
idx = idx+1;
if D1 > 0 Then
{
TF = idx%n;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) or Index == 0 Then
{
TL_New(sDate,sTime,0,sDate,sTime,99999999);
oo = o;
hh = h;
ll = l;
value1 = value1+1;
xopen1 = xopen;
xclose1 = xclose;
xhigh1 = xhigh;
xlow1 = xlow;
T1 = T[1];
}
if hh > 0 and h > hh Then
hh = h;
if ll > 0 and l < ll Then
ll = l;
cc = c;
if value1 == 1 then
{
xOpen = oo;
xClose = (oo+hh+ll+cc)/4;
xHigh = MaxList(hh, xOpen, xClose);
xLow = MinList(ll, xOpen,xClose);
}
if value1 > 1 then
{
xClose = (oo+hh+ll+cc)/4;
xOpen = (xOpen1 + xClose1)/2 ;
xHigh = MaxList(hh, xOpen, xClose) ;
xLow = MinList(ll, xOpen, xClose) ;
}
if XClose > Xopen Then
{
T = 1;
PlotPaintBar(h,l,"강조",Red);
}
else if XClose < Xopen Then
{
T = -1;
PlotPaintBar(h,l,"강조",Blue);
}
else
{
T = 0;
PlotPaintBar(h,l,"강조",GREEN);
}
if T != T[1] Then
{
if T == -1 Then
{
tx = Text_New(sDate,sTime,H,"■");
Text_SetColor(tx,Blue);
Text_SetStyle(tx,2,1);
}
if T == 1 and Xclose < DayHigh-1 Then
{
tx = Text_New(sDate,sTime,L,"■");
Text_SetColor(tx,Red);
Text_SetStyle(tx,2,0);
}
}
}
4
input : n(10);
var : D1(0),idx(0),TF(0),T(0),T1(0),T2(0),tx(0);
var : oo(0),hh(0),ll(0),cc(0);
var : xopen(0),xhigh(0),xlow(0),xclose(0);
var : xopen1(0),xhigh1(0),xlow1(0),xclose1(0);
if Bdate != Bdate[1] or Index == 0 Then
{
D1 = sdate;
idx = 0;
}
Else
idx = idx+1;
if D1 > 0 Then
{
TF = idx%n;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF < TF[1]) or Index == 0 Then
{
TL_New(sDate,sTime,0,sDate,sTime,99999999);
oo = o;
hh = h;
ll = l;
value1 = value1+1;
xopen1 = xopen;
xclose1 = xclose;
xhigh1 = xhigh;
xlow1 = xlow;
T1 = T[1];
T2 = T1[1];
if T1 != T2 Then
{
if T1 == -1 Then
{
tx = Text_New(sDate,sTime,H,"■");
Text_SetColor(tx,Blue);
Text_SetStyle(tx,2,1);
}
if T1 == 1 and Xclose < DayHigh-1 Then
{
tx = Text_New(sDate,sTime,L,"■");
Text_SetColor(tx,Red);
Text_SetStyle(tx,2,0);
}
}
}
if hh > 0 and h > hh Then
hh = h;
if ll > 0 and l < ll Then
ll = l;
cc = c;
if value1 == 1 then
{
xOpen = oo;
xClose = (oo+hh+ll+cc)/4;
xHigh = MaxList(hh, xOpen, xClose);
xLow = MinList(ll, xOpen,xClose);
}
if value1 > 1 then
{
xClose = (oo+hh+ll+cc)/4;
xOpen = (xOpen1 + xClose1)/2 ;
xHigh = MaxList(hh, xOpen, xClose) ;
xLow = MinList(ll, xOpen, xClose) ;
}
if XClose > Xopen Then
{
T = 1;
PlotPaintBar(h,l,"강조",Red);
}
else if XClose < Xopen Then
{
T = -1;
PlotPaintBar(h,l,"강조",Blue);
}
else
{
T = 0;
PlotPaintBar(h,l,"강조",GREEN);
}
}
즐거운 하루되세요
> 고성 님이 쓴 글입니다.
> 제목 : 하이킨 아시 타주기
> var : xClose(0),xOpen(0),xHigh(0),xLow(0);
if index == 0 then
{
xOpen = open;
xClose = (O+H+L+C)/4;
xHigh = MaxList( high, xOpen, xClose);
xLow = MinList( low, xOpen,xClose);
}
else
{
xClose = (O+H+L+C)/4;
xOpen = (xOpen [1] + xClose [1])/2 ;
xHigh = MaxList(High, xOpen, xClose) ;
xLow = MinList(Low, xOpen, xClose) ;
}
if XClose > Xopen Then
PlotPaintBar(h,l,"강조",Red);
else if XClose < Xopen Then
PlotPaintBar(h,l,"강조",Blue);
else
PlotPaintBar(h,l,"강조",GREEN);
a,15틱 차트에 150틱 타주기 설치.
b,수정된 타주기 수식이 음전환되면 바 상단에 네모 표시.
당일 고점 -1p 아래에서 양전환되면 하단에 네모 표시. 감사합니다.
다음글
이전글