커뮤니티
부탁 드립니다.
2023-07-07 21:35:35
1085
글번호 170400
분봉과 틱봉에서 사용할수 있도록 첨부된 그림에 표시된 검정과 하얀색의 지표(상승직선과 하락직선)와 위 아래에 표시된 숫자(지표수치와 틱수,시간)이 똑같이 표시되게 부탁좀 드려 봅니다. 봉수는 30개정도를 기준으로요.
날마다 수고가 많으신데 더워진 날씨에 건강 유의하시기 바랍니다.
답변 1
예스스탁 예스스탁 답변
2023-07-07 10:02:28
안녕하세요
예스스탁입니다.
그림만으로 정확한 지표 내용을 알수 없습니다.
아래식 참고하셔서 수정보완해 사용하시기 바랍니다.
표시값을 모두 작성해 드릴수 없습니다.
값과 틱수 정도만 표시되게 작성해 드립니다.
input : Period(30);
Array : HD[10](0),HT[10](0),HV[10](0); //고점 날짜, 시간, 가격 저장할 배열
Array : LD[10](0),LT[10](0),LV[10](0); //저점 날짜, 시간, 가격 저장할 배열
var : cnt(0),Hprice(0),Lprice(0);
var : UpTrend(false),DownTrend(False),Trend(0);
var : ZigZagTL(0),HTL(0),LTL(0);
var : Text(0),Box(0),Grid(0);
HPrice = H;
LPrice = L;
if Index == 0 Then
{
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
}
Else
{
UpTrend = HPrice >= Highest(HPrice,Period)[1];
DownTrend = LPrice <= Lowest(LPrice,Period)[1];
if trend <= 0 and UpTrend == true Then
{
trend = 1;
For cnt = 9 DownTo 1
{
HD[cnt] = HD[cnt-1];
HT[cnt] = HT[cnt-1];
HV[cnt] = HV[cnt-1];
}
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
ZigZagTL = TL_New(LD[0],LT[0],LV[0],HD[0],HT[0],HV[0]);
TL_SetColor(ZigZagTL,White);
TL_SetSize(ZigZagTL,1);
Text = Text_New(HD[0],HT[0],HV[0],NumToStr(HV[0],2)+NewLine+"+"+NumToStr(abs(HV[0]-LV[0])/PriceScale,0)+"틱");
Text_SetColor(Text,White);
Text_SetStyle(Text,2,1);
}
Else if trend >= 0 and DownTrend Then//하락추세 전환
{
trend = -1;
For cnt = 9 DownTo 1
{
LD[cnt] = LD[cnt-1];
LT[cnt] = LT[cnt-1];
LV[cnt] = LV[cnt-1];
}
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
ZigZagTL = TL_New(HD[0],HT[0],HV[0],LD[0],LT[0],LV[0]);
TL_SetColor(ZigZagTL,Black);
TL_SetSize(ZigZagTL,1);
Text = Text_New(LD[0],LT[0],LV[0],NumToStr(LV[0],2)+NewLine+"-"+NumToStr(abs(HV[0]-LV[0])/PriceScale,0)+"틱");
Text_SetColor(Text,White);
Text_SetStyle(Text,2,0);
}
Else
{
if trend == 1 Then
{
if HPrice > HV[0] Then
{
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
TL_SetEnd(ZigZagTL,HD[0],HT[0],HV[0]);
Text_SetLocation(Text,HD[0],HT[0],HV[0]);
Text_SetString(Text,NumToStr(HV[0],2)+NewLine+"+"+NumToStr(abs(HV[0]-LV[0])/PriceScale,0)+"틱");
}
}
if trend == -1 Then
{
if LPrice < LV[0] Then
{
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
TL_SetEnd(ZigZagTL,LD[0],LT[0],LV[0]);
Text_SetLocation(Text,LD[0],LT[0],LV[0]);
Text_SetString(Text,NumToStr(LV[0],2)+NewLine+"-"+NumToStr(abs(HV[0]-LV[0])/PriceScale,0)+"틱");
}
}
}
}
즐거운 하루되세요
> 사냥꾼 님이 쓴 글입니다.
> 제목 : 부탁 드립니다.
> 분봉과 틱봉에서 사용할수 있도록 첨부된 그림에 표시된 검정과 하얀색의 지표(상승직선과 하락직선)와 위 아래에 표시된 숫자(지표수치와 틱수,시간)이 똑같이 표시되게 부탁좀 드려 봅니다. 봉수는 30개정도를 기준으로요.
날마다 수고가 많으신데 더워진 날씨에 건강 유의하시기 바랍니다.