커뮤니티
수식작성 부탁드립니다.
2025-08-24 16:29:45
97
글번호 193460
첨부 이미지
그림1
안녕하세요. 운영자님
제가 이번에 요청드릴 사항은
매수영역 : MACD signal > MACD and 스토캐스틱 K > 스토캐스틱 D and RSI>55 and
이동평균선 5일선 > 20일선 (정배열) and 일목균형표 구름대 양운
이중 하나의 조건이라도 충족되지 않으면 끝
매도영역 : MACD signal < MACD and 스토캐스틱 K < 스토캐스틱 D and RSI<45 and
이동평균선 5일선 < 20일선 (역배열) and 일목균형표 구름대 음운
이중 하나의 조건이라도 충족되지 않으면 끝
첨부된 그림의 바탕색과 같은 배경으로 구현될 수 있도록 부탁드리며, 시스템으로도 구현될 수 있도록 따로 작성 부탁 드립니다.
수고하세요
- 1. 바탕색.png (0.02 MB)
답변 1
예스스탁 예스스탁 답변
2025-08-25 12:43:26
안녕하세요
예스스탁입니다.
1
input : short(12),long(26),sig(9);
input : sto1(10),sto2(5),sto3(5);
input : RsiP(10);
input : Period1(5),Period2(20);
var : macdv(0),macds(0);
var : stok(0),stod(0);
var : R(0),m1(0),m2(0),box(0);
var : 전환선(0),기준선(0),선행스팬1(0), 선행스팬2(0);
macdv = macd(short,long);
macds = ema(macdv,sig);
stok = stochasticsK(sto1,sto2);
stod = stochasticsD(sto1,sto2,sto3);
R = RSI(RSIP);
m1= ma(C,Period1);
m2= ma(C,Period2);
전환선 = (Highest(High, 9) + Lowest(Low, 9)) / 2;
기준선 = (Highest(High, 26) + Lowest(Low, 26)) / 2;
선행스팬1 = (전환선[25] + 기준선[25]) / 2 ;
선행스팬2 = (Highest(High, 52)[25] + Lowest(Low, 52)[25]) / 2;
Condition1 = macds > macdv and stok > stod and R > 55 and m1 > m2 and 선행스팬1 > 선행스팬2;
Condition2 = macds < macdv and stok < stod and R < 45 and m1 < m2 and 선행스팬1 < 선행스팬2;
if Condition1 == true Then
{
if Condition1[1] == False Then
{
box = Box_New(sDate,sTime,H,NextBarSdate,NextBarStime,L);
Box_SetColor(box,Yellow);
Box_SetFill(box,true);
Box_SetExtFill(box,true);
}
Else
Box_SetEnd(box,NextBarSdate,NextBarStime,L);
}
if Condition2 == true Then
{
if Condition2[1] == False Then
{
box = Box_New(sDate,sTime,H,NextBarSdate,NextBarStime,L);
Box_SetColor(box,Blue);
Box_SetFill(box,true);
Box_SetExtFill(box,true);
}
Else
Box_SetEnd(box,NextBarSdate,NextBarStime,L);
}
2
input : short(12),long(26),sig(9);
input : sto1(10),sto2(5),sto3(5);
input : RsiP(10);
input : Period1(5),Period2(20);
var : macdv(0),macds(0);
var : stok(0),stod(0);
var : R(0),m1(0),m2(0),box(0);
var : 전환선(0),기준선(0),선행스팬1(0), 선행스팬2(0);
macdv = macd(short,long);
macds = ema(macdv,sig);
stok = stochasticsK(sto1,sto2);
stod = stochasticsD(sto1,sto2,sto3);
R = RSI(RSIP);
m1= ma(C,Period1);
m2= ma(C,Period2);
전환선 = (Highest(High, 9) + Lowest(Low, 9)) / 2;
기준선 = (Highest(High, 26) + Lowest(Low, 26)) / 2;
선행스팬1 = (전환선[25] + 기준선[25]) / 2 ;
선행스팬2 = (Highest(High, 52)[25] + Lowest(Low, 52)[25]) / 2;
Condition1 = macds > macdv and stok > stod and R > 55 and m1 > m2 and 선행스팬1 > 선행스팬2;
Condition2 = macds < macdv and stok < stod and R < 45 and m1 < m2 and 선행스팬1 < 선행스팬2;
if Condition1 == true Then
{
Buy();
}
if Condition1 == False Then
ExitLong();
if Condition2 == true Then
{
Sell();
}
if Condition2 == False Then
ExitShort();
즐거운 하루되세요
> 고박사122 님이 쓴 글입니다.
> 제목 : 수식작성 부탁드립니다.
> 안녕하세요. 운영자님
제가 이번에 요청드릴 사항은
매수영역 : MACD signal > MACD and 스토캐스틱 K > 스토캐스틱 D and RSI>55 and
이동평균선 5일선 > 20일선 (정배열) and 일목균형표 구름대 양운
이중 하나의 조건이라도 충족되지 않으면 끝
매도영역 : MACD signal < MACD and 스토캐스틱 K < 스토캐스틱 D and RSI<45 and
이동평균선 5일선 < 20일선 (역배열) and 일목균형표 구름대 음운
이중 하나의 조건이라도 충족되지 않으면 끝
첨부된 그림의 바탕색과 같은 배경으로 구현될 수 있도록 부탁드리며, 시스템으로도 구현될 수 있도록 따로 작성 부탁 드립니다.
수고하세요
이전글