커뮤니티
예스스탁에서 제공되는 RSI 수식을 알고 싶습니다.
2025-08-09 13:02:17
133
글번호 193100
안녕 하세요? 저는 예스스탁에서 제공되는 RSI 수식을 알고 싶습니다.
기존 커뮤니티에 올려 주신 내용으로 해 보았으나 결과가 다르게 나오네요.
예스스탁에서 제공되는 wilder 방식의 수식을 알고 싶습니다.
<<기존 알려 주신 내용>>
input : N(10);
var : RS(0),RSIV(0);
#n일간종가평균상승폭
var1 = AccumN(IFF(C>C[1],C-C[1],0),N);
var2 = AccumN(IFF(C>C[1],1,0),N);
Var3 = var1/Var2;
#n일간종가평균하락폭
var4 = AccumN(IFF(C
지표
답변 1

예스스탁 예스스탁 답변
2025-08-11 10:11:04
안녕하세요
예스스탁입니다.
예스랭귀지 편집기에서
RSI 함수식은 열어보실 수 있습니다.
파일관리자 사용자함수탭에서 RSI선택해 열어보시면 됩니다.
수식 내용은 아래와 같습니다.
Inputs: Length(NumericSimple);
Variables: Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
If CurrentBar == 1 AND Length > 0 Then Begin
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1 Begin
UpAmt = C[Counter] - C[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
End;
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
End
Else
If CurrentBar > 1 AND Length > 0 Then Begin
UpAmt = C[0] - C[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpAvg = (UpAvg[1] * (Length - 1) + UpAmt) / Length;
DownAvg = (DownAvg[1] * (Length - 1) + DownAmt) / Length;
End;
If UpAvg + DownAvg <> 0 Then
RSI = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSI = 0;
즐거운 하루되세요
> 이머꼬 님이 쓴 글입니다.
> 제목 : 예스스탁에서 제공되는 RSI 수식을 알고 싶습니다.
> 안녕 하세요? 저는 예스스탁에서 제공되는 RSI 수식을 알고 싶습니다.
기존 커뮤니티에 올려 주신 내용으로 해 보았으나 결과가 다르게 나오네요.
예스스탁에서 제공되는 wilder 방식의 수식을 알고 싶습니다.
<<기존 알려 주신 내용>>
input : N(10);
var : RS(0),RSIV(0);
#n일간종가평균상승폭
var1 = AccumN(IFF(C>C[1],C-C[1],0),N);
var2 = AccumN(IFF(C>C[1],1,0),N);
Var3 = var1/Var2;
#n일간종가평균하락폭
var4 = AccumN(IFF(C