커뮤니티
타주기 지표식
2023-08-16 22:30:24
1237
글번호 171558
아래 수식을 타주기챠트에 사용할수 있도록 변환 부탁드립니다
그리고 수식해설 부탁합니다
input : 기간(20),pt(1);
var : A(0),t(0);
A = WMA(C,기간);
if A > A[1]*(1+pt/1000) Then
t = 1;
if A < A[1]*(1-pt/1000) Then
t = -1;
if A <= A[1]*(1+pt/1000) and A >= A[1]*(1-pt/1000) Then
t = 0;
Plot1(t,"지표",iff(T==1,red,blue));
plot2(0,"기준선");
********************************************************
<< 지표 해설 >>
input : 기간(20),pt(5);
var : A(0);
A = WMA(C,기간);
if A > A[1]*(1+pt/1000) Then
value1 = A;
if A < A[1]*(1-pt/1000) Then
value2 = A;
if A <= A[1]*(1+pt/1000) and A >= A[1]*(1-pt/1000) Then
value3 = A;
Plot1(A);
Plot2(value1);
Plot3(Value2);
Plot4(Value3);
답변 1
예스스탁 예스스탁 답변
2023-08-17 15:46:54
안녕하세요
예스스탁입니다.
1
가중이평이 0.1% 상승하면 1, 하락하면 -1 아니면 0을 그리는 지표입니다.
input : 타주기분(30),기간(20),pt(1);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),T(0);
Var : Sum1(0),CSum1(0),WMA1(0),WMA2(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
WMA2 = WMA1[1];
}
CC[0] = C;
if CC[기간] > 0 Then
{
Sum1 = 0;
CSum1 = 0;
For cnt = 0 To 기간 - 1
{
Sum1 = Sum1 + CC[cnt] * (기간 - cnt);
CSum1 = CSum1 + 기간 - cnt;
}
If CSum1 > 0 Then
WMA1 = Sum1/CSum1;
Else
WMA1 = 0;
if WMA1 > WMA2*(1+pt/1000) Then
t = 1;
if WMA1 < WMA2*(1-pt/1000) Then
t = -1;
if WMA1 <= WMA2*(1+pt/1000) and WMA1 >= WMA2*(1-pt/1000) Then
t = 0;
Plot1(t,"지표",iff(T==1,red,blue));
plot2(0,"기준선");
}
}
2
가중이평이 0.1% 상승할때값, 0.1% 하락할때 값, +0.1%~-0.1% 사이일때 값을 그리는 지표입니다.
input : 타주기분(30),기간(20),pt(1);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),T(0);
Var : Sum1(0),CSum1(0),WMA1(0),WMA2(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
WMA2 = WMA1[1];
var1 = value1[1];
var2 = value2[1];
var3 = value3[1];
}
CC[0] = C;
if CC[기간] > 0 Then
{
Sum1 = 0;
CSum1 = 0;
For cnt = 0 To 기간 - 1
{
Sum1 = Sum1 + CC[cnt] * (기간 - cnt);
CSum1 = CSum1 + 기간 - cnt;
}
If CSum1 > 0 Then
WMA1 = Sum1/CSum1;
Else
WMA1 = 0;
if WMA1 > WMA2*(1+pt/1000) Then
value1 = WMA1;
Else
value1 = var1;
if WMA1 < WMA2*(1-pt/1000) Then
value2 = WMA1;
Else
Value2 = Var2;
if WMA1 <= WMA2*(1+pt/1000) and WMA1 >= WMA2*(1-pt/1000) Then
value3 = WMA1;
Else
Value3 = Var3;
Plot1(WMA1);
Plot2(value1);
Plot3(Value2);
Plot4(Value3);
}
}
즐거운 하루되세요
> 조민철 님이 쓴 글입니다.
> 제목 : 타주기 지표식
> 아래 수식을 타주기챠트에 사용할수 있도록 변환 부탁드립니다
그리고 수식해설 부탁합니다
input : 기간(20),pt(1);
var : A(0),t(0);
A = WMA(C,기간);
if A > A[1]*(1+pt/1000) Then
t = 1;
if A < A[1]*(1-pt/1000) Then
t = -1;
if A <= A[1]*(1+pt/1000) and A >= A[1]*(1-pt/1000) Then
t = 0;
Plot1(t,"지표",iff(T==1,red,blue));
plot2(0,"기준선");
********************************************************
<< 지표 해설 >>
input : 기간(20),pt(5);
var : A(0);
A = WMA(C,기간);
if A > A[1]*(1+pt/1000) Then
value1 = A;
if A < A[1]*(1-pt/1000) Then
value2 = A;
if A <= A[1]*(1+pt/1000) and A >= A[1]*(1-pt/1000) Then
value3 = A;
Plot1(A);
Plot2(value1);
Plot3(Value2);
Plot4(Value3);