커뮤니티
문의
2023-07-18 15:44:36
1196
글번호 170730
일봉에 표시를 하고 싶은데요
일주월에서 동시에 스톡캐스틱 12.5.5 골든크로스일때
일봉에만 강조표시를 하고 싶습니다.
답변 1
예스스탁 예스스탁 답변
2023-07-19 14:17:50
안녕하세요
예스스탁입니다.
input : Sto1(10),Sto2(5),Sto3(5);
input : wSto1(10),wSto2(5), wSto3(5);
input : mSto1(10),mSto2(5), mSto3(5);
var : stok(0),stod(0);
var : wEp1(0),wEP2(0),cnt(0);
var : wHV(0), wLV(0), wfastK(0),wStoK(0),wStoD(0);
var : wIDX(0), PrewStoK(0), PrewStoD(0);
Array : WH[100](0),WL[100](0);
var : mEp1(0),mEP2(0);
var : mHV(0), mLV(0), mfastK(0),mStoK(0),mStoD(0);
var : mIDX(0), PremStoK(0), PremStoD(0);
Array : mH[100](0),mL[100](0);
stok = StochasticsK(sto1,sto2);
stod = Stochasticsd(sto1,sto2,sto3);
wEp1 = 2/(wSto2+1);
wEp2 = 2/(wSto3+1);
if DayOfWeek(bdate) < DayOfWeek(bdate[1]) Then
{
for cnt = 99 DownTo 1
{
WH[cnt] = WH[cnt-1];
WL[cnt] = WL[cnt-1];
}
widx = widx + 1;
PrewStoK = wStoK[1];
PrewStoD = wStoD[1];
WH[0] = H;
WL[0] = L;
}
if WH[0] > 0 and H > WH[0] Then
WH[0] = H;
if WL[0] > 0 and L < WL[0] Then
WL[0] = L;
if WH[wSto1-1] > 0 and WL[wSto1-1] > 0 Then
{
wHV = WH[0];
wLV = WL[0];
for cnt = 0 to wSto1-1
{
if WH[cnt] > wHV then
wHV = WH[cnt];
if WL[cnt] < wLV then
wLV = WL[cnt];
}
wFastK = (C-wLV)/(wHV-wLV)*100;
}
if wIDX <= 1 then
{
wStoK = wFastK ;
wStoD = wStoK ;
}
else
{
wStoK = wFastK * wEP1 + PrewStoK * (1-wEP1);
wStoD = wStoK * wEP2 + PrewStoD * (1-wEP2);
}
mEp1 = 2/(mSto2+1);
mEp2 = 2/(mSto3+1);
if bdate > bdate[1]+30 Then
{
for cnt = 99 DownTo 1
{
mH[cnt] = mH[cnt-1];
mL[cnt] = mL[cnt-1];
}
midx = midx + 1;
PremStoK = mStoK[1];
PremStoD = mStoD[1];
mH[0] = H;
mL[0] = L;
}
if mH[0] > 0 and H > mH[0] Then
mH[0] = H;
if mL[0] > 0 and L < mL[0] Then
mL[0] = L;
if mH[mSto1-1] > 0 and mL[mSto1-1] > 0 Then
{
mHV = mH[0];
mLV = mL[0];
for cnt = 0 to mSto1-1
{
if mH[cnt] > mHV then
mHV = mH[cnt];
if mL[cnt] < mLV then
mLV = mL[cnt];
}
mFastK = (C-mLV)/(mHV-mLV)*100;
}
if mIDX <= 1 then
{
mStoK = mFastK ;
mStoD = mStoK ;
}
else
{
mStoK = mFastK * mEP1 + PremStoK * (1-mEP1);
mStoD = mStoK * mEP2 + PremStoD * (1-mEP2);
}
if CrossUp(stok,stod) and
wstok > wstod and prewstok < prewstod and
mstok > mstod and premstok < premstod Then
PlotPaintBar(h,l,"강조",Magenta);
즐거운 하루되세요
> 엉덩공주 님이 쓴 글입니다.
> 제목 : 문의
> 일봉에 표시를 하고 싶은데요
일주월에서 동시에 스톡캐스틱 12.5.5 골든크로스일때
일봉에만 강조표시를 하고 싶습니다.
다음글
이전글