커뮤니티
틱봉에서 30분봉 점찍기좀 부탁 드립니다
2023-10-04 15:16:28
935
글번호 172819
* 좋은 한주 되십시요.
* 30분 분봉 crossup , crossdown시 차트에 점찍기(●) 요청 드립니다.
단 틱봉 사용 예정 입니다.
즉 틱 봉을 사용 하는데 30분봉 이평선(ma(c,30))이 ma(c,5) 와크로스 되거나 다운되면
점찍기를 요청 드립니다.
틱봉은 몇 틱봉을 사용 해야할지 아무리 찾아봐도 잘 모르겠습니다.
30분봉 점찍기 적당한 틱봉(또는 비슷) 계산해 주시면 사용 하겠습니다.
즉 매매시 30분봉 크로스업 다운이 중요한 변화라서 필요 합니다.
분봉을 틱봉에 점찍기 안되는 건가요?
* 항상 많은 도움에 고맙습니다. 수고하십시요.
답변 1
예스스탁 예스스탁 답변
2023-10-04 16:01:34
안녕하세요
예스스탁입니다.
틱봉에서 분봉의 지표는 정확히 계산할 수 없습니다.
틱봉의 주기가 낮을수록 실제와 가까운 값이 됩니다.
input : ntime1(30),P1(5),P2(30);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),Tx(0);
var : sum1(0),mav1(0),premav1(0);
var : sum2(0),mav2(0),premav2(0);
Array : CC[100](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%ntime1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime1 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime1 > 1 and TM >= TM[1]+ntime1) or
(Bdate == Bdate[1] and ntime1 == 1 and TM > TM[1]) Then
{
for cnt = 99 downto 1
{
CC[cnt] = CC[cnt-1];
}
premav1 = mav1[1];
premav2 = mav2[1];
}
CC[0] = C;
if CC[P1-1] > 0 then
{
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1+CC[cnt];
}
mav1 = sum1/P1;
}
if CC[P2-1] > 0 then
{
sum2 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2+CC[cnt];
}
mav2 = sum2/P2;
}
plot1(mav1);
plot2(mav2);
IF mav1 > mav2 and premav1 < premav2 Then
{
tx = Text_New(sDate,sTime,L,"●");
Text_SetStyle(tx,2,0);
Text_SetColor(tx,Red);
}
IF mav1 < mav2 and premav1 > premav2 Then
{
tx = Text_New(sDate,sTime,H,"●");
Text_SetStyle(tx,2,1);
Text_SetColor(tx,Blue);
}
}
즐거운 하루되세요
> 요타 님이 쓴 글입니다.
> 제목 : 틱봉에서 30분봉 점찍기좀 부탁 드립니다
> * 좋은 한주 되십시요.
* 30분 분봉 crossup , crossdown시 차트에 점찍기(●) 요청 드립니다.
단 틱봉 사용 예정 입니다.
즉 틱 봉을 사용 하는데 30분봉 이평선(ma(c,30))이 ma(c,5) 와크로스 되거나 다운되면
점찍기를 요청 드립니다.
틱봉은 몇 틱봉을 사용 해야할지 아무리 찾아봐도 잘 모르겠습니다.
30분봉 점찍기 적당한 틱봉(또는 비슷) 계산해 주시면 사용 하겠습니다.
즉 매매시 30분봉 크로스업 다운이 중요한 변화라서 필요 합니다.
분봉을 틱봉에 점찍기 안되는 건가요?
* 항상 많은 도움에 고맙습니다. 수고하십시요.